perl - convert string of numeric values/ranges to actual values

Question

I'd like to convert a sting of the form 1,2,25-27,4,8,14,7-10 into a list of the actual values: 1,2,4,7,8,9,10,14,25,26,27.

I've searched and found nothing that does this sort of expansion. Anyone aware of way to do this easily?

Duplicate of http://stackoverflow.com/q/1016766/725418 – TLP Oct 11 '13 at 16:07 — TLP, Oct 11 '13 at 16:07

score 5 · Accepted Answer · answered Oct 11 '13 at 15:02

5

my $s = "1,2,25-27,4,8,14,7-10";
my %seen;
my @arr =
  sort { $a <=> $b }
  grep { !$seen{$_}++ }
  map { 
    my @r = split /-/; 
    @r>1 ? ($r[0] .. $r[1]) : @r;
  }
  split /,/, $s;

print "@arr\n";

output

1 2 4 7 8 9 10 14 25 26 27

answered Oct 11 '13 at 15:02

mpapec

50,217
8
67
127

I'll write explanation if you need it – mpapec Oct 11 '13 at 15:05
2

The perl is strong with this one! That's elegant and exactly what I was looking for. Thanks you very much. While I could not have written that on my own, I can follow what it's doing. – SecondGear Oct 11 '13 at 15:18

edi_allen · Answer 2 · 2013-10-11T15:44:23.807

Another way to do this quickly is by using the string version of eval. But you have to keep in mind that the use of eval have some security implication so you better sanitize any string before passing it to eval.

use strict;
use warnings;

my $string = "1,2,25-27,4,8,14,7-10";

$string =~ s/-/../g;

my @list = sort {$a <=> $b} keys { map {$_, 1} eval $string };

print "@list\n";  

#output
1 2 4 7 8 9 10 14 25 26 27

perl - convert string of numeric values/ranges to actual values

2 Answers2