System.Timers.Timer (.NET) really slow?

Question

I was under the impression that System.Timers.Timer creates its own thread and that Microsoft recommends this type of timer to do tasks that do more accurate timing (as opposed to Windows.Forms.Timer, which runs in the UI thread).

The code below (I think) should be copy-and-pasteable into a project with an empty form. On my machine, I cannot get tmrWork to tick any faster than about 60 times per second, and it's amazingly unstable.

Public Class Form1

    Private lblRate As New Windows.Forms.Label
    Private WithEvents tmrUI As New Windows.Forms.Timer
    Private WithEvents tmrWork As New System.Timers.Timer

    Public Sub New()
        Me.Controls.Add(lblRate)

        InitializeComponent()
    End Sub

    Private StartTime As DateTime = DateTime.Now
    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) _
        Handles MyBase.Load
        tmrUI.Interval = 100
        tmrUI.Enabled = True
        tmrWork.Interval = 1
        tmrWork.Enabled = True
    End Sub

    Private Counter As Integer = 0
    Private Sub tmrUI_Tick(sender As Object, e As System.EventArgs) _
        Handles tmrUI.Tick
        Dim Secs As Integer = (DateTime.Now - StartTime).TotalSeconds
        If Secs > 0 Then lblRate.Text = (Counter / Secs).ToString("#,##0.0")
    End Sub

    Private Sub tmrWork_Elapsed(sender As Object, e As System.Timers.ElapsedEventArgs) _
        Handles tmrWork.Elapsed
        Counter += 1
    End Sub
End Class

In this particular simple case, putting everything in tmrUI will yield the same performance. I guess I never tried to get a System.Timers.Timer to go too fast, but this performance looks just too bad to me. I wrote my own class to use the high performance timer in hardware but it seems like there should be a built-in timer that can do, say 100 ticks per second?

What's going on here?

Answer 1

The above code for dbasnett throws an error at "Stop" below the Debug.WriteLine (during the debugging mode.) I recommend that contributors test their code before giving advice.

Stackoverflow is vital for finding the best coding solutions and it is up to us (the contributors) to do our best.

Each time an Elapsed is called, the callback is fired on its own thread. In addition, there is nothing stopping one Elapsed event handler from firing before the previous one is completed.

For further research, I highly recommend viewing the provided links below:

https://learn.microsoft.com/en-us/archive/msdn-magazine/2004/february/comparing-the-timer-classes-in-the-net-framework-class-library

https://learn.microsoft.com/en-us/dotnet/api/system.timers.timer?view=net-6.0

The following code is the correct solution and I personally tested it. Every 4 seconds, it will restart:

Public Class Form1

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load

        Clockwork.AutoReset = True
        Clockwork.Interval = 4000 '4 seconds
        AddHandler Clockwork.Elapsed, AddressOf Tick1
        Clockwork.Start()

    End Sub

    ReadOnly Clockwork As New Timers.Timer

    Private Sub Tick1(sender As Object, e As Timers.ElapsedEventArgs)

        Clockwork.Stop()
        MessageBox.Show("Timer's Working")
        Clockwork.Start() 'This will restart the timer

    End Sub
End Class

Answer 2

To get near 100Hz try something like this which uses an AutoResetEvent.

Private Sub tmrWork()
    'start this as a background thread
    Dim tmr As New Threading.AutoResetEvent(False)
    Dim stpw As Stopwatch = Stopwatch.StartNew
    Const interval As Integer = 10 'the interval
    '
    '
    Do 'timer
        stpw.Stop()
        If stpw.ElapsedMilliseconds > interval Then
            tmr.WaitOne(interval) 'the interval
        Else
            tmr.WaitOne(CInt(interval - stpw.ElapsedMilliseconds)) 'the interval
        End If
        stpw.Restart()
        '
        'code to execute when 'timer' elapses
        '

    Loop
End Sub

Here is a test that shows that, depending on what you do in the loop, it is possible to fire off code at 100Hz.

Private Sub tmrWork()
    Dim tmr As New Threading.AutoResetEvent(False)
    Dim stpw As Stopwatch = Stopwatch.StartNew
    Const interval As Integer = 10 'the interval
    'for testing
    Dim cts As New List(Of Long)
    '
    '
    Do 'timer
        tmr.WaitOne(interval) 'wait for the interval
        cts.Add(stpw.ElapsedMilliseconds) 'add elapsed to list
        stpw.Restart() 'restart
        If cts.Count >= 500 Then 'five second test
            Debug.WriteLine(String.Format("Avg: {0},  Min: {1},  Max: {2}", cts.Average, cts.Min, cts.Max))
            Stop
        End If
    Loop
End Sub

Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
    Dim t As New Threading.Thread(AddressOf tmrWork)
    t.IsBackground = True
    t.Start()
End Sub

For Hans Pissant

Platform Timer Resolution:Platform Timer Resolution The default platform timer resolution is 15.6ms (15625000ns) and should be used whenever the system is idle. If the timer resolution is increased, processor power management technologies may not be effective. The timer resolution may be increased due to multimedia playback or graphical animations. Current Timer Resolution (100ns units) 100000 Maximum Timer Period (100ns units) 156001

Platform Timer Resolution:Outstanding Timer Request A program or service has requested a timer resolution smaller than the platform maximum timer resolution. Requested Period 100000 Requesting Process ID 452 Requesting Process Path \Device\HarddiskVolume3\Windows\System32\svchost.exe