How to compare file format in windows batch script

Question

I have list of file names which contains .xml, .css, .js, .jsp, .java etc. I want a code that will allow you execute your function only when that file have .js or .jsp or .java extension.I don't know how to check muliple condition in if statement. that's why adding as OR..kindly help me..Thank you

   FOR /F "delims=#" %%A in (demo.txt) do (

    IF [/I] %%~xA==".js" OR %%~xA==".css" OR %%~xA==".java"

    (

    echo correct format

    )

    ELSE

    (

    ECHO incorrect format

    ) 

)

score 1 · Answer 1 · edited May 23 '17 at 11:57

1

Create a variable that contains a list of all valid extensions. Be sure to include an extra dot at the end, such that all extensions are enclosed by dots. Then for each value, attempt search and replace on the list, replacing the found extension (plus dot) with nothing. If the result is different than the original list, then the extension is valid.

@echo off
setlocal enableDelayedExpansion
set "formats=.css.js.jsp.java."
for /f "delims=#" %%A in (demo.txt) do (
  if "!formats:%%~xA.=!" neq "!formats!" (
    echo %%~xA is correct format
  ) else (
    echo %%~xA is incorrect format
  )
)

See IF… OR IF… in a windows batch file for additional methods to implement OR logic.

edited May 23 '17 at 11:57

Community

1
1

answered Oct 25 '13 at 14:16

dbenham

127,446
28
251
390

simpler than mine attempt.+1 – npocmaka Oct 25 '13 at 14:19
Thank you so much...your code running perfectly..Thanks alot :) – user2918831 Oct 25 '13 at 14:35
@user2918831 - Don't forget to accept the answer you find most helpful if it completely answers your question. Simply click on the check mark in the upper left of the anser. That action lets others know the question has been answered, awards you 2 reputation points, awards the answer poster 15 rep points. Only one answer can be accepted per question. Once you reach 15 rep points you will be able to up vote any answer that you find useful, including answers to other people's questions. – dbenham Oct 25 '13 at 15:12

npocmaka · Answer 2 · 2013-10-25T14:30:23.177

1

    setlocal enableDelayedExpansion
    FOR /F "delims=#" %%A in (demo.txt) do (
      set "format=incorect"
      for %%E in (.js;.java;.jsp;.css) do (
         if "%%~xA" == "%%~E" (         
           set "format=correct"
         )
      )
      if "!format!" equ "correct" (
        echo correct format
      ) else (
        echo incorrect format
      )

    )
   endlocal

edited Oct 25 '13 at 14:30

answered Oct 25 '13 at 14:18

npocmaka

55,367
18
148
187

score 1 · Answer 3 · answered Oct 25 '13 at 14:26

1

If file list in demo.txt as indicated by OP

for /F "tokens=*" %%f in ('type demo.txt ^| findstr /i /e ".js .java .jsp"') do (
    rem here what needs to be done
    echo %%f
)

If files in directory, replace type demo.txt with dir /b .... adjusting the directory to process.

answered Oct 25 '13 at 14:26

MC ND

69,615
8
84
126

you need to escape the pipe – npocmaka Oct 25 '13 at 14:27
and `findstr /i /e /c:"jsp" /c:"java" ...` – npocmaka Oct 25 '13 at 14:29
Corrected. Copied and pasted from commandline and i forget to correct it. – MC ND Oct 25 '13 at 14:29
1

No, /C: is not necessary. Documentation states spaces delimit multiple substrings UNLESS /c is used. – MC ND Oct 25 '13 at 14:30
test this : `echo some.js| findstr /i /e ".js .java .jsp"` – npocmaka Oct 25 '13 at 14:32
1

If fails because the echo is outputing one quote at the end. And findstr /e says the coincidence should be at the end. So no match. – MC ND Oct 25 '13 at 14:34
1

Sorry. Now i see you have edited your test. new version return some.js – MC ND Oct 25 '13 at 14:35

Endoro · Answer 4 · 2013-10-25T19:05:31.533

0

try this:

@ECHO OFF &SETLOCAL
for /f "delims=#" %%a in (demo.txt) do (
    set "flag="
    if /i "%%~xa"==".js" set "flag=true"
    if /i "%%~xa"==".css" set "flag=true"
    if /i "%%~xa"==".java" set "flag=true"
    if defined flag (echo %%~xa is valid) else echo %%~xa is not valid
)

edited Oct 25 '13 at 19:05

answered Oct 25 '13 at 18:58

Endoro

37,015
8
50
63

How to compare file format in windows batch script

4 Answers4