How a macro can be automatically started based on the value of different cells in a specific range

Question

I'm trying to automatically start a macro based on the value entered into a cell. I was able to do it for one cell but how can I apply it to a range, example from L1 to L600?

Here is the code that works for 1 cell:

Sub Worksheet_Change(ByVal Target As Range)

Dim CAD As String
CAD = "Canadians (CDN)"

    If Intersect(Target, Range("L14")) Is Nothing Then Exit Sub
    Application.EnableEvents = False 'to prevent endless loop

        If Range("L14").Value = CAD Then
        Range("M14") = 1
        End If

    Application.EnableEvents = True

End Sub

Basically I have to check the next cell L15 and enter a value in M15 if the condition is met and so on....

Answer 1

I see Sid has already posted an answer, but here's a slightly different version:

Sub Worksheet_Change(ByVal Target As Range)

Dim CAD As String, c as Range, rng As Range
CAD = "Canadians (CDN)"

on error goto haveErr
    set rng = application.Intersect(Target, Me.Range("L1:L600"))
    if not rng is nothing then
        Application.EnableEvents = False         
        for each c in rng.cells
           if c.value=CAD then c.offset(0,1).value=1
        next c
    End If

haveErr:
    Application.EnableEvents = True

End Sub

Answer 2

Is this what you are trying (UNTESTED)?

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim CAD As String: CAD = "Canadians (CDN)"

    If Target.Cells.CountLarge > 1 Then Exit Sub

    On Error GoTo Whoa

    Application.EnableEvents = False

    If Not Intersect(Target, Range("L1:L600")) Is Nothing Then
        If Target.Value = CAD Then Target.Offset(, 1).Value = 1
    End If

Letscontinue:
    Application.EnableEvents = True
    Exit Sub
Whoa:
    MsgBox Err.Description
    Resume Letscontinue
End Sub

And since you are using Worksheet_Change you may want to see this POST as well.