intel-Based Assembly Language idiv

Question

I'm trying to get idiv working properly and I've read you put what you want to divide such as 25 and then in ebx you put what you want to divide by such as 5 then you do

idiv ebx

which then puts EAX = 5 and then EDX = 0.

However it doesn't do that in my program the input I do is 100000000

output:

Kilobytes: 100000000

Megabytes: 1869375819

Was wondering what am I doing wrong here?

%include "asm_io.inc"
;
; initialized data is put in the .data segment
;
segment .data
prompt db "Please enter the number of bytes:", 0
param db "1 = Calculate it in kilobytes", 0Ah, "2 = Calculate it in megabytes", 10, 0
output db "Kilobytes: %d", 0Ah, "MegaBytes: %d", 10, 0
;
;
segment .bss
;
input resd 1
input2 resd 1
choice resd 1
;
; code is put in the .text segment
;
segment .text
    global  asm_main
extern printf
asm_main:
    enter   0,0              
    pusha

    mov eax, prompt
    call print_string
    call read_int
    mov [input], eax
    mov [input2], eax

    sub esp, 10h
    push dword [output]
    push dword [input2]
    push dword [input]


    mov eax, param
    call print_string
    call read_int

    cmp eax, 1
    je kilobyte; Jump if eax is equal to 1

    cmp eax, 2
    je megabyte; Jump if eax equal to 2

kilobyte:
    pop eax             ; Pop input into eax
    cdq             
    mov ebx, 1024       ; Put 1024 into ebx
    idiv ebx             ; EAX = 100000000/1024 = 97656
    mov [input], eax    ; Move 97656 into var=input
    push dword [input]  ; Put into stack
    jmp megabyte

megabyte:
    pop eax             ; Pop input into eax
    cdq         
    mov ebx, 1048576    ; Put 1048576 into ebx
    idiv ebx             ; EAX = 100000000/1024 = 95
    mov [input2], eax   ; Move 95 into var=input    
    push dword [input]  ; Put into stack
    jmp printOut

printOut:
    mov dword [esp], output
    call printf

    add esp, 4 * 3


    add esp, 10h

    popa
    mov     eax, 0            
    leave                     
    ret

UPDATE

Well I put in xor edx, edx but I am still getting the same output as before. I've looked into my ebook and other sites and it says same thing so I am really unsure of what I am doing wrong. As well tried the idiv route with no luck.

There's nothing called "Intel-based assembly language". Intel has many different architectures with corresponding different assembly language. The question should be tag with `x86` — phuclv, Nov 08 '13 at 08:48

johnfound · Answer 1 · 2013-11-08T17:48:37.853

About the division

At first, for the goal you need (computing MBytes and KBytes) you need unsigned devision actually. So, use div instruction instead of idiv.

Second, div and idiv actually divide 64bit number in edx:eax by a 32bit number specified as an operand. But your edx register contains random number.

So, you have to expand the number in eax to 64bit before the division.

For idiv use:

    cdq       ; convert signed 32bit number in eax into signed 64bit in edx:eax
    idiv  ebx

For div use:

    xor   edx, edx  ; set edx to 0 in order to extend unsigned eax in edx:eax
    div   ebx

About the printint

Your printing code looks wrong:

kilobyte:
    pop eax             ; Pop input into eax
    cdq             
    mov ebx, 1024       ; Put 1024 into ebx
    idiv ebx             ; EAX = 100000000/1024 = 97656
    mov [input], eax    ; Move 97656 into var=input
    push dword [input]  ; Put into stack
    jmp megabyte

megabyte:
    pop eax             ; Pop input into eax
    cdq         
    mov ebx, 1048576    ; Put 1048576 into ebx
    idiv ebx             ; EAX = 100000000/1024 = 95
    mov [input2], eax   ; Move 95 into var=input    
    push dword [input]  ; Put into stack
    jmp printOut

printOut:
    mov dword [esp], output
    call printf

    add esp, 4 * 3

At first, why to jump to the next address??? The CPU will get there by itself. This is not exactly error, but makes the code less readable and is simply redundant.

    mov [input2], eax   ; Move 95 into var=input    
    push dword [input]  ; Put into stack

printOut:
    mov dword [esp], output
    call printf

    add esp, 4 * 3

Here you can see, that the result is stored in [input2], but [input] is pushed in the stack. Why? The next instruction mov dword [esp], output overwrites the last pushed value in the stack.

Notice that push instruction first decrements esp and then stores the pushed value at [esp]. Here you need push output instead.

"push dword [input] ; Put into stack" thank you for pointing that out, suppose to be input2 pushed, typo. I put in **jmp** because I thought it was needed to call the next function as if it was like a C/C++ function. — user2922055, Nov 08 '13 at 18:18

score 5 · Answer 2 · edited Jun 20 '20 at 09:12

5

You need to initialize EDX - either zero it (xor edx, edx) and use unsigned operations, or sign extend EAX into it (cdq)

IDIV does as follows (link):

Divides (signed) the value in the AX, DX:AX, or EDX:EAX registers (dividend) by the source operand (divisor) and stores the result in the AX (AH:AL), DX:AX, or EDX:EAX registers. The source operand can be a general-purpose register or a memory location.

The action of this instruction depends on the operand size (dividend/divisor), as shown in the following table: IDIV Results [header]Operand

Since you're dividing by EBX, it would take the dividend from EDX:EAX. You didn't initialize EDX to zero and therefor got junk result.

edited Jun 20 '20 at 09:12

Community

1
1

answered Nov 08 '13 at 06:53

Leeor

19,260
5
56
87

In general you need to _sign extend_ `eax` into `edx`: zeroing `edx` is only correct if `eax` is always positive. – gsg Nov 08 '13 at 07:15
@gsg - Correct, fixing – Leeor Nov 08 '13 at 07:24
ok done but I am getting the same errors. Looking back on my book it uses idiv with cdq but uses ecx instead of ebx. – user2922055 Nov 08 '13 at 07:45
@user2922055, Where exactly do you populate `output` with the results? it seems like you're just leaving them on the stack – Leeor Nov 08 '13 at 08:17
For signed `idiv`, use `cdq`. For unsigned `div`, use `xor edx,edx`. See [Why should EDX be 0 before using the DIV instruction?](https://stackoverflow.com/q/38416593) for more about mostly unsigned division, and [When and why do we sign extend and use cdq with mul/div?](https://stackoverflow.com/q/36464879) about signed and unsigned division. – Peter Cordes May 21 '23 at 12:50

João Monteiro · Answer 3 · 2020-09-23T01:06:30.417

The result is consistent with your use of the stack.

The first three "push" of your code, leave the stack as

100000000
100000000
1869375819 (corresponding to string "Kilobytes: %d..." of your data.

When your code reaches the printOut, you overwrite the topmost value with the address of the string to printf. So your stack is :

(address of printf string)
100000000
1869375819 (corresponding to string "Kilobytes: %d..." of your data.)

And printf prints these two values.

In fact, appears that you don't need all that push/pop. The only place where the stack is needed is in the call to printf. It must be :

(address of printf string)
(result of kilobyte: code)
(result of megabyte: code)

As you saved the value into input (to use in kilobyte:) and input2 (to use in megabyte:), you don't need to pop anything.

you can use :

kilobyte:
   mov eax, [input]
   cdq
   mov ebx, 1024
   idiv ebx
   mov [input], eax

So, input now contains the result of idiv. Similarly, in megabyte :

megabyte:
   mov eax, [input2]
   cdq
   mov ebx, 1048576
   idiv ebx
   mov [input2], eax

As in the previous code, now, input2 contains the result you want. Finally, in printOut :

printOut:
   push [input2]
   push [input]
   push $output
   call printf

Good luck coding.

Note that `1024` is a power of 2, so you'd actually want `sar dword [input], 10` to do an arithmetic right shift. — Peter Cordes, Sep 23 '20 at 01:03
(`sar` rounds toward -Infinity, not toward zero like `idiv`, so to get the exact same semantics you'd want to do some extra fixup to adjust by 1 depending on the sign bit of the value being right-shifted, like C compilers do.) — Peter Cordes, May 21 '23 at 12:52

intel-Based Assembly Language idiv

3 Answers3

About the division

About the printint