Can't catch message (postmessage)

Question

i would like to send a message with postmessage() to a TObject instance, but after the thread terminates, the program does not step into method HandleThreadCompletion.

const
  WM_THREAD_COMPLETE = WM_USER + 5437;

The TObject instance (TMaster) contains the identifier for the thread object

type
  TMaster = class(TObject)
  private
    ...
    Fslave_search_thread : Tsrch_slave_thread;
    fMsgHandlerHWND : HWND;
    function start_slvsearch_th: integer; 
    procedure HandleThreadCompletion(var Message: TMessage);
    ...
  public
    ...
  end;

constructor TMaster.Create (aNode: TTreeNode; aName, anIP, aMAC: string);
begin
  ...
  fMsgHandlerHWND := AllocateHWnd(HandleThreadCompletion);
  ...
end;

I free and nil the thread in TMaster.HandleThreadCompletion()

procedure TMaster.HandleThreadCompletion(var Message: TMessage);
begin
  if message.msg = WM_THREAD_COMPLETE then begin
    if Assigned(Fslave_search_thread) then
    begin
      Fslave_search_thread.WaitFor;
      Fslave_search_thread.Free;
      Fslave_search_thread := nil;
      ...
    end
  end else
    message.result := DefWindowProc(fMsgHandlerHWND, Message.Msg, Message.wParam, Message.lParam) ; 
end;

Creating the thread here (suspended), filling some fields than starting it (resume).

function TMaster.start_slvsearch_th: integer;
var
  i: integer;
begin
  if not Assigned(Fslave_search_thread) then begin
    ...
    Fslave_search_thread := Tsrch_slave_thread.Create(true);
    ... 
  with Fslave_search_thread do
  begin
    master := self;
    master_HWND := self.fMsgHandlerHWND;
    FreeOnTerminate := False;
    Resume;   
    ...
  end;
end;

When terminated (with setting the terminate flag from outside or the cycle finishes), sending the message:

procedure Tsrch_slave_thread.Execute;
begin
  while master.CMD_LISTCNT = 1 do 
  begin 
    ...
    if terminated then break;
  end;
  PostMessage(master_HWND, WM_THREAD_COMPLETE, 0, 0);   
  ...
end;

http://members.upclive.hu/ikt/thread_terminate_test_postmessage.zip

Answer 1

The most obvious explanations are:

1. The master thread has terminated before it can process the message.
2. The master thread is not pumping its message queue.
3. The master thread destroys the window before it processes the message.

If you had shown an SSCCE I could have narrowed it down further. Since we cannot see an SSCCE, that means you'll need to narrow it down.

Answer 2

Update:

Sertac found the reason to your problems. The fMsgHandlerHWND was destroyed immediately after it was created in a try/finally construct which should have been a try/except (or something else).

Anyway, the rest of my answer would have been less error prone to implement.

---

It is difficult to say what is wrong with your code without a test case that produces your observation.

However, I would suggest to use a simpler approach to handle the thread shut down.

Before starting the thread, assign an event handler to the OnTerminate property. By setting TThread.FreeOnTerminate you don't have to explicitly free the thread object.

In the OnTerminate event handler, just collect data from the thread (if any) and set the thread reference to nil.

type
  TMaster = class
    private
      FThread: TMyThread;
      procedure OnThreadTerminate(Sender: TObject);
    public
      constructor Create;
      procedure StopThread;
      function StartThread: Boolean;
  end;

constructor TMaster.Create;
begin
  Inherited;
  FThread := Nil;
end;

procedure TMaster.StopThread;
begin
  if Assigned(FThread) then
    FThread.Terminate;
end;

procedure TMaster.OnThreadTerminate(Sender: TObject);
begin
  // Collect data from the thread
  ...
  // Just clear the thread reference
  FThread := Nil;
end;

function TMaster.StartThread: Boolean;
begin
  Result := (FThread = Nil);
  if Result then
  begin
    FThread := TMyThread.Create(True);
    FThread.FreeOnTerminate := True;  // Thread will self destruct
    FThread.OnTerminate := Self.OnThreadTerminate;  // Called when thread is terminating
    FThread.Start; // Older Delphi versions uses Resume
  end;
end;