Neo4j: Match multiple labels (2 or more)

Question

I would like to do a search, and I would like to start traversing from 2 labels (OR condition). For example, I need to find out all the nodes which have labels either 'Male' or 'Female' and whose property, name =~ '.ail.'.

Answer 1

You can put this condition in the WHERE clause:

MATCH (n)
WHERE n:Male OR n:Female
RETURN n

EDIT

As @tbaum points out this performs an AllNodesScan. I wrote the answer when labels were fairly new and expected the query planner to eventually implement it with a NodeByLabelScan for each label, as it does for the single label case

MATCH (n)
WHERE n:Male
RETURN n

I still think this is a reasonable expression of the query and that it is reasonable to expect the query planner to implement it with label scans, but as of Neo4j 2.2.3 the query is still implemented with an AllNodesScan and a label filter. Here is therefore a more verbose alternative. Since the label disjunction signifies a set union and this union can be expressed in different ways, we can express it in a way that the query planner implements without scanning all nodes, and instead starts with a NodeByLabelScan per label.

MATCH (n:Male)
WHERE n.name =~ '.ail.'
RETURN n
UNION MATCH (n:Female)
WHERE n.name =~ '.ail.'
RETURN n

This means expressing the query once for each label and joining them with an explicit UNION. This is not unreasonable, at least for smaller number of labels, but it's not clear to me why the query planners shouldn't be able to infer the same implementation from the simpler query so I have opened a github issue here.

Answer 2

MATCH n WHERE n:Label1 OR n:Label2

... will result in an AllNodesScan this is a bad Idea!

maybe a better solution:

OPTIONAL MATCH (n1:Label1)
WITH collect(distinct n1) as c1

OPTIONAL MATCH (n2:Label2) 
WITH collect(distinct n2) + c1 as c2

OPTIONAL MATCH (n3:Label3) 
WITH collect(distinct n3) + c2 as c3

UNWIND c3 as nodes
RETURN count(nodes),labels(nodes) 

Answer 3

With Neo4j 3.4.7 the query planner does a UNION and then a DISTINCT of 2 NodeByLabelScans when you hand it a WHERE query with 2 OR'ed label filters. Trying the sandbox Offshore Leaks Database with EXPLAIN MATCH (o) WHERE o:Officer OR o:Entity RETURN o yields this planning:

Answer 4

As for v3.5, we can do:

MATCH (n) WHERE (n:User OR n:Admin) AND n.name CONTAINS "ail" RETURN n

and get:

╒══════════════════╕
│"n"               │
╞══════════════════╡
│{"name":"Abigail"}│
├──────────────────┤
│{"name":"Bailee"} │
└──────────────────┘

Answer 5

If you want to filter node by multiple labels with OR or IN condition, use this code:

MATCH (n)
WHERE labels(n) in [['Male'],['Female']]
AND n.name =~ '.ail.'
RETURN n

Answer 6

There is a dedicated way to match on multiple labels now (in 2023).

This will only work on Neo4j 5 and higher.

MATCH (n:Movie|Person) RETURN n.name AS name, n.title AS title

As per the docs found here.

To solve your specific query:
MATCH (n:User|Admin) WHERE n.name CONTAINS "ail" RETURN n

Answer 7

Another option, if you need to work with the combined set or otherwise avoid the UNION:

MATCH(m:Male) WHERE m.name=~'.ail.' WITH COLLECT(m) AS male 
MATCH(f:Female) WHERE f.name=~'.ail.' WITH male, COLLECT(f) AS female
UNWIND (male + female) AS person 
RETURN person.name;

This is not quite as efficient as the UNION approach, but still avoids the expensive AllNodesScan operator. In my use case, the query already contains a UNION for a different purpose.

Answer 8

Documentation for v3.0 says this:

One can also describe a node that has multiple labels:

(a:User:Admin)-->(b)

Source: https://neo4j.com/docs/developer-manual/current/cypher/#_labels