Looping over lists in cf9

Question

Page 116 of the developer's guide says "Unlike the cfloop tag, CFScript for-in loops do not provide built-in support for looping over queries and lists."

Q: How do I loop over a list using the new script syntax in ColdFusion 9?

<cfloop list="#qry.Columnlist#" index="FieldName">
   <cfset form[FieldName] = qry[FieldName][1]>
</cfloop>

Adam Cameron has put together a fantastic resource at https://github.com/daccfml/cfscript/blob/master/cfscript.md — Phillip Senn, Nov 06 '14 at 17:46

score 18 · Accepted Answer · answered Mar 29 '11 at 14:38

18

You can also try the listToArray and then use the for-in construct for Arrays in CF9 as:

<cfscript>
aCol = listToArray (qry.ColumnList);

for( fieldName in aCol ){
    form[fieldName]  = qry[fieldName][1];
}

</cfscript>

answered Mar 29 '11 at 14:38

Lostlinkpr

1,453
2
12
13

5

Note that this works but only with Update 1 installed. The original CF9 will give an error since for-in was only allowed on struct's. – DaveBurns Apr 21 '11 at 18:12
1

Is the intermediate variable `aCol` necessary in this example? Wouldn't `for(fieldName in ListToArray(qry.ColumnList))` be cleaner (less scope pollution)? – Jared Beck Sep 02 '13 at 21:38
Will it create additional array variable, that implicates additional memory allocation? Does that mean that cfloop tag is more efficient than doing such stuff in cfscript? I am asking this because I want to persuade team to use cfscript, but they giving this point as a disadvantage. – wyxa Sep 29 '15 at 15:00

score 12 · Answer 2 · edited Oct 26 '11 at 21:20

12

<cfscript>
  var i = 0;
  var l = ListLen(qry.Columnlist);
  var FieldName = "";
  for (i = 1; i lte l; i = i + 1)  // you also can use i++ instead
  {
    FieldName = ListGetAt(qry.Columnlist, i);
    form[FieldName] = qry[FieldName][1];
  }
</cfscript>

EDIT Nicer (maybe a even little faster, for really heavy loops) version of the above:

<cfscript>
  var i = 0;
  var Fields = ListToArray(qry.Columnlist);
  var FieldName = "";
  var l = arrayLen(Fields);
  for (i = 1; i lte l; i = i + 1)  // you also can use i++ instead
  {
    FieldName = Fields[i];
    form[FieldName] = qry[FieldName][1];
  }
</cfscript>

edited Oct 26 '11 at 21:20

jfrobishow

2,897
2
27
42

answered Jan 07 '10 at 14:14

Tomalak

332,285
67
532
628

Slightly shorter form: for (i = 1; i <= qry.RecordCount; i++) {} – Sergey Galashyn Jan 07 '10 at 14:45
1

@Sergii: That's the whole point - it's not about the `RecordCount`, but about the length of the `ColumnList`. ;-) – Tomalak Jan 07 '10 at 16:13

score 5 · Answer 3 · answered Jan 07 '10 at 19:37

5

I would turn the list into an array first. ListGetAt() is not efficient to be called n times in a loop. ArrayLen() however should be quite fast.

<cfscript>
arr = ListToArray(qry.Columnlist);

for (i = 1; i <= ArrayLen(arr); i++)
{
    fieldName = arr[i];
    form[FieldName] = qry[FieldName][1];
}
</cfscript>

answered Jan 07 '10 at 19:37

Henry

32,689
19
120
221

wouldn't it also be faster to call ArrayLen just once and store it in a variable? – Dave DuPlantis Apr 18 '11 at 16:17
yes it would. Just wanna keep the code segment small and neat – Henry Apr 18 '11 at 18:04
that makes sense ... and it's more readable using `fieldName` than `arr[i]`. – Dave DuPlantis Apr 18 '11 at 18:07
I'd probably use a `for(element in array)` loop here, Henry. You only need the index value here to get the element, so you might as well not bother with it. – Adam Cameron Sep 18 '14 at 13:15
@AdamCameron... it was answered back in 2010 and I doubt for-in loop for array was mature or even existed. :) – Henry Sep 18 '14 at 20:55
ColdFusion 9? Sure they did. And I wouldn't've suggested it if it wasn't an appropriate suggestion. – Adam Cameron Sep 19 '14 at 07:38
1

@AdamCameron see DaveBurns comment with 3 up votes on the other answer. – Henry Sep 19 '14 at 15:51

Looping over lists in cf9

3 Answers3