How do I pass parameters to the File::Find subroutine that processes each file?

Question

Using File::Find, how can I pass parameters to the function that processes each file?

I have a Perl script that traverses directories in order to convert some 3-channel TIFF files to JPEG files (3 JPEG files per TIFF file). This works, but I would like to pass some parameters to the function that processes each file (short of using global variables).

Here is the relevant part of the script where I have tried to pass the parameter:

use File::Find;

sub findFiles
{
    my $IsDryRun2 = ${$_[0]}{anInIsDryRun2};
}

find ( { wanted => \&findFiles, anInIsDryRun2 => $isDryRun }, $startDir);

$isDryRun is a scalar. $startDir is a string, full path to a directory.

$IsDryRun2 is not set:

Use of uninitialized value $IsDryRun2 in concatenation (.) or string at TIFFconvert.pl line 197 (#1) (W uninitialized) An undefined value was used as if it were already defined. It was interpreted as a "" or a 0, but maybe it was a mistake. To suppress this warning assign a defined value to your variables.

(The old call without parameters was: find ( \&findFiles, $startDir); )

Test platform (but the production home will be a Linux machine, Ubuntu 9.1, Perl 5.10, 64 bit): ActiveState Perl 64 bit. Windows XP. From perl -v: v5.10.0 built for MSWin32-x64-multi-thread Binary build 1004 [287188] provided by ActiveState.

score 16 · Accepted Answer · answered Jan 13 '10 at 12:52

16

You need to create a sub reference that calls your wanted sub with the desired parameters:

find( 
  sub { 
    findFiles({ anInIsDryRun2 => $isDryRun });
  },
  $startDir
);

This is, more-or-less, currying. It's just not pretty currying. :)

answered Jan 13 '10 at 12:52

hobbs

223,387
19
210
288

Thanks, it worked. Is the first semicolon required (third line)? – Peter Mortensen Jan 13 '10 at 13:05
You don't need the that semicolon, but it doesn't hurt to have it there. – brian d foy Jan 13 '10 at 14:06
@hobbs => i've always liked the way Perl handles currying with anonymous subs. what would be pretty to you? – Eric Strom Jan 16 '10 at 02:42
`sub curry { my ($sub, @args) = @_; sub { $sub->(@args, @_) } }` – ikegami Mar 04 '18 at 19:50

score 3 · Answer 2 · answered Feb 02 '10 at 12:01

3

You can create any sort of code reference you like. You don't have to use a reference to a named subroutine. For many examples of how to do this, see my File::Find::Closures module. I created that module to answer precisely this question.

answered Feb 02 '10 at 12:01

brian d foy

129,424
31
207
592

score 3 · Answer 3 · edited Jul 15 '12 at 18:44

3

See the PerlMonks entry Why I hate File::Find and how I (hope I) fixed it describing how to do it with closures.

edited Jul 15 '12 at 18:44

Peter Mortensen

30,738
21
105
131

answered Jan 08 '12 at 16:09

rjha94

4,292
3
30
37

score 0 · Answer 4 · edited Mar 04 '18 at 13:29

#
# -----------------------------------------------------------------------------
# Read directory recursively and return only the files matching the regex
# for the file extension. Example: Get all the .pl or .pm files:
#     my $arrRefTxtFiles = $objFH->doReadDirGetFilesByExtension ($dir, 'pl|pm')
# -----------------------------------------------------------------------------
sub doReadDirGetFilesByExtension {
     my $self = shift;    # Remove this if you are not calling OO style
     my $dir  = shift;
     my $ext  = shift;

     my @arr_files = ();
     # File::find accepts ONLY single function call, without params, hence:
     find(wrapp_wanted_call(\&filter_file_with_ext, $ext, \@arr_files), $dir);
     return \@arr_files;
}

#
# -----------------------------------------------------------------------------
# Return only the file with the passed extensions
# -----------------------------------------------------------------------------
sub filter_file_with_ext {
    my $ext     = shift;
    my $arr_ref_files = shift;

    my $F = $File::Find::name;

    # Fill into the array behind the array reference any file matching
    # the ext regex.
    push @$arr_ref_files, $F if (-f $F and $F =~ /^.*\.$ext$/);
}

#
# -----------------------------------------------------------------------------
# The wrapper around the wanted function
# -----------------------------------------------------------------------------
sub wrapp_wanted_call {
    my ($function, $param1, $param2) = @_;

    sub {
      $function->($param1, $param2);
    }
}

You might want to add an explanation for the sample code. And perhaps sample usage of the 3 functions. — Peter Mortensen, Mar 04 '18 at 14:21
IMHO the func comments suffice + the usage is shown for the doReadDirGetFilesByExtension func. I really think that if a user does not get what those func do by this comments and description than probably he/she should not use this code as he/she might lose more time adjusting it for his/her needs compared to figuring out a solution for his/her problem in another way - TMTOWTDI ... — Yordan Georgiev, Mar 04 '18 at 14:35

How do I pass parameters to the File::Find subroutine that processes each file?

4 Answers4

Linked

Related