1

I asked the question Send email from clipboard without opening mail.app and got the code

set a to "myemail@mail.com"
tell application "Mail"
    tell (make new outgoing message)
        set subject to (the clipboard)
        set content to "content"
        make new to recipient at end of to recipients with properties {address:a}
        send
    end tell
end tell

now I wonder, how could I have a script that do the same thing, but modifies it like this: if the Subject is the first 10 words, and iff the clipboard har more than 10 words, then the clipboard is cut off. For example like this "hello there baby this is a long message sent with... [see notes]" and then the enitre message (i.e. "hello there baby this is a long message sent with my new email, see you.") is in the content of the email.

Community
  • 1
  • 1
jacob
  • 810
  • 3
  • 9
  • 19

1 Answers1

2

Replace the set subject ... and set content ... lines in your script with the following:

if (count of words of (the clipboard)) is greater than 10 then
    set oldDelims to AppleScript's text item delimiters
    set AppleScript's text item delimiters to " "
    set subject to ((words 1 through 10 of (the clipboard)) & "... [see notes]") as text
    set AppleScript's text item delimiters to oldDelims
    set content to (the clipboard)
else
    set subject to (the clipboard)
    set content to "content"
end if

Links to references:

@adayzdone has a good point - sometimes using words of to split a string to a list then reassembly with text item delimiters can mess up the input data. You could do this instead:

set oldDelims to AppleScript's text item delimiters
set AppleScript's text item delimiters to " "
set cblist to text items of (the clipboard)
set AppleScript's text item delimiters to oldDelims

if (count of cblist) is greater than 10 then
    set oldDelims to AppleScript's text item delimiters
    set AppleScript's text item delimiters to " "
    set subject to ((items 1 through 10 of cblist) & "... [see notes]") as text
    set AppleScript's text item delimiters to oldDelims
    set content to (the clipboard)
else
    set subject to (the clipboard)
    set content to "content"
end if
Digital Trauma
  • 15,475
  • 3
  • 51
  • 83
  • You don't need to use text item delimiters. – adayzdone Dec 23 '13 at 05:38
  • @adayzdone - Why not? If I coerce `(words of ) as text` without setting the delimiter to " ", then the words are concatenated without any spaces in between. – Digital Trauma Dec 23 '13 at 17:44
  • I read it too quickly. Although I see why you used tid, your script will have problems with a subject such as "Please wire some $$$ to 1-212-555-3333" – adayzdone Dec 25 '13 at 04:07