Batch file assignment woes

Question

The following simple batch file doesn't work as expected. It's meant to accept an argument, and if none is supplied, it uses a default value ("default", in this case).

Instead, if there is no argument supplied, it assigns an empty string to the variable Arg.

Test.bat:

@echo off
set Arg=%1
if "%Arg%"=="" (
    set Arg=Default
    echo No Arg, so use default value=%Arg%
) else (
    echo Arg=%Arg%
)
pause

The output of Test.bat is:

No Arg, so use default value=
Press any key to continue . . . 

Answer 1

Use

setlocal enabledelayedexpansion

and then !Arg! instead of %Arg% within the block. And read help set which explains all this.

Answer 2

Try

@echo off
set Arg=%1
if not defined arg set Arg=Default&echo No Arg, so use default
echo Arg=%Arg%

The problem is that within a block (parenthesisied series of statements) variables are resolved at PARSE time - before the instructions are executed.

@echo off
set Arg=%1
if not defined arg set Arg=Default&call echo No Arg, so use default=%%arg%%
echo Arg=%Arg%

if you really want the default to be displayed on the report line.

Answer 3

@echo off

if [%1] == [] (
   set Arg=Default
) else (
   set Arg=%1
)
@echo Arg=%Arg%

Reference: How to check command line parameter in ".bat" file?

Answer 4

@echo off
set arg=default
if not "%~1"=="" set "arg=%~1"
echo arg is ""%arg%"