Getting AD Details based on username

Question

I have a code to retrieve the details of a user from the AD such as email address, phone number etc, etc. The codes I am currently using is:

Set objSysInfo = CreateObject("ADSystemInfo")
strUser = objSysInfo.UserName
msgbox(strUser)
Set objUser = GetObject("LDAP://" & strUser)

It gets the currently logged in user's details. But what I need to do now is to parse in the user's username and retrieve the details based on that.

I have tried to change objSysinfo.UserName to the username and it returned blank.

Set objSysInfo = CreateObject("ADSystemInfo")
strUser = "SomeUserName"
msgbox(strUser)
Set objUser = GetObject("LDAP://" & strUser)

How should I go about retrieving the details from the AD based on a user name provided?

Ansgar Wiechers · Accepted Answer · 2020-10-23T06:45:27.147

22

LDAP URIs require a distinguished name. Account names won't work. If you want to get user objects based on the account name you need a "regular" LDAP query:

username = "SomeUserName"

Set rootDSE = GetObject("LDAP://RootDSE")
base  = "<LDAP://" & rootDSE.Get("defaultNamingContext") & ">"
'filter on user objects with the given account name
fltr  = "(&(objectClass=user)(objectCategory=Person)" & _
        "(sAMAccountName=" & username & "))"
'add other attributes according to your requirements
attr  = "distinguishedName,sAMAccountName"
scope = "subtree"

Set conn = CreateObject("ADODB.Connection")
conn.Provider = "ADsDSOObject"
conn.Open "Active Directory Provider"

Set cmd = CreateObject("ADODB.Command")
Set cmd.ActiveConnection = conn
cmd.CommandText = base & ";" & fltr & ";" & attr & ";" & scope

Set rs = cmd.Execute
Do Until rs.EOF
  WScript.Echo rs.Fields("distinguishedName").Value
  rs.MoveNext
Loop
rs.Close

conn.Close

Since I got annoyed from having to write all that boilerplate code over and over again, I wrapped it in a class (ADQuery) some time ago.

edited Oct 23 '20 at 06:45

answered Jan 14 '14 at 12:28

Ansgar Wiechers

193,178
25
254
328

it works very well! Thank you so much! So is this a query that retrieves from the AD's database? – LuxuryWaffles Jan 15 '14 at 06:22
@BloopieBloops Correct. – Ansgar Wiechers Jan 15 '14 at 08:46
I recently found a coder with a Github site that had a make command for constructing Excel files that contained VBA. It was impressive. My workplace security won't allow me to save your .vba file to my hard drive or rename it. Is there a chance you can post your library to Github or something similar? – Rick Henderson Nov 20 '18 at 19:32
2

@RickHenderson I'll think about it. – Ansgar Wiechers Nov 20 '18 at 22:22

score 3 · Answer 2 · answered Nov 06 '17 at 21:29

Just an extra comment to Ansgar the RootDSE is great if you only have one domain. You can modify his code to point else where:

    base  = "<LDAP://" & rootDSE.Get("defaultNamingContext") & ">"

to something like:

    base  = "<LDAP://" & "DC=corp,DC=foo,DC=com" & ">"

if your domain AD domain is corp.foo.com

Getting AD Details based on username

2 Answers2

Linked