How can I read blobfield without freezing?

Question

I want to read blobfield (with blobstream) from client side (over network) but application freezes while fetching data. How can I read blobfield without freezing and showing percentage with a progressbar. (I'm using Delphi and Firebird)

i'm using uniquery component. i've found this code from: http://forums.devart.com/viewtopic.php?t=14629

but it doesn't work properly:

const
BlockSize= $F000;
var
Blob: TBlob;
Buffer: array of byte;
p: pointer;
pos, count: integer;

  UniQuery1.SQL.Text:= 'select * from TABLE1 where FIELD_ID = 1';
  UniQuery1.Open;

  blob:= uniquery1.GetBlob('DATA');
  SetLength(buffer, blob.Size);
  ProgressBar1.Position:= 0;
  Application.ProcessMessages;

 repeat
  count:= Blob.Read(pos, blocksize, p);
  ProgressBar1.Position:= Round(pos/Blob.Size * 100);
  pos:= pos + count;
  p:= pointer(integer(p) + count);
  Application.ProcessMessages;
 until count < blocksize;

PS: i've set uniquery's options:

cacheblobs:= false;
streamedblobls:= true;
deferredblobread:= true;

in the first step of repeat-until loop, Blob.Read method reads all of stream, so it doesnt work properly.

I would make a `TBlobStream` descendant with progress reporting capability and as @whosrdaddy said, put your DB stuff into a separate worker thread. — TLama, Jan 17 '14 at 08:46
Related: http://stackoverflow.com/questions/14215248/anything-else-i-can-use-to-keep-program-responsive-besides-processmessage — Jens Mühlenhoff, Jan 17 '14 at 09:48

Jens Mühlenhoff · Answer 1 · 2014-01-18T08:57:58.827

You should use a thread, here is an example with Delphi TThread:

type
  TMyForm = class(TForm)
  private
    FPosition: Integer;
    procedure ProgressUpdate;
    procedure Execute;
  end;

procedure TMyForm.ProgressUpdate;
begin
  ProgressBar1.Position := FPosition;
end;

procedure TMyForm.Execute;
begin
  FPosition:= 0;
  ProgressUpdate;
  Thread := TThread.CreateAnonymousThread(procedure
    begin
      repeat
        // Do some long running stuff (in chunks, so we can update the position)
        FPosition := CalculatePosition;
        // Important: Synchronize will run ProgressUpdate in the main thread!
        TThread.Synchronize(nil, ProgressUpdate); 
      until SomeCondition;
    end
  );
  Thread.Start;
end;

So after applying this pattern to your code we get:

type
  TMyForm = class(TForm)
  private
    FPosition: Integer;
    procedure ProgressUpdate;
    procedure Execute;
  end;

procedure TMyForm.ProgressUpdate;
begin
  ProgressBar1.Position := FPosition;
end;

procedure TMyForm.Execute;
var
  Blob: TBlob;
  Thread: TThread;
begin
  UniQuery1.SQL.Text := 'SELECT * FROM TABLE1 WHERE FIELD_ID = 1';
  UniQuery1.Open;
  Blob := UniQuery1.GetBlob('DATA');

  FPosition:= 0;
  ProgressUpdate;
  Thread := TThread.CreateAnonymousThread(
    procedure
    const
      BlockSize = $F000;
    var
      Buffer: array of Byte;
      P: Pointer;
      Pos, Count: Integer;
    begin
      SetLength(Buffer, Blob.Size);
      repeat
        Count := Blob.Read(Pos, BlockSize, P);
        FPosition := Round(Pos / Blob.Size * 100);
        Pos := Pos + Count;
        P := Pointer(Integer(P) + Count);
        // Important: Synchronize will run ProgressUpdate in the main thread!
        TThread.Synchronize(nil, ProgressUpdate); 
      until Count < BlockSize;
    end
  );
  Thread.Start;
end;

I removed the Application.ProcessMessage and moved all processing to the thread.

The Thread is setting the FPosition private attribute and uses TThread.Synchronize to set the ProgressBar position to FPosition in the main thread.

If your block size is not big enough this might still block the UI (due to excessive synchronization), so choose an appropriate block size or add some update delay.

You have to make sure that the connection of the UniQuery1 object is not used in the main thread while the anonymous thread is running or move the connection and query to the thread as well.

Also this can have reentrance problems, but it should give you a basic idea of how to use a thread for background processing.

PS: It might also be a good idea to run the query in the thread, especially if it can take some time.

sorry, i'm not good at threads, on TThread.Synchronize(ProgressUpdate); line it gives error: E2389 Protected member 'TThread.Synchronize' is inaccessible here. — user3205651, Jan 17 '14 at 19:52
`TThread.Synchronize(nil, ProgressUpdate)` should work. See [`TThread.Synchronize`](http://docwiki.embarcadero.com/Libraries/en/System.Classes.TThread.Synchronize). `Note: When using the static version of the Synchronize method with nil/NULL as a first parameter, it will synchronize the method referenced by AMethod within the main thread.` — LU RD, Jan 17 '14 at 22:31
That is correct (fixed). Sorry I did not test this, but I only wanted to give you the right pattern. — Jens Mühlenhoff, Jan 18 '14 at 08:59
You should also mind my warning about too many progress updates. — Jens Mühlenhoff, Jan 18 '14 at 09:01
@user3205651 You should spend some time to learn about threads, every good programmer should know about background processing. — Jens Mühlenhoff, Jan 18 '14 at 09:03

How can I read blobfield without freezing?

1 Answers1