Delete Row from Array

Question

I am trying to go through an array to find duplicate entries in a single column of that array and delete the entire row.

I am getting figuring out rangeStart, rangeEnd, and lastrow above this and that part is working fine.

data = Range(rangeStart, rangeEnd)

For i = lastrow - 1 To 2 Step -1
    If data(i - 1, x) = data(i, x) Then
        'Delete data(i)
    End If
Next

Any help with this would be awesome!

Easier to create a second empty array of the same size and copy only unique "rows" over. — Tim Williams, Jan 31 '14 at 16:14

Tim Williams · Accepted Answer · 2014-01-31T19:18:45.020

3

Sub RemoveDups()
Const COMPARE_COL as Long = 1
Dim a, aNew(), nr As Long, nc As Long
Dim r As Long, c As Long, rNew As Long
Dim v As String, tmp

    a = Selection.Value
    nr = UBound(a, 1)
    nc = UBound(a, 2)

    ReDim aNew(1 To nr, 1 To nc)
    rNew = 0
    v = Chr(0)

    For r = 1 To nr
        tmp = a(r, COMPARE_COL)
        If tmp <> v Then
            rNew = rNew + 1
            For c = 1 To nc
                aNew(rNew, c) = a(r, c)
            Next c
            v = tmp
        End If
    Next r

    Selection.Value = aNew

End Sub

edited Jan 31 '14 at 19:18

answered Jan 31 '14 at 18:26

Tim Williams

154,628
8
97
125

Thanks! This seems to do what I need it to do! – CongdonJL Jan 31 '14 at 19:33

score 0 · Answer 2 · answered Jan 31 '14 at 15:56

0

Does this help?:

If data(i - 1, x) = data(i, x) Then
    data(i,x).EntireRow.Delete
End If

answered Jan 31 '14 at 15:56

hstay

1,439
1
11
20

Getting a Subscript out of range – CongdonJL Jan 31 '14 at 16:13
`lastrow` should be equal to `(rangeEnd.row - rangeStart.row)` – hstay Jan 31 '14 at 16:38
4

@hstay - OP is not looping through a range (note there is no `Set` where they assign the range to `data`, so that line creates a 2-D array from the range values) – Tim Williams Jan 31 '14 at 17:12
Thanks, @TimWilliams, I was blindfolded after seing Range(). – hstay Feb 03 '14 at 09:36

score 0 · Answer 3 · answered Feb 02 '14 at 01:57

Why not use Excel's inbuilt Unique options (Data ... Remove Duplicates)?

Another efficient VBA method is to use a Dictionary.

Sub A_Unique_B()

Dim X
Dim objDict As Object
Dim lngRow As Long

Set objDict = CreateObject("Scripting.Dictionary")
X = Application.Transpose(Range([a1], Cells(Rows.Count, "A").End(xlUp)))

For lngRow = 1 To UBound(X, 1)
    objDict(X(lngRow)) = 1
Next

Range("B1:B" & objDict.Count) = Application.Transpose(objDict.Keys)
End Sub

Delete Row from Array

3 Answers3

Linked