Batch file For Loops with 2 arrays

Question

I wish to have the for loop in my batch file to iterate 2 arrays. The pseudo code in my mind is something like below:

for each i in array1 
 print i
 print array2[x++]

array1 and array2 will have the same size.

Will I be able to achieve the same result in batch file? I currently have the following code.

for %%i in %APP_LIST1% DO (
    %appcmd% add app /site.name:%siteName% /path:/%%i /physicalPath:"d:\Apps\%%i"
)

I would like to use %APP_LIST2% (aka array2) in the same for loop as well.

Help please!

What is the format of `APP_LIST1`, could you post some of it? — unclemeat, Mar 07 '14 at 01:59
Do you just want to do the same thing for both arrays, or do you want to do something different to the values in `APP_LIST2`? — unclemeat, Mar 07 '14 at 02:01

score 1 · Accepted Answer · edited May 23 '17 at 12:10

I am afraid I don't really understand what is your concern about the second array. If you can access one array, you can access any number of arrays in the same way...

Please, note that an array is a "collection of data items that can be selected by indices computed at run-time" as defined in Wikipedia. This way, you may use the same index used in the first array to access the second one; this should work in your case because "array1 and array2 will have the same size".

For example:

@echo off
setlocal EnableDelayedExpansion

rem Create first array
set i=0
for %%a in (apple orange pear) do (
   set /A i+=1
   set fruit[!i!]=%%a
)

rem Create second array
set i=0
for %%a in (red green blue) do (
   set /A i+=1
   set color[!i!]=%%a
)

rem Access both arrays at same time
for /L %%i in (1,1,3) do (
   echo Fruit: !fruit[%%i]!, color: !color[%%i]!
)

For further details on array management in Batch files, see: this post.

Batch file For Loops with 2 arrays

1 Answers1