How can I check if a variable is empty or not in tcsh Shell?

Question

IF I have to check that if a variable is empty or not for that in bash shell i can check with the following script:

if [ -z "$1" ] 
then
    echo "variable is empty"
else 
    echo "variable contains $1"
fi

But I need to convert it into tcsh shell.

[Are you sure you should convert it to `tcsh`?](http://www.grymoire.com/unix/CshTop10.txt) — chepner, Mar 25 '14 at 16:10
Tcsh is not suitable for programming, but try this: `if ("x$1" == "x")`. — n. m. could be an AI, Mar 25 '14 at 16:11
That is not an answer to the question asked. The question was TCSH. — Doug Royer, Apr 07 '20 at 17:59

mklement0 · Accepted Answer · 2020-07-01T21:04:52.810

The standard warnings regarding use of tcsh/csh apply (don't use it for scripting, due to its inherent limitations), but here's the translation:

if ( "$1" == "" ) then      # parentheses not strictly needed in this simple case
    echo "variable is empty"
else 
    echo "variable contains $1"
endif

Note, though, that if you were to use an arbitrary variable name rather than $1 in the above, the statement would break if that variable weren't defined yet (whereas $1 is always defined, even if unset).

To plan for the case where a variable, say $var, may not be defined, it gets tricky:

if (! $?var) then       
  echo "variable is undefined"
else
  if ("$var" == "")  then
      echo "variable is empty"
  else 
      echo "variable contains $var"
  endif
endif

The nested ifs are required to avoid breaking the script, as tcsh apparently doesn't short-circuit (an else if branch's conditional will get evaluated even if the if branch is entered; similarly, both sides of && and || expressions are seemingly always evaluated - this applies at least with respect to use of undefined variables).

score 2 · Answer 2 · edited Jun 20 '18 at 23:23

2

You can try this (found here):

set name
if ( ${%name} == 0 ) then
        echo " Variable name has 0 characters as value."
endif

Note that the person who posted this has the following signature:

Standard advice: avoid csh family for scripting.

Note: This will break if name is an environment variable.

setenv name foobar ; set name ; echo '+++'$name'+++' ; unset name ; echo '==='$name'==='

++++++
===foobar===

edited Jun 20 '18 at 23:23

Community

1
1

answered Mar 25 '14 at 16:12

Tom Fenech

72,334
12
107
141

The second part of this answer was an edit suggested by an anonymous user, which seems to be about variables masking environment variables with the same name. I'm not really sure that it is relevant to the question but I'm leaving it here in case it is useful to someone. – Tom Fenech Jun 21 '18 at 09:56

DrGC · Answer 3 · 2017-01-20T18:39:13.870

0

EDIT: see comment below.

if ( $?1 ) then
    echo "variable is empty"
else 
    echo "variable contains $1"
endif

edited Jan 20 '17 at 18:39

answered Jan 19 '17 at 19:04

DrGC

168
1
5

1

You have the condition backwards. The behavior of `$?1` seems different from the behavior of `$?foo`; it appears that `$1` is always set, even if no corresponding argument was passed (which is why your solution works if you reverse the condition). `csh`, as opposed to `tcsh`, doesn't permit `$?1`. – Keith Thompson Jan 20 '17 at 16:58
oops, yes, you are right. Although i get the same also for tcsh, $?! always defined. – DrGC Jan 20 '17 at 18:33

How can I check if a variable is empty or not in tcsh Shell?

3 Answers3

Linked