Change CheckBox state without calling OnClick Event

Question

I'm wondering so when I change state of CheckBox

CheckBox->Checked=false;

It calls CheckBoxOnClick Event , how to avoid it ?

By using a tButton with a ✓ at the .text property. The height and width 25x25 so it looks like a checkbox. Start with .text empty. When the button is pressed the label is changed to a ✓. onClick can test if the label is empty or a ✓ mark. Using an if mylabel.text = '' then ...change the text to the ✓ else mylabel.text:='✓'; Thats it. Anywhere else in your code you can read the mylabel.text value to see if its ✓ or not. I have found that when using a stylebook there is no way around, for me to have the checkbox in an unchecked state on form.create. Good solution and I hope it helps you. — Winston, Apr 29 '23 at 20:34

yonojoy · Answer 1 · 2016-06-01T14:42:11.887

In newer Delphi versions you can use class helpers to add this functionality:

CheckBox.SetCheckedWithoutClick(False);

by using the following class helper for a VCL TCheckBox:

TCheckBoxHelper = class helper for TCheckBox
    procedure SetCheckedWithoutClick(AChecked: Boolean);
end;

procedure TCheckBoxHelper.SetCheckedWithoutClick(AChecked: Boolean);
begin
    ClicksDisabled := True;
    try
        Checked := AChecked;
    finally
        ClicksDisabled := False;
    end;
end;

Just for completeness: A FMX TCheckBox will behave similar (triggering OnChange). You can workaround this by using the following class helper:

TCheckBoxHelper = class helper for TCheckBox
    procedure SetCheckedWithoutClick(AChecked: Boolean);
end;

procedure TCheckBoxHelper.SetCheckedWithoutClick(AChecked: Boolean);
var
    BckEvent: TNotifyEvent;
begin
    BckEvent := OnChange;
    OnChange := nil;
    try
        IsChecked := AChecked;
    finally
        OnChange := BckEvent;
    end;
end;

Disclaimer: Thanks, dummzeuch for the original idea. Be aware of the usual hints regarding class helpers.

It is just what I was looking for !! Thanks – KryNaC Jan 30 '17 at 09:01 — KryNaC, Jan 30 '17 at 09:01

score 10 · Accepted Answer · answered Feb 15 '10 at 07:18

10

You could surround the onClick event code with something like

if myFlag then
  begin
    ...event code...
  end;

If you don't want it to be executed, set myFlag to false and after the checkbox state's change set it back to true.

answered Feb 15 '10 at 07:18

Holgerwa

3,430
9
42
50

yes ... :-S that's really easy. Don't know why I didn't made it myself >_ – cnd Feb 15 '10 at 07:35

score 10 · Answer 3 · answered Feb 15 '10 at 07:57

Another option is to change the protected ClicksDisable property using an interposer class like this:

type
  THackCheckBox = class(TCustomCheckBox)
  end;

procedure TCheckBox_SetCheckedNoOnClick(_Chk: TCustomCheckBox; _Checked: boolean);
var
  Chk: THackCheckBox;
begin
  Chk := THackCheckBox(_Chk);
  Chk.ClicksDisabled := true;
  try
    Chk.Checked := _Checked;
  finally
    Chk.ClicksDisabled := false;
  end;
end;

score 7 · Answer 4 · answered Feb 15 '10 at 07:02

7

I hope there's a button solution but you could store the current event in a TNotifyEvent var, then set Checkbox.OnChecked to nil and afterwards restore it.

answered Feb 15 '10 at 07:02

Remko

7,214
2
32
52

CheckBox->Checked=false is on button but it even calls onClick event. So I'll try it. Thank you. – cnd Feb 15 '10 at 07:09

score 4 · Answer 5 · edited Oct 07 '17 at 08:37

4

try this way:

Checkbox.OnClick := nil;
try
  Checkbox.Checked := yourFlag;
finally
  Checkbox.OnClick := CheckboxClick;
end;

edited Oct 07 '17 at 08:37

saastn

5,717
8
47
78

answered Mar 28 '16 at 10:50

oakrom

59
1
7

Worked for me. It seems to be the easiest solution. – felipeaf May 08 '19 at 20:02

score 2 · Answer 6 · answered Jan 27 '21 at 22:16

2

Use the focused property to establish if the control has been clicked or the checked has been updated outside the control.

If tcheckbox.focused then

 run the content of the method

else

skip the content

answered Jan 27 '21 at 22:16

OVACH

21
3

score 1 · Answer 7 · answered May 20 '20 at 16:06

Some other and much easier solution is not avoiding the the OnClick event but modifying the event handler not to respond unless the DataSet.State is in either dsEdit or dsInsert as initiated by a user triggered TDBCheckBox click e.g.:

procedure TForm1.chkSelectClick(Sender: TObject);
begin
  if chkSelect.Checked = True then
    if DataSource1.DataSet.State in [dsEdit,dsInsert] then
      begin
        { your event handler }
      end;
end;

score -1 · Answer 8 · answered May 18 '17 at 06:19

-1

Simple solution is to put your onclick code in onmouseup event;

answered May 18 '17 at 06:19

Aleksandar

9

score -1 · Answer 9 · answered Oct 11 '11 at 13:47

-1

CheckBox.State := cbUnchecked; works in Delphi, this doesn't fire onClickEvent AFAIK

answered Oct 11 '11 at 13:47

Andik

129
1
5

I thought so but tried it in XE7 and setting State to CBChecked or CBUnchecked fires the OnClickEvent. – David Bolton Sep 09 '21 at 09:12

Change CheckBox state without calling OnClick Event

9 Answers9

Linked