Windows Batch Iterating CSV list and selecting from second list

Question

I have a list of projects and a list of project types. I need to iterate over the list of project types and every time the selected project type equals a certain value I need to get the I^th entry from the project names. For example:

Project Names: Project1,Project2,Project3

Project Types: web,ssis,ssis

I need all the "ssis" projects so the resulting list should be "Project2,Project3".

I've used for /f a lot but I don't know how to get the "i" in the "for" iteration so I can select the related entry from the second list. I've searched on this and gone down into the weeds on "for" but can't seem to come up with an answer.

If there's a method that works better than "for" I'm game. If there's a way to use "for" on the first list and pull the related entries out of the second list that would be great too.

Any help is greatly appreciated.

Answer 1

Based off a now-deleted comment:

@ECHO OFF

SET projlist=Project1,Project2,Project3
SET projtypes=web,ssis,ssrs
SET /a ptr=1

SETLOCAL ENABLEDELAYEDEXPANSION

FOR %%a IN (%projtypes%) DO (
  ECHO %%a
  SET index=1
  FOR %%b IN (%projlist%) DO (
    IF !index!==!ptr! ECHO %%b
    SET /A index+=1
  )
  SET /a ptr=ptr+1
  ECHO ----------------
)
ENDLOCAL

Running this will give this result:

web
Project1
----------------
ssis
Project2
----------------
ssis
Project3
----------------

Of course, you'll need to modify it to fit your exact needs.

Answer 2

If I understand it correctly, you want to group all project names that belongs to the same project type and show the result as a list of groups. I taken the answer of this post, that do a match of the elements of two lists, and modified it in order to get the groups you want:

@echo off
setlocal EnableDelayedExpansion

set ProjectNames=Project1,Project2,Project3
set ProjectTypes=web,ssis,ssis

rem Group project names by type
set i=0
for %%A in (%ProjectTypes%) do (
   set /A i+=1, j=0
   for %%B in (%ProjectNames%) do (
      set /A j+=1
      if !i! equ !j! set NamesByType[%%A]=!NamesByType[%%A]!,%%B
   )
)

rem Show result
for /F "tokens=2,3 delims=[]=" %%a in ('set NamesByType[') do (
   set list=%%b
   echo Type %%a: !list:~1!
)

Output:

Type ssis: Project2,Project3
Type web: Project1

You may also consult a particular element of NamesByType array, for example:

echo %NamesByType[ssis]%