Gradle global build directory

Question

I want to know is it possible to configure Gradle to use one global build directory for all projects? I need this because I store all my projects in Google Drive folder (for backup and fast access from other devices) and when I build project Google Drive is loading CPU while syncing project build directory. So I want to move build directories outside of Google Drive.

Also this option will be useful for those who want to build projects using RAM disk as storage for build directory.

@PaulVerest May be. But now I do not store projects in any cloud storage and use global build directory only for build process boosting and for fast cleanup. — mixel, Mar 18 '15 at 09:00
@madhead I use Git :) I stored my projects in Google Drive as backup option and to have fast access to source access via cloud from mobile and other devices. — mixel, Apr 09 '15 at 06:20
@madhead Question was not about where to store source code but about how to create global build directory for Gradle. And that is very useful because you can place it on RAM drive and speed up Gradle builds. — mixel, Apr 09 '15 at 06:27
@mixel Did you do measurements of RAM VS disk build? I guess you were still using HDD instead of SSD at that time. — TWiStErRob, Jul 06 '16 at 17:27
@TWiStErRob No, I was using SSD and did not do any measurements. My primary goal was to move build directories of all projects to one place to easily clean up disk space. Now I'm not using RAM drive because it does not give be noticeable performance boost but I still have global build directory in my home directory. — mixel, Jul 06 '16 at 17:41
@mixel Thanks for the detailed reply. A tip: consider [SSD aging](http://techreport.com/review/27909/the-ssd-endurance-experiment-theyre-all-dead), even if it's equally fast. — TWiStErRob, Jul 06 '16 at 17:47

mixel · Accepted Answer · 2016-10-11T13:27:41.203

Thanks to Peter Niederwieser. I decided to post my own answer because of additional details.

To setup global build directory you need to add these lines to ~/.gradle/init.gradle:

gradle.projectsLoaded {
    rootProject.allprojects {
        buildDir = "/path/to/build/${rootProject.name}/${project.name}"
    }
}

Nice option to have global build directory on the RAM disk.

If you are macOS (OS X) user you can do this with:

diskutil erasevolume HFS+ 'RAMDiskName' `hdiutil attach -nomount ram://XXXXXX`

where XXXXXX is a count of 512-byte blocks (for example, it's 262114 for 128MB RAM disk)

And buildDir line will be:

buildDir = "/Volumes/RAMDiskName/${rootProject.name}/${project.name}"

Also you can extend configuration to:

get global build path from environment variable or fallback to build directory inside project directory;
include project group in path, this makes path more unique especially if you have several projects with the same name.

~/.gradle/init.gradle:

def configProject(p, buildDir) {
    p.buildDir = "${buildDir}/${p.name}"  
    p.subprojects { s ->
        configProject(s, "${p.buildDir}")
    }
}

def buildDir = System.env.GRADLE_GLOBAL_BUILD_PATH
if (!buildDir?.trim()) {
    buildDir = "build"
}

gradle.projectsLoaded {
    if (ext.has("group")) {
        buildDir += "/${ext.group}"
    }
    configProject(rootProject, buildDir)
}

And in project settings.gradle:

gradle.ext.group = 'com.example.yourproject'

Also you can use this setting in project build.gradle to set project group but this is optional:

allprojects {
    ...
    group gradle.ext.group
}

score 7 · Answer 2 · answered Apr 28 '14 at 15:45

7

build.gradle:

def baseDir = "/global/build/dir/$project.name"
buildDir = baseDir + "/root"
subprojects {
    buildDir = baseDir + project.path.replaceFirst(":", "/").replace(":", ".")
}

answered Apr 28 '14 at 15:45

Peter Niederwieser

121,412
21
324
259

Nice. But is there any setting like environment variable? So I could tweak global gradle behavior, not per project. – mixel Apr 28 '14 at 19:35
You mean not per build, but for all builds? You could put the code into `~/.gradle/init.gradle` (would have to be slightly adapted). – Peter Niederwieser Apr 28 '14 at 20:33
Thanks for help! I upvoted your answer but added mine as fully acceptable for my question. – mixel Apr 29 '14 at 08:18
Thanks. This works well in projects with deeply nested module directories. – Boris Timofeev Apr 30 '21 at 07:48

score 0 · Answer 3 · answered Jul 06 '16 at 17:44

You could also go the opposite way. Replace the build folder with a global folder.

Remove project's build folder
mklink /d ...disk\path\to\project\build ...RAM\path\to\project (or ln in Unix)
Build fast

You can automate this in the clean task, so a gradlew clean cleans the folder contents and recreates the link.

With some quick testing it seems that Google Drive doesn't recognize directory in junction links on Windows. It'll sync the folders, but not the contents. Weirdly if I upload files to Drive into those folders, they're synced into the local copy. But, if I delete the synced file from the disk, the deletion is not synced back. It seems links cause Drive to be one way.

Gradle global build directory

3 Answers3

Linked