Set 'From' email address in Lotus Notes when sending via VBA

Question

I am using a VBA function in an Access database to call Lotus Notes to send automated emails to customers. The emails are being sent from the users personal Lotus account so that they have a history of the sent emails in their Sent items. However, I don't want the customers to see our internal email addresses.

We are instructing the customers not to reply to the email (call us instead) and want the email to appear to be from noreply@company.com. I am able to set the 'ReplyTo' field to something like noreply@company.com which works if the customer replies to the email but the 'From' field still appears to be coming from the users real email address and the customer would be able to see that information and still send an email to our address.

I have tried setting the following properties, but they don't seem to work:

.DisplaySent = "noreply@company.com"
.iNetFrom = "noreply@company.com"
.iNetPrincipal = "noreply@company.com"

(I currently have these commented out in the below VBA because they didn't seem to have any effect)

Below is the VBA I am using. Any suggestions? Thanks!

Public Sub SendNotesMail(Subject As String, Attachment As String, Recipient As     Variant, BodyText As String, SaveIt As Boolean)

    'Set up the objects required for Automation into lotus notes
    Dim Maildb As Object 'The mail database
    Dim UserName As String 'The current users notes name
    Dim MailDbName As String 'THe current users notes mail database name
    Dim MailDoc As Object 'The mail document itself
    Dim AttachME As Object 'The attachment richtextfile object
    Dim Session As Object 'The notes session
    Dim EmbedObj As Object 'The embedded object (Attachment)

    'Start a session to notes
    Set Session = CreateObject("Notes.NotesSession")

    'Next line only works with 5.x and above. Replace password with your password
    'Session.Initialize ("password")
    'Get the sessions username and then calculate the mail file name
    'You may or may not need this as for MailDBname with some systems you
    'can pass an empty string or using above password you can use other mailboxes.
    UserName = Session.UserName
    MailDbName = Left$(UserName, 1) & Right$(UserName, (Len(UserName) - InStr(1, UserName, " "))) & ".nsf"

    'Open the mail database in notes
    Set Maildb = Session.GETDATABASE("", MailDbName)
    If Maildb.ISOPEN = True Then
        'Already open for mail
    Else
         Maildb.OPENMAIL
    End If

    'Set up the new mail document
    Set MailDoc = Maildb.CREATEDOCUMENT
    MailDoc.principal = "noreply@company.com"
    MailDoc.ReplyTo = "noreply@company.com"
    'MailDoc.DisplaySent = "noreply@company.com"
    'MailDoc.iNetFrom = "noreply@company.com"
    'MailDoc.iNetPrincipal = "noreply@company.com"
    MailDoc.Form = "Memo"
    MailDoc.sendto = Recipient
    MailDoc.Subject = Subject
    MailDoc.Body = BodyText
    MailDoc.SAVEMESSAGEONSEND = SaveIt

    'Set up the embedded object and attachment and attach it
    If Attachment <> "" Then
        Set AttachME = MailDoc.CREATERICHTEXTITEM("Attachment")
        Set EmbedObj = AttachME.EMBEDOBJECT(1454, "", Attachment, "Attachment")
        MailDoc.CREATERICHTEXTITEM ("Attachment")
    End If

    'Send the document
    MailDoc.PostedDate = Now() 'Gets the mail to appear in the sent items folder
    MailDoc.SEND 0, Recipient

    'Clean Up
    Set Maildb = Nothing
    Set MailDoc = Nothing
    Set AttachME = Nothing
    Set Session = Nothing
    Set EmbedObj = Nothing
End Sub

score 2 · Answer 1 · answered May 16 '14 at 14:41

2

You can't change the From this way. It will always be sent with the original sender.

There are two ways to solve this. No. 1 create a Mailbox for noreply@company.com and send all the mails from that box instead the user's. All the mails will then have a flag "sent by" to original sender. Depending on the mailclient, a reply will end either in the central mailbox or in the users box.

No. 2 you create the mail directly in the servers mail.box, than you are able to manipulate all the fields. And afterwards you create the same document in the users mailbox with all the necessary items for sent mails.

answered May 16 '14 at 14:41

umeli

1,068
8
14

Thanks for the reply. Option #1 I unfortunately can't do due to internal reasons. I'm taking a look at Option #2 by aren't familiar with how to accomplish that. We are using a Domino server, but I'm not sure how to create an email directly in the servers email box. Are there any online resources which provide insight on how to do that? I tried searching, but am not exactly sure what I'm even searching for. – user3644787 May 16 '14 at 14:58
The previous URL is extremely helpful. Thank you. I will try it out and post results. – user3644787 May 16 '14 at 15:11
I quickly hit a brick wall. The class written by Karl-Henry Martinsson is written in something else other than VBA, therefore in MS Access about 20% of the lines fail. For example, the line `Private p_sendto List As String` fails because of the word 'List' which VBA doesn't support. Is there any way to convert this to VBA or enable a reference in MS Access to allow this class to work in Access? – user3644787 May 16 '14 at 17:22
2

Don't copy the code. Read it to learn the technique, and then write the equivalent code in VBA. The key line of code is Set mailbox = New NotesDatabase(mailservername,"mail.box"). Note the second argument. It's saying that you want to open the server's mail.box file, which is sometimes also known as the server's router mailbox. (In fact, it might redirect you automatically to a different file, such as mail2.box, but you don't have to worry about that.) – Richard Schwartz May 16 '14 at 19:05
The code is written in Lotusscript. Like Richard says, look at the code to understand what it is doing, then write the corresponding functionality in VBA. Lists are really cool and useful, and I would not be surprised if VBA has something similar. You cen read more about lists here: http://blog.texasswede.com/sntt-lists-the-forgotten-gem-in-lotusscript/ – Karl-Henry Martinsson May 19 '14 at 02:09

score 1 · Answer 2 · answered May 18 '14 at 14:22

1

Use the @NotesDomain workaround in your code. Just change this one line in your code:

MailDoc.Principal = "noreply@company.com@NotesDomain"

and it should work. The Domino server looks for "@NotesDomain" routing the mail and if the Principal field ends with this string then fields From and ReplyTo are set to the string before "@NotesDomain".

More information about "@NotesDomain" approach you can find here in section "How can I change the apparent sender of agent generated mail?".

answered May 18 '14 at 14:22

Knut Herrmann

30,880
4
31
67

cool thing, wasn't aware of that. But still it's not quite what was requested here, as far as I can see: mail arrives with "noreply" in the From field, but the real name still appears as "Sent By" in the Notes mail client, and still is printed into the internal fields "From", "INetFrom" und "$OnBehalfOf"; for a mail sent externally the real name appears in the mail header as "Sender" and is listed as "Return-Path" - BTW: thanks for linking Julie's brilliant doc; the other day I've been looking for it... – Lothar Mueller May 19 '14 at 08:47

Set 'From' email address in Lotus Notes when sending via VBA

2 Answers2

Linked