Loop not looping and 2nd If not Iffing

Question

Here's all my code

Module Module1

Sub Main()
    Dim yob As Integer
    System.Console.WriteLine("If you would as be kind as to input your year of birth then I will        tell you how old you are")
loops:
    Try
        yob = Int32.Parse(Console.ReadLine())
    Catch ex As SystemException
        Console.WriteLine("that is not a number, try again.")
        GoTo loops
    Finally
    End Try
    Do Until yob > 0 And yob < DateTime.Today.Year
    Loop
    If yob < 0 Or yob > DateTime.Today.Year Then
        Console.WriteLine("You entered a number that is either zero or a date in the future.")
        Console.WriteLine("You can't be born in the future. C'mon son")
        Console.WriteLine("Try again")
    End If
    Dim Age = DateTime.Today.Year - yob
    Console.WriteLine("You are " & Age & " years old")
    If Age > 100 Then
        Console.WriteLine("You are were born over a 100 years ago and little is known about that time since there was no Facebook, Twitter or Instagram for people to log their every")
        Console.WriteLine(" thought, action, emotion, or take pictures of their food before this time")
        Console.ReadKey()
    End If
    If Age > 90 Then
        Console.WriteLine("You were born in the 20s")
        Console.WriteLine("In this decade Halloween was born. The first Halloween celebration in America took place in Anoka, Minnesota in 1921. ")
        Console.ReadKey()
    End If
End Sub

End Module

Until I added a goto in my try catch block my loop would run fine. Now it doesn't and if you input a year bigger than 2014 It just sits their. The other problem I have is that my 2nd If doesn't work. If you put in a year that makes your age bigger than 90 It doesn't do anything and the program closes without performing the If statements. Any Ideas on what's wrong?

have you debugged it? set a breakpoint and compare what it actually does versus what you thought it would do — Ňɏssa Pøngjǣrdenlarp, May 16 '14 at 21:42
I'm sorry I'm very new to this and this is my first programming course. The program compiles fine it just doesn't do what it is supposed to. — Tim The Learner, May 16 '14 at 21:44
thats is **why** we debug- to fix logic errors; knowing how the code **actually** runs results in fewer similar errors in the future — Ňɏssa Pøngjǣrdenlarp, May 16 '14 at 21:46
what will `Do Until yob > 0 And yob < DateTime.Today.Year...Loop` (in either your version or ps2goat's, when you enter 2020? — Ňɏssa Pøngjǣrdenlarp, May 16 '14 at 21:55
It does nothing. The program stops and you can not continue or exit without manual clicking the exit key in the corner. — Tim The Learner, May 16 '14 at 22:04
it isnt stuck or hung, you loop back to the ReadLine with no new prompt, so it is waiting for new input (ps2goat version); in yours it will just do nothing endlessly — Ňɏssa Pøngjǣrdenlarp, May 16 '14 at 22:09

score 2 · Answer 1 · answered May 16 '14 at 21:43

2

The code you want to loop has to be in the Do loop.

Do
Try
    yob = Int32.Parse(Console.ReadLine())
Catch ex As SystemException
    Console.WriteLine("that is not a number, try again.")
    GoTo loops
Finally
End Try
Loop Until yob > 0 And yob < DateTime.Today.Year

answered May 16 '14 at 21:43

ps2goat

8,067
1
35
68

This changes nothing. Same result as before. – Tim The Learner May 16 '14 at 21:48

Guffa · Accepted Answer · 2014-05-16T22:14:00.207

Wow, a Goto. Not everyday that you see one of those, and for good reason. You shouldn't use it. There are some situations where it's useful, but you are not likely to actually encounter one of them, ever.

The reason that the code stops for a year out of range is that you have an empty loop where you check the year. As the variable can't change inside the loop, the loop will never end.

You should use the loop around the input instead of after it, and do all the checking inside the loop. You can use the TryParse method instead of letting the code throw an exception, it's usually better to check for the condition that would cause an error instead of waiting for it to happen:

Dim yob As Integer
System.Console.WriteLine("If you would as be kind as to input your year of birth then I will        tell you how old you are")
Dim inputting As Boolean = True
Do While inputting
  Dim input As String = Console.ReadLine()
  If Int32.TryParse(input, yob) Then
    If yob <= 0 Or yob > DateTime.Today.Year Then
      Console.WriteLine("You entered a number that is either zero or a date in the future.")
      Console.WriteLine("You can't be born in the future. C'mon son")
      Console.WriteLine("Try again")
    Else
      inputting = False
    End If
  Else
    Console.WriteLine("that is not a number, try again.")
  End If
Loop

When I test with a year that makes me 94, the second If statement works fine. However, it only checks the lower bound, so if I enter a year that makes me 150 years old, it still says that I was born in the twenties.

Also, being between 90 and 100 doesn't mean that you were born in the twenties, but being between 85 and 95 does. You might want to use the actual birth year in that condition instead of the age:

If yob >= 1920 And yob <= 1929 Then

Side note: Only the birth year is not enough to accurately determine the age. If I was born 1994 it's not certain that I am 20 years old, if I haven't had my birthday yet this year, I'm still 19.

To accurately determine the exact age i would have to take into account leap years and such. I will simply change my Console.Writeline to say that " you are or will be age this year". — Tim The Learner, May 16 '14 at 22:17
@TimTheLearner: You would only need to take leap years into account if you were calculating the age in days or weeks, otherwise you just subtract one from the age if the birthday hasn't happened this year. Changing the message will accurately tell what calculation the program has done, so that is the best solution if you don't want to change it to also accept the birthday. — Guffa, May 16 '14 at 22:24

score 1 · Answer 3 · edited May 23 '17 at 12:05

There are two problems in your code. (Well, three if I count also the goto) The first one is the empty do while that, if you type a value bigger than the current year, will loop forever as pointed in the comments above. The second problem is the lacking of an else if between your two outputs. If I have more than 100 years then I have also more than 90 years and you write both statements.

The first problem is fixed removing all the try/catch block and the Do while loop with

While True
    if Int32.TryParse(Console.ReadLine(), yob) then
      if yob > 0 And yob < DateTime.Today.Year then
        Exit While
      else
        Console.Writeline("Enter a number between 0 and " & DateTime.ToDay.Year)
      End if
    else
        Console.Writeline("This is not a number")
    End if
End While

Notice that TryParse is preferable to the simple Parse because if the input is not a number it will return false and it doesn't throw an exception.

The second problem is simply fixed adding the appropriate else if (and use Console.Readline to be sure to exit when the user presses enter)

If Age > 100 Then
    .....
    Console.ReadLine()
else If Age > 90 Then
    ....
    Console.ReadLine()
End If

However keep in mind that calculating the age of a person is not a simple task as it seems.
Look at this question

Loop not looping and 2nd If not Iffing

3 Answers3