Grails: ExpandoMetaClass for a method

Question

Consider a method

 def public Set<AgeRange> getAgeRanges(boolean excludeSenior) {
           -- something ---
     }

how to write ExpandoMetaClass for this like

    ClassName.metaClass.methodName << { boolean excludeSenior->
           -- something ---
       }

Answer 1

I tried this in the Groovy console and it worked:

class Something {

    Set getAgeRanges(boolean excludeSenior) {
        [1, 2, 3] as Set
    }
}

// test the original method
def s = new Something()
assert s.getAgeRanges(true) == [1, 2, 3] as Set

// replace the method
Something.metaClass.getAgeRanges = { boolean excludeSenior ->
    [4, 5, 6] as Set
}

// test the replacement method
s = new Something()
assert s.getAgeRanges(true) == [4, 5, 6] as Set

Answer 2

I am not really sure what you are asking but this may demonstrate what you are looking for:

Some class:

class SomeClass {
    List<Integer> ages
}

Some metaprogramming to add a method to the class:

SomeClass.metaClass.agesOlderThan { int minimumAge ->
    // note that "delegate" here will be the instance
    // of SomeClass which the agesOlderThan method
    // was invoked on...
    delegate.ages?.findAll { it > minimumAge }
}

Create an instance of SomeClass and call the new method...

def sc = new SomeClass(ages: [2, 12, 22, 32])

assert sc.agesOlderThan(20) == [22, 32]

Does that help?