Push Function(s) with args into an Array to call up later

Question

I have an add method that pushes a function into an array so it can be called up later.

class FRAME.Renderer
  camera   : FRAME.__Camera
  renderer : FRAME.__Renderer 
  scene    : FRAME.__Scene 


  constructor : ( lookAt )->
    @lookAt  = lookAt or false
    @modules = []


  add : ( module )->
    self = this 

    if typeof( module ) is 'function' then @modules.push( module )
    else throw new Error( 'add() only accepts a Function' )

    this 

  build :->
    self = this 
    len  = @modules.length  

    setup =( i )->
        temp = self.modules[i].bind( self )
        temp()

    if len isnt 0 then for i in [0..len-1] then setup( i )


makeCircle =->
  # Circle stuff

makeSquare =->
  # Square stuff

renderer = new FRAME.Renderer()
renderer.add( makeCircle )
renderer.add( makeSquare )

renderer.render()

This works without any issues. How, or is it possible, to have this setup and call add with a function that has parameters ( should I use an object/array combo [{}] to hold the modules instead ) ?

makeSquare = ( options )->
  # Square stuff

renderer.add( makeSquare, options )

`modules : []` needs to go in the constructor, or else [it would be shared amongst all instances](http://stackoverflow.com/q/15449838/1048572)!!! — Bergi, Jul 09 '14 at 21:04
Using a closure is a great idea — didn't even occur to me. — Foreign Object, Jul 09 '14 at 21:05
@Bergi Thanks!. I was imagining something more complex, and I completely ignored the simple solution right in front of me. — Foreign Object, Jul 09 '14 at 21:13

score 0 · Accepted Answer · answered Jul 09 '14 at 21:14

Yes, this is possible, and actually quite easy with coffeescript:

add: (module, args...) ->
  if typeof module is 'function'
    @modules.push {fn: module, args: args}
  else
    throw new Error 'add() only accepts a Function'
  @
build: ->
  for {fn, args} in @modules
    fn(args...) # or
    fn.apply @, args # if you want to bind them
  @

Push Function(s) with args into an Array to call up later

1 Answers1