Inno Setup find subfolder

Question

Is there anyway to get all (or just the first) subfolder in a directory? I'm trying to install my files into a subdirectory that has a dynamic name. It is not one of the constants available with Inno Setup. Is there anyway to find this subdirectory name?

By which pattern do you want to search that folder ? Also, *first folder* is pretty wide term. First in which case ? — TLama, Jul 16 '14 at 14:58
I guess it doesn't really matter - I expect there to be only one folder — Dan, Jul 16 '14 at 15:16

score 5 · Accepted Answer · answered Jul 16 '14 at 15:29

Well, to get name of a first found subfolder of a certain folder, no matter which one it is, you may use the following function:

[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName={pf}\My Program

[Code]
function TryGetFirstSubfolder(const Path: string; out Folder: string): Boolean;
var
  S: string;
  FindRec: TFindRec;
begin
  Result := False;
  if FindFirst(ExpandConstant(AddBackslash(Path) + '*'), FindRec) then
  try
    repeat
      if (FindRec.Attributes and FILE_ATTRIBUTE_DIRECTORY <> 0) and
        (FindRec.Name <> '.') and (FindRec.Name <> '..') then
      begin
        Result := True;
        Folder := AddBackslash(Path) + FindRec.Name;
        Exit;
      end;
    until
      not FindNext(FindRec);
  finally
    FindClose(FindRec);
  end;
end;

procedure InitializeWizard;
var
  S: string;
begin  
  if TryGetFirstSubfolder('C:\Folder', S) then
    MsgBox('The first found subfolder is: ' + S, mbInformation, MB_OK);
end;

Thank you! Please ignore my other comment – Dan Jul 16 '14 at 16:35 — Dan, Jul 16 '14 at 16:35

Inno Setup find subfolder

1 Answers1

Linked