How does Vim's autoread work?

Question

:h autoread says:

When a file has been detected to have been changed outside of Vim and it has not been changed inside of Vim, automatically read it again.

After putting set autoread in my vimrc, I open a file with Vim, switch to another editor, change the file, and wait to see the changes in Vim as well. Nothing happens. I have to use :e to reload the file with the new content.

What did I miss? I'm using Vim 7.2 on Mac 10.5.8

Yeah, I think the problem is that :set autoread only works in a gui vim, not from the terminal. I know this is an old question, but I had a very hard time finding any good help on this. The answer below with the WatchForChanges function is golden. — nathan, Apr 23 '13 at 23:39
`autoread` can work in plain vim, inside a terminal emulator see [this answer](https://stackoverflow.com/a/45428958/5353461). — Tom Hale, Aug 01 '17 at 04:20
See also: [Can vim monitor realtime changes to a file - Stack Overflow](https://stackoverflow.com/questions/2157914/can-vim-monitor-realtime-changes-to-a-file) — user202729, Dec 09 '21 at 12:03

score 45 · Accepted Answer · edited Feb 14 '22 at 10:23

45

Autoread does not reload file unless you do something like run external command (like !ls or !sh etc). vim does not do checks periodically. You can reload file manually using :e.

More details in this thread: Click here

edited Feb 14 '22 at 10:23

Eric O. Lebigot

91,433
48
218
260

answered Mar 22 '10 at 07:52

fphilipe · Answer 2 · 2017-01-03T06:50:56.510

41

I use the following snippet which triggers autoread whenever I switch buffer or when focusing vim again:

au FocusGained,BufEnter * :silent! !

Also, it makes sense to use it in combination with the following snippet so that the files are always saved when leaving a buffer or vim, avoiding conflict situations:

au FocusLost,WinLeave * :silent! w

EDIT: If you want to speed up the write by disabling any hooks that run on save (e.g. linters), you can prefix the w command with noautocmd:

au FocusLost,WinLeave * :silent! noautocmd w

edited Jan 03 '17 at 06:50

answered Dec 06 '13 at 07:38

fphilipe

9,739
1
40
52

I really like the simplicity of this solution, so added it to the vim wiki as well. – Shyam Habarakada May 30 '14 at 14:41
3

Why not use `:checktime` to explicitly trigger the check without shelling out? Also Vim should already be doing this on FocusGained, you shouldn't need an autocmd for that! – Ben May 30 '14 at 21:00
How would I add this to my .vimrc to make this behaviour default? – StevieP Sep 17 '15 at 11:21
1

@StevieP [Here](https://github.com/fphilipe/dotfiles/blob/64c0921d3601edf8c2a59e24097a80f430ad215c/vimrc#L183-L188) the relevant lines in my .vimrc. – fphilipe Sep 17 '15 at 11:33
Right on. Thanks @fphilipe! – StevieP Sep 17 '15 at 12:00
a bit more aggressive: `au InsertLeave * :slient! w` – Arne Sep 06 '16 at 15:33
@Ben +1 for using `checktime` rather than `!`. Otherwise, my neovim (run in terminal) does not do this automatically on FocusGained – Greg Mar 27 '17 at 15:34
We could use `update` in place of `w` to write when the buffer has been modified. – Brij May 04 '20 at 19:54
@Brij or `wa` (short for `wall`), which "write[s] all changed buffers". – fphilipe May 05 '20 at 05:49

score 21 · Answer 3 · edited Mar 20 '17 at 10:18

21

As per my posting on superuser.com

Autoread just doesn't work. Use the following.

http://vim.wikia.com/wiki/Have_Vim_check_automatically_if_the_file_has_changed_externally

I got the best results by calling the setup function directly, like so.

let autoreadargs={'autoread':1} 
execute WatchForChanges("*",autoreadargs)

The reason for this, is that I want to run a ipython/screen/vim setup.

edited Mar 20 '17 at 10:18

Community

1
1

answered Dec 22 '11 at 22:45

irishjava

503
4
11

1

Finally! I have tried quite a few suggestions for getting something like this to work, but none worked in a terminal. This gets the job done! Thanks. – nathan Apr 23 '13 at 23:36

score 19 · Answer 4 · answered Dec 19 '18 at 22:39

19

A bit late to the party, but vim nowadays has timers, and you can do:

if ! exists("g:CheckUpdateStarted")
    let g:CheckUpdateStarted=1
    call timer_start(1,'CheckUpdate')
endif
function! CheckUpdate(timer)
    silent! checktime
    call timer_start(1000,'CheckUpdate')
endfunction

answered Dec 19 '18 at 22:39

Bananach

2,016
26
51

This worked the best for me, and covers all cases, it seems. Thanks! – Biggybi May 22 '19 at 23:21
This is the only solution that did the trick: I executed `prettier --write *` and all my files opened in vim get updated immediately - no need to change mode from normal to insert or do other things to see changes like in other answers. – daGo Oct 13 '19 at 09:20
While other solutions that are ranked higher gave me headache and still did not work properly, this one worked directly just by copying the code, and it works like a charm. This should be the top answer. – Ameer Taweel Apr 10 '21 at 19:14
Well, it didn't work for me. – M Imam Pratama Nov 04 '21 at 04:49
This is the one! – daviewales May 06 '22 at 00:47
With `silent!` it will keep running if there's an error, right? Also, is there any reason not to use the [`repeat` parameter](https://neovim.io/doc/user/builtin.html#:~:text=dictionary.%20%20Supported%20entries%3A%0A%09%09%20%20%20%22-,repeat,-%22%09Number%20of%20times)? – Andrew Apr 19 '23 at 15:33

Greg Sexton · Answer 5 · 2012-07-14T12:07:00.227

12

Outside of gvim, autoread doesn't work for me.

To get around this I use this rather ugly hack.

set autoread
augroup checktime
    au!
    if !has("gui_running")
        "silent! necessary otherwise throws errors when using command
        "line window.
        autocmd BufEnter        * silent! checktime
        autocmd CursorHold      * silent! checktime
        autocmd CursorHoldI     * silent! checktime
        "these two _may_ slow things down. Remove if they do.
        autocmd CursorMoved     * silent! checktime
        autocmd CursorMovedI    * silent! checktime
    endif
augroup END

This seems to be what the script irishjava linked to does, but that lets you toggle this for buffers. I just want it to work for everything.

edited Jul 14 '12 at 12:07

answered Jun 09 '12 at 15:23

Greg Sexton

9,189
7
31
37

Hi, thanks. Your comment reminded me that I posted this. Thought I would update the code as it didn't work well when using the command-line window (`q:`). – Greg Sexton Jul 14 '12 at 12:07
This works great! Can I ask though if you know of a way to get it to write a timestamp of when the file was read in (and the buffer reloaded) when `checktime` does its thing? That would be nice. – Steven Lu Jul 20 '13 at 03:03

Tom Hale · Answer 6 · 2017-08-01T05:55:01.377

10

Trigger when cursor stops moving

Add to your vimrc:

au CursorHold,CursorHoldI * checktime

By default, CursorHold is triggered after the cursor remains still for 4 seconds, and is configurable via updatetime.

Buffer change trigger

To have autoread trigger when changing buffers, add to your vimrc:

au FocusGained,BufEnter * checktime

Terminal window focus trigger

To have FocusGained (see above) work in plain vim, inside a terminal emulator (Xterm, tmux, etc) install the plugin: vim-tmux-focus-events

On tmux versions > 1.9, you'll need to add in .tmux.conf:

set -g focus-events on

edited Aug 01 '17 at 05:55

answered Aug 01 '17 at 04:24

Tom Hale

40,825
36
187
242

See the longer, sister answer [here](https://unix.stackexchange.com/a/383044/143394). – Tom Hale Aug 01 '17 at 06:15
CursorHold and CursorHoldI only trigger once, they do not retrigger every "updatetime". – Julian Pechacek Aug 21 '23 at 04:33

score 1 · Answer 7 · edited Dec 22 '11 at 22:54

1

for me it works when i use the command

:set autoread

Of course you have to save the file in the other editor before anything happens.

edited Dec 22 '11 at 22:54

lucapette

20,564
6
65
59

answered Aug 24 '10 at 15:03

Dominic

19
1

score 0 · Answer 8 · answered Apr 17 '21 at 03:51

I know this post is a bit old but hopefully this will help someone like myself that came across a similar issue.

I don't know how autoload works but I do know how vimscript works which is usually how get things done. If you find this useful, upvote. To answer your question, don't edit the same file in other editors. Usually you will get a notification in vim if you want to reload the file. I was having this problem but my problem was different. I wanted to reload a css file after compiling it with hugo from scss. This is what I did, you can take my code ideas and make them work for your needs.

Usage

Change style.scss to the file you're working on and add a pattern to autoload_files, these are the files you want to autoload. In my case I want to reload a file that ends with the extension 'content'.
In the autocmd include the files that you're going to write, in my case 'style.scss'.
Change the delay from 500 ms to whatever you want.

function! AutoLoadFiles(timer) abort
    let found_ids = []
    let autoload_files = ['content$'] "The files you want to autoload
    let openBuffers=map(gettabinfo(tabpagenr())[0].windows,{idx,val->getwininfo(val)[0]['bufnr']})
    for buf in openBuffers
    let name =  bufname(buf)
        for pat in autoload_files
            if match(name,pat) != -1 
                let fid = getbufinfo(buf)[0].windows[0]
                call add(found_ids,fid)
            endif
        endfor
    endfor
    for id in found_ids
        call win_execute(id,'edit')
    endfor
call timer_stop(a:timer)
endfunction
augroup AutoLoadFiles
    autocmd!
    au BufWrite *style.scss let s:delay_timer = timer_start(500, 'AutoLoadFiles',{'repeat':1})
augroup end

How does Vim's autoread work?

8 Answers8

Trigger when cursor stops moving

Buffer change trigger

Terminal window focus trigger

Linked