Is interface inheritance nothing more than syntactic sugar?

Question

The below code does not work.

program Project7;    
{$APPTYPE CONSOLE}
{$R *.res}

uses System.SysUtils;

type
  I1 = interface
    ['{B4BF44AD-23A9-4F42-BA2B-6E137E22344E}']
    procedure Test1;
  end;

  I2 = interface(I1)
    ['{AAAAAAAA-23A9-4F42-BA2B-BBBBBBBBBBBB}']
    procedure Test2;
  end;

  T12 = class(TInterfacedObject, I2)
  public
    procedure Test1;
    procedure Test2;
  public
    function MeAsI1: I1;
    function MeASI2: I2;
  end;

function T12.MeAsI1: I1;
begin
  Result:= (self as I1);
end;

function T12.MeASI2: I2;
begin
  Result:= (self as I2);
end;

procedure T12.Test1;
begin
 Writeln('T12: test1 from interface i1');
end;

procedure T12.Test2;
begin
   Writeln('T12: test2 from interface i2');
end;

Implemenation:

var
  MyClass: T12;
  AI1: I1;
  AI2: I2;
begin
  MyClass:= T12.Create;
  AI2:= MyClass.MeAsI2;
  AI2.Test2;
  Readln;
  AI1:= MyClass.MeAsI1;    //<< Exception interface not supported
  AI1.Test1;
  Readln;
end.

It gives an Exception: interface not supported.
It looks like interface inheritance does not really work like class inheritance.
If I add the interface I1 to class T12 it does work, but this gets a bit silly when a class implements many interfaces.
Is there a way to only declare I2 and still be able to return a reference to I1 from inside the class?
I'm using Delphi XE6, but I'm sure the error is the same in Delphi 3.

EDIT
A use case for this would be:

 IReadOnly = interface
   function GetSomething: integer;
   ...

 IRWIntf = interface(IReadOnly)
   procedure SetSomething(value: integer);
   ....

Answer 1

This is by design. You can only retrieve those interfaces from a class that are explicitely mentioned in the class declaration.

Regarding your example: as I2 is inherited from I1, you can call the methods from I1 directly from AI2 as well as you can pass AI2 everywhere an interface of I1 is expected.

Answer 2

Interface inheritance follows the logic of interfaces. With an interface you define the declaration without any implementation. So the inherited interface has the same declaration and nothing more and therefore there will be no implementation inheritance.

But you can do the following

procedure UseI1( AI1 : I1 );
begin
  AI1.Test1;
end;

procedure UseI2( AI2 : I2 );
begin
  AI2.Test1;
  AI2.Test2;
  UseI1( AI2 ); // use the inherited interface
end;

If you want your sample class to output the I1 then you have to change the method

function T12.MeAsI1: I1;
var
  LI2 : I2;
begin
  LI2 := Self;
  Result := LI2;
end;

---

But you have to be careful with that. Think of a class implementing both I1 and I2

TImplementor = class( TInterfacedPersistent, I1, I2 )
private
  procedure I1_Test1;
  procedure I2_Test1;
  procedure I2_Test2;

  procedure I1.Test1 = I1_Test1;
  procedure I2.Test1 = I2_Test1;
  procedure I2.Test2 = I2_Test2;
end;

procedure TImplementor.I1_Test1;
begin
  Writeln( 'I1_Test1' );
end;

procedure TImplementor.I2_Test1;
begin
  Writeln( 'I2_Test1' );
end;

procedure TImplementor.I2_Test2;
begin
  Writeln( 'I2_Test2' );
end;

Now we can use this

var
  LImplementor : TImplementor;
begin
  LImplementor := TImplementor.Create;
  try
    UseI1( LImplementor );
    // Output
    // I1_Test1
    UseI2( LImplementor );
    // Output
    // I2_Test1
    // I2_Test2
    // I2_Test1 !!!!!
  finally
    LImplementor.Free;
  end;
end;

Although we call UseI1 two times, we got two different outputs, because two different methods were called.