Playing AAC streams with Adobe AIR in Android/iOS

Question

Looks like it's a pretty common trouble but I still can't see any solution.

The goal is to play some AAC stream in Adobe AIR mobile app.

I've used a transcoder from https://code.google.com/p/project-thunder-snow/. The one adds FLV headers to AAC data so the stream can be played through a standard AS3 NetStream object (as I understand). It works fine for Win and Mac, but the same app launched on Android or iOS produces neither sound nor any error. I've figured out that transcoder works fine, the cause is in the different characteristics of NetStreams.

So, is there any solution or, at least, any documentation describing the difference between the NetStreams on PC and mobile platform?

Answer 1

okay... I might have a clue for you. I tried running the NBAAC code link you posted on the other question from inside Flash CS5 and got this error:

onChannelReady : MetaData Error: Error #2067: The ExternalInterface is not available in this container. ExternalInterface requires Internet Explorer ActiveX, Firefox, Mozilla 1.7.5 and greater, or other browsers that support NPRuntime.

So it seems the player is designed to be used only inside an html page & uses ExternalInterface (Javascript) for getting metadata from browser into SWF

I removed the ExternalInterface stuff and it played ok in Flash Player & Device Central without browser/HTML. Try this code in your AIR app (I don't have AIR installed anymore to confirm..)

package
{
        import com.thebitstream.flv.CodecFactory;
        import com.thebitstream.flv.Transcoder;
        import com.thebitstream.flv.codec.*;
        import com.thebitstream.ice.*;
        import com.thebitstream.nsv.*;

        import flash.display.Sprite;
        import flash.events.Event;
        import flash.events.IOErrorEvent;
        import flash.events.ProgressEvent;
        import flash.events.SecurityErrorEvent;
        //import flash.external.externalInterface;
        import flash.media.SoundTransform;
        import flash.net.NetConnection;
        import flash.net.NetStream;
        import flash.net.NetStreamAppendBytesAction;
        import flash.net.URLRequest;
        import flash.net.URLRequestMethod;
        import flash.net.URLStream;
        import flash.utils.ByteArray;
        import flash.utils.setTimeout;

        [SWF (width="250",height="250")]

        public dynamic class NBAAC_AIR_v2 extends Sprite
        {
            public var request:URLRequest;
            public var transcoder :Transcoder
            public var transport :NetConnection;
            public var transportStream :NetStream;
            public var serverConnection:URLStream;

            //public var host:String=" "; //now not used in line... request=new URLRequest(resource);
            public var resource:String="http://aacplus-ac-64.timlradio.co.uk/;"; //test station

            public function NBAAC_AIR_v2 ()
            {
                super();

                /*
                if(loaderInfo.parameters.host)
                        host=loaderInfo.parameters.host;
                if(loaderInfo.parameters.resource)
                        resource=loaderInfo.parameters.resource;
                 */       

                //CodecFactory.ImportCodec(MetaData);

                CodecFactory.ImportCodec(AAC);
                CodecFactory.ImportCodec(AACP);         

                transcoder = new Transcoder();
                transcoder.addEventListener(CodecEvent.STREAM_READY,onChannelReady);
                transcoder.addEventListener(StreamDataEvent.DATA, onTag);
                transcoder.initiate();

                transcoder.loadCodec("AAC");

                transport = new NetConnection();
                transport.connect(null);

                flash.utils.setTimeout(boot,500);
            }

            public function boot():void
            {
                //externalInterface.addCallback('nbaac.setVolume', onVolume);
                //externalInterface.addCallback('nbaac.togglePause', onTogglePause);
                //externalInterface.addCallback('nbaac.setBuffer', setBufferLength);
                //externalInterface.addCallback('nbaac.getBuffer', getBufferLength);
                //externalInterface.addCallback('nbaac.getTime', getTime);

                /*
                var meta:Object={};
                meta.uri="";
                meta.StreamTitle=""; 
                */

                //externalInterface.call('logit','start up');

                transportStream = new NetStream(transport);
                transportStream.bufferTime=2;
                transportStream.client = this;
                transportStream.soundTransform=new SoundTransform(.5,0);
                transportStream.play(null);                             
                transportStream.appendBytesAction(NetStreamAppendBytesAction.RESET_BEGIN);

                var headerTag:ByteArray=transcoder.createHeader(false,true);
                transportStream.appendBytes(headerTag);                         
                headerTag.clear();

                //transcoder.readMetaObject(meta,0);

                serverConnection=new URLStream();
                serverConnection.addEventListener(ProgressEvent.PROGRESS,loaded);
                serverConnection.addEventListener(IOErrorEvent.IO_ERROR, onIo);                                 
                serverConnection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, onNoPolicy);
                serverConnection.addEventListener(Event.CLOSE, onClose);

                request=new URLRequest(resource); //removed "host" from url

                //request.requestHeaders=[new URLRequestHeader("GET",resource+" HTTP/1.0")];
                //request.requestHeaders=[new URLRequestHeader("Icy-MetaData","1")];

                request.method=URLRequestMethod.GET;
                serverConnection.load(request);
            }

            private function getTime() :Number
            {   return transportStream.time;  }

            private function getBufferLength() :Number
            {  return transportStream.bufferLength; }

            private function setBufferLength (val:Number) :void
            {   transportStream.bufferTime = val;  }

            private function onTogglePause():void
            {   transportStream.togglePause(); }

            private function onVolume (val:Number) :void
            {   transportStream.soundTransform = new SoundTransform(val, 0); }

            private function onIo(pe:IOErrorEvent) :void
            {  /* externalInterface.call('logit','IOErrorEvent') */  }

            private function onTag(sde:StreamDataEvent) :void
            {
                    sde.tag.position=0;
                    transportStream.appendBytes(sde.tag);
            }

            private function onChannelReady(ce:CodecEvent) :void
            {  trace('onChannelReady :',ce.codec.type); }

            private function onClose(e:Event):void
            {   /* externalInterface.call('logit','onClose') */ }

            public function onMetaData(e:Object):void
            {  /* externalInterface.call('logit','onMetaData') */ }

            private function loaded(e:ProgressEvent):void
            {                       
                var chunk:ByteArray=new ByteArray();

                while(serverConnection.bytesAvailable)
                {   chunk.writeByte( serverConnection.readByte() ); }

                chunk.position=0;   
                transcoder.addRawData( chunk, 0, "AAC" );                                                        
            }

            private function onNoPolicy(se:SecurityErrorEvent):void
            { /* externalInterface.call('logit','SecurityErrorEvent'+host+resource+'<br />'+se.text); */ }

    }

}