XSL:if test not working as expected

Question

   <xsl:for-each select="class/student">
         ID:   <xsl:value-of select="id"/><br/>
           Name:  <xsl:value-of select="lastName"/>,<xsl:value-of select="firstName"/><br/>
          Date:  <xsl:value-of select="date"/><br/>
           Major: <xsl:if test="major[@Year > 2008]"> 
                    <xsl:value-of select="major"/> ,
                     declared in:  <xsl:value-of select="major[@Year]"/>    
                  </xsl:if><br/><br/>
          </xsl:for-each>

XML code`:

     <student>
    <id>1000001</id>
    <lastName>john</lastName>
    <firstName>Doe</firstName>
    <date format="d">08/25/2006</date>
    <major Year="2006">CS:BS</major>
  </student>

output:

ID: 1000001
 Name: Doe,John
 Date-enrolled: August 25, 2006
 Major: CS:BS , declared in: CS:BS

the xml code above is just a sample of the actual xml code, there are more 'Year' values/elements.

Hi guys,

Im trying to get only majors whose Year is greater than 2008, for some reason im getting the wrong output.

thanks

To be able to help, we really need to see more of your input XML, and enough of your XSLT to recreate the problem (rather than just some XSLT that is commented out). Showing your expected and actual output would also help, as saying you are "getting the wrong output" is a bit vague. Thank you! — Tim C, Sep 27 '14 at 20:59
That's better.... Although your XSLT refers to a `class` element in your, which is not shown in your in your XML. Also, is the output shown your actual output you are getting now, or your expected output? — Tim C, Sep 27 '14 at 21:10
actual output im getting now, class is just the parent node of the xml file. — user3434926, Sep 27 '14 at 21:23

score 0 · Answer 1 · answered Sep 27 '14 at 21:33

You say "there are more 'Year' values/elements" than shown, and that may be the key to the problem. If your input contains two elements

<major Year="2006">CS:BS</major>
<major Year="2009">CS:BS</major>

then test="major/@Year > 2008" will return true, because there is one such element, and in XSLT 1.0, <xsl:value-of select="major"/> will output the first selected element (in 2.0 it will raise an error).

In future, please try to supply a complete sample stylesheet and source document that allow others to reproduce the problem. If you try to cut it down without testing that the cut-down version exhibits the problem, it's easy to eliminate the feature that is the actual source of the trouble.

JLRishe · Answer 2 · 2014-09-29T06:20:27.413

The problem is that you are going about this backwards. You need to select the stuff that you want, and then use it. You are checking whether the stuff that you want exists, and then using something less specific.

This should fix your issue:

Major: 
<xsl:for-each select="major[@Year > 2008]">
  <br/>
  <xsl:value-of select="."/>, declared in: <xsl:value-of select="@Year"/>
</xsl:for-each>
<br/>

Your use of

<xsl:value-of select="major[@Year]"/>

was also incorrect. The following would have actually output a year value:

<xsl:value-of select="major/@Year"/>

I strongly suggest using either <xsl:text> or <xsl:value-of> for your static text. Your current approach of sprinkling text throughout your XSLT is resulting in very messy-looking XSLT code:

<xsl:for-each select="class/student">
  <xsl:value-of select="concat('ID: ', id)"/>
  <br/>
  <xsl:value-of select="concat('Name: ', lastName, ',', firstName)"/>
  <br/>
  <xsl:value-of select="concat('Date: ', date)"/>
  <br/>
  <xsl:text>Major:</xsl:text>
  <xsl:for-each select="major[@Year > 2008]">
    <br/>
    <xsl:value-of select="concat(., ', declared in: ', @Year)"/>
  </xsl:for-each>
  <br/>
</xsl:for-each>

XSL:if test not working as expected

2 Answers2