Windows Batch file - taskkill if window title contains text

Question

I want to write a simple batch file to kill a process that contains certain text in the window title. Right now I have:

taskkill /fi "Windowtitle eq XXXX*" /im cmd.exe

And that works, except what I want to do is use the wildcard both at the beginning AND end of the title. So something like:

taskkill /fi "Windowtitle eq \*X*" /im cmd.exe

But I tried this and it does not work. Is there something I'm missing or is this not possible?

score 13 · Accepted Answer · answered Oct 24 '14 at 16:52

13

No, wildcards are not allowed at the start of the filter.

for /f "tokens=2 delims=," %%a in ('
    tasklist /fi "imagename eq cmd.exe" /v /fo:csv /nh 
    ^| findstr /r /c:".*X[^,]*$"
') do taskkill /pid %%a

This will retrieve the list of tasks, in csv and verbose format (that will include window title as the last field in the output).

The list is filtered by findstr with a regular expression that will search the indicated text (the X) in the last field.

If any line matches the filter, the for will tokenize it, retrieving the second field (the PID) that will be used in taskkill to end the process.

answered Oct 24 '14 at 16:52

MC ND

69,615
8
84
126

After searching for hours, this is by far the best method out there! Thank you, MC ND! – Acidon Feb 14 '16 at 04:50
Finally a solution that worked for me. Thank you! – JCBrown Jun 09 '21 at 04:40

score 8 · Answer 2 · answered Nov 27 '15 at 08:03

8

In the special case you have started the command window from a batch file yourself, you can specify the window title using the command

START MyWindowTitle c:/MyProcess.exe

That way it is easy to kill the process again using just

taskkill /fi "WindowTitle eq MyWindowTitle"

answered Nov 27 '15 at 08:03

Godsmith

2,492
30
26

1

Nice ! this works. Note: if your title has "Administrator: " in front, see this answer here : http://stackoverflow.com/questions/10948235/taskkill-window-spaces-in-its-title-name – Marc Feb 10 '16 at 15:05
Perfect and simple example. Thanks – Satendra Jindal Sep 14 '17 at 08:47
You have to put double quotes around `MyWindowTitle` for the command to work – Ahmad Feb 17 '20 at 06:02

score 0 · Answer 3 · answered Jan 29 '23 at 06:38

0

A little more elaborate, but you can use:

for /f "tokens=2 delims== " %%A in ('tasklist /nh /fi "imagename eq cmd.exe" /fi "windowtitle eq MyWindowTi*"') do set "PID=%%A"
taskkill /F /T /PID !PID!

answered Jan 29 '23 at 06:38

i YAM GzORM

1
1

Windows Batch file - taskkill if window title contains text

3 Answers3

Linked

Related