Convert time in GMT to current time zone in perl

Question

I want to convert GMT time string to my system time zone. Ex. Tue Nov 04 22:03:03 2014 GMT

My machine time zone is PST, so output should be : 2014-11-04 14:03:03 PST

I can do this in bash but could not find any solution for perl.

Bash solution=> timestamp_local=date "+%Y-%m-%d %H:%M:%S %Z" -d "$timestamp_GMT"

Anyone have solution in perl?

PS: I have to process a huge file ( around 100-200MB of text file ). So, I want a optimized solution.

You could just call your bash solution from the perl script using the system command. — GriffinG, Nov 05 '14 at 01:49
Do you have [`Time::Local`](http://perldoc.perl.org/Time/Local.html)? — Elliott Frisch, Nov 05 '14 at 01:56
@GriffinG I have a huge file, Calling system for this conversion will adversly impact the run time of my script. I should have mentioned this in the question. — Abhijeet, Nov 05 '14 at 21:21

score 3 · Answer 1 · edited May 23 '17 at 12:05

Simple enough with DateTime and friends.

#!/usr/bin/perl

use strict;
use warnings;
use 5.010;

use DateTime::Format::Strptime;
use DateTime;

my $format = '%a %b %d %H:%M:%S %Y %Z';
my $time_string = 'Tue Nov 04 22:03:03 2014 GMT';

my $dt_p = DateTime::Format::Strptime->new(
  pattern => $format,
  time_zone => 'UTC',
);

my $time = $dt_p->parse_datetime($time_string);

say $time->strftime('%a %b %d %H:%M:%S %Y %Z');

$time->set_time_zone('America/Los_Angeles');

say $time->strftime('%a %b %d %H:%M:%S %Y %Z');

Update: And this old answer shows how to do something very similar with the core module Time::Piece.

score 1 · Answer 2 · answered Nov 05 '14 at 04:52

POSIX library should be enough to do this;

use strict;
use feature qw/say/;
use POSIX qw(strftime tzset);

say strftime("%Y %d %m %H:%M:%S GMT", gmtime(time));    # GMT
say strftime("%Y %d %m %H:%M:%S %Z", localtime(time));  # Local Time

# Set to  custom timezone
$ENV{TZ} = 'America/Los_Angeles';
tzset;
say strftime("%Y %d %m %H:%M:%S %Z", localtime(time));  # Custom Zone

Convert time in GMT to current time zone in perl

2 Answers2