I have 100's of .xml files (TV show based) that are named sequentially like so:
s07e01.xml
s07e02.xml
s07e03.xml
s07e04.xml
The season and number of episodes (per season) differ.
In each file there are two lines:
<ID></ID>
<EpisodeNumber></EpisodeNumber>
Is it possible to batch edit these files adding the episode number to these two elements?
Thanks.
Here is a bash script:
#! /bin/bash
for f in *.xml ; do
n=${f##*/s}; n=${n#*e}; n=${n%.xml}
echo "File $f --> episode $n" >&2
mv -f "$f" "$f.bak"
while IFS= read -r line ; do
if [[ "$line" == *"<ID>"*"</ID>"* ]]; then
echo -e "${line%%[^ ]*}<ID>$n</ID>\r"
elif [[ "$line" == *"<EpisodeNumber>"*"</EpisodeNumber>"* ]]; then
echo -e "${line%%[^ ]*}<EpisodeNumber>$n</EpisodeNumber>\r"
else
echo -e "$line\r"
fi
done < "$f.bak" >| "$f"
done
@echo off
setlocal EnableDelayedExpansion
rem Process all .xml files
for %%f in (*.xml) do (
rem Get season and episode in %%a and %%b
for /F "tokens=1,2 delims=se." %%a in ("%%f") do (
rem Get the numbers of both target lines
set "repLines=/"
for /F "delims=:" %%c in ('findstr "<ID> <EpisodeNumber>" "%%f"') do (
set "repLines=!repLines!%%c/"
)
rem Initialize the (first) replacement string
set "replace=<ID>%%a</ID>"
rem Process the file, replace values, create new file
(for /F "tokens=1* delims=:" %%c in ('findstr /N "^" "%%f"') do (
rem If this is a target line
if "!repLines:/%%c/=!" neq "!repLines!" (
rem Do the replacement
echo !replace!
rem And change to next (second) replacement string
set "replace=<EpisodeNumber>%%b</EpisodeNumber>"
) else (
rem Output the line unchanged
setlocal DisableDelayedExpansion
set "line=%%d"
setlocal EnableDelayedExpansion
echo(!line!
endlocal & endlocal
)
)) > "%%~Nf.tmp"
)
)
rem Update files
del *.xml
ren *.tmp *.xml
Previous solution assume that there are just two lines with <ID></ID> and <EpisodeNumber></EpisodeNumber> values placed in that order. If this is not true, a small modification is needed.
simple batch script:
@echo off
REM rename all files with matching patterns to tmp-files:
ren s??e??.xml *.tmp
REM for all tmp-files do:
for /f "tokens=*" %%f in ('dir /b *.tmp') do (
REM get season and episode:
for /f "tokens=1,2 delims=SsEe." %%i in ("%%~nf") do (
REM write new xml file:
>%%~dpnf.xml echo ^<ID^>%%i^</ID^>
>>%%~dpnf.xml echo ^<EpisodeNumber^>%%j^</EpisodeNumber^>
)
)
REM delete tmp files:
del *.tmp
There is a very efficient and elegant solution using REPL.BAT - a hybrid JScript/batch utility that performs a regular expression search/replace on stdin and writes the result to stdout. REPL.BAT is pure script that will run natively on any Windows machine from XP onward. Full documentation is built into the script.
I use REPL.BAT twice. First to modify the output of DIR /B, filtering out lines that don't match the name template, and also extracting the Season and Episode values. The result is processed by FOR /F. Then for each file, a second REPL.BAT modifies the actual file and writes it to a temp file. Finally, the temp file is MOVEd to the original file name. The 2nd REPL makes both replacements in one pass. The replacement value is a JScript expression that determines which value to plug in, depending on the matched tag name.
This script will process all files in the current folder:
@echo off
for /f "delims=: tokens=1,2*" %%A in (
'dir /b /a-d s??e*.xml^|repl "^s(\d\d)e(\d\d)" "$1:$2:$&" ia'
) do (
type "%%C"|repl "(<(ID|EpisodeNumber)>).*?(</\2>)" "$1+($2=='ID'?'%%A':'%%B')+$3" j >"%%C.new"
move /y "%%C.new" "%%C" >nul
)
This second version will process an entire folder hierarchy. It only requires a slight modification to the DIR command and the initial REPL search string:
for /f "delims=: tokens=1,2*" %%A in (
'dir /b /s /a-d s??e*.xml^|repl "^.*\\s(\d\d)e(\d\d)" "$1:$2:$&" ia'
) do (
type "%%C"|repl "(<(ID|EpisodeNumber)>).*?(</\2>)" "$1+($2=='ID'?'%%A':'%%B')+$3" j >"%%C.new"
move /y "%%C.new" "%%C" >nul
)
