How can I fetch Google static maps with TIdHTTP?

Question

I'm trying to return content from maps.google.com from within Delphi 2006 using the TIdHTTP component.

My code is as follows

procedure TForm1.GetGoogleMap();
var
  t_GetRequest: String;
  t_Source: TStringList;
  t_Stream: TMemoryStream;
begin
  t_Source := TStringList.Create;

  try
    t_Stream := TMemoryStream.Create;

    try
      t_GetRequest :=
        'http://maps.google.com/maps/api/staticmap?' +
        'center=Brooklyn+Bridge,New+York,NY' +
        '&zoom=14' +
        '&size=512x512' +
        '&maptype=roadmap' +
        '&markers=color:blue|label:S|40.702147,-74.015794' +
        '&markers=color:green|label:G|40.711614,-74.012318' +
        '&markers=color:red|color:red|label:C|40.718217,-73.998284' +
        '&sensor=false';

      IdHTTP1.Post(t_GetRequest, t_Source, t_Stream);

      t_Stream.SaveToFile('google.html');
    finally
      t_Stream.Free;
    end;
  finally
    t_Source.Free;
  end;
end;

However I keep getting the response HTTP/1.0 403 Forbidden. I assume this means that I don't have permission to make this request but if I copy the url into my web browser IE 8, it works fine. Is there some header information that I need or something else?

score 4 · Answer 1 · answered Apr 23 '10 at 05:10

4

you're doing a POST request, however your browser will be doing a GET request; change your delphi code to also do a GET request.

google may be blocking by UserAgent; try clearing it, or changing it to match your browser's.

answered Apr 23 '10 at 05:10

glob

2,960
17
21

score 1 · Answer 2 · answered Aug 11 '10 at 04:46

cloudstrif3, the value returned by the request is a image not a html page, i just wrote this article Using Google maps (Static Maps) without TWebBrowser on my blog, so you can check the source code.

check this sample.

var
  StreamData :TMemoryStream;
  JPEGImage  : TJPEGImage;
  Url        : string; 
begin
  Url        :='http://maps.google.com/maps/api/staticmap?' +  
  'center=Brooklyn+Bridge,New+York,NY' +  
  '&zoom=14' +  
  '&size=512x512' +  
  '&maptype=roadmap' +  
  '&markers=color:blue|label:S|40.702147,-74.015794' +  
  '&markers=color:green|label:G|40.711614,-74.012318' +  
  '&markers=color:red|color:red|label:C|40.718217,-73.998284' +  
  '&format=jpg'; //i add this param to return a  jpg image , because the default format used is png.
  '&sensor=false'; 
  StreamData := TMemoryStream.Create;
  JPEGImage  := TJPEGImage.Create;
  try
    try
     idhttp1.Get(Url, StreamData); //Send the request and get the image
     StreamData.Seek(0,soFromBeginning);
     JPEGImage.LoadFromStream(StreamData);//load the image in a Stream
     ImageMap.Picture.Assign(JPEGImage);//Load the image in a Timage component
    Except On E : Exception Do
     MessageDlg('Exception: '+E.Message,mtError, [mbOK], 0);
    End;
  finally
    StreamData.free;
    JPEGImage.Free;
  end;
end;

score 0 · Answer 3 · edited May 14 '13 at 01:14

const
 NONE              = $00; //Zero-value number
 INET_USERAGENT    = 'Mozilla/4.0, Indy Library (Windows; en-US)';
 INET_REDIRECT_MAX = 10;
var
  StreamData :TMemoryStream;
  JPEGImage  : TJPEGImage;
  Url,html        : string;

begin
  idhttp1.request.userAgent:=INET_USERAGENT;                             //Define user agent
  idhttp1.redirectMaximum:=INET_REDIRECT_MAX;                            //Redirect maxumum
  idhttp1.handleRedirects:=INET_REDIRECT_MAX<>NONE;
  Url        :=edit1.Text;
  StreamData := TMemoryStream.Create;
  JPEGImage  := TJPEGImage.Create;

  try
    try
     html:= idhttp1.Get(Url); //Send the request and get the image

     idhttp1.Get(Url, StreamData); //Send the request and get the image
     StreamData.Seek(0,soFromBeginning);
     memo1.Lines.Text:=html;
     JPEGImage.LoadFromStream(StreamData);//load the image in a Stream
     ImageMap.Picture.Assign(JPEGImage);//Load the image in a Timage component

    Except On E : Exception Do
     MessageDlg('Exception: '+E.Message,mtError, [mbOK], 0);
    End;
  finally
    StreamData.free;
    JPEGImage.Free;
  end;
end;

score 0 · Answer 4 · edited May 23 '17 at 12:02

0

I am reinventing the wheel & coding the same thing from scratch :-)

This question explains why you get 403.

I added this line of code & it worked for me:
idHttp.request.useragent := 'Mozilla/5.0 (compatible; MSIE 9.0; Windows NT 6.1; WOW64; Trident/5.0; MAAU)';

Yes, I do realize that the question is 3 years old (and never awarded an answer), but I append this to help others.

edited May 23 '17 at 12:02

Community

1
1

answered Feb 23 '14 at 04:09

Mawg says reinstate Monica

38,334
103
306
551

score 0 · Answer 5 · answered Apr 23 '10 at 04:47

Are you behind a Proxy Server that needs authentication?

I don't have Delphi installed anymore but I think that the Indy components support Proxy authentication, something like...(untested)

IdHTTP1.ProxyParams.ProxyServer := 'http://proxyaddress';
idHTTP1.ProxyParams.ProxyPort := 8080;
idHTTP.ProxyParams.ProxyUserName := 'name';
idHTTP.ProxyParams.ProxyPassword := 'pwd';

score 0 · Answer 6 · answered Apr 27 '10 at 17:11

Like glob said, you need to do a Get() instead of a Post(), for example:

procedure TForm1.GetGoogleMap();  
var  
  t_GetRequest: String;  
  t_Stream: TMemoryStream;  
begin  
  t_Stream := TMemoryStream.Create;  
  try  
    t_GetRequest :=  
      'http://maps.google.com/maps/api/staticmap?' +  
      'center=Brooklyn+Bridge,New+York,NY' +  
      '&zoom=14' +  
      '&size=512x512' +  
      '&maptype=roadmap' +  
      '&markers=color:blue|label:S|40.702147,-74.015794' +  
      '&markers=color:green|label:G|40.711614,-74.012318' +  
      '&markers=color:red|color:red|label:C|40.718217,-73.998284' +  
      '&sensor=false';  

    IdHTTP1.Get(t_GetRequest, t_Stream);  

    t_Stream.SaveToFile('google.html');  
  finally  
    t_Stream.Free;  
  end;  
end;

How can I fetch Google static maps with TIdHTTP?

6 Answers6