Cannot find library with simple C++ example

Question

I am building a C++ library called alpha in Ubuntu with cmake, which contains one source file:

cmake_minimum_required(VERSION 2.8)

project(Alpha)

add_library (alpha alpha.cpp)

This creates a file called libalpha.a, which I now want to link to. So, I copy it into the source directory of another C++ projected called beta, which also contains one source file:

cmake_minimum_required(VERSION 2.8)

project(Beta)

add_executable(beta beta.cpp)

target_link_libraries(beta alpha)

However, I get the following error:

/usr/bin/ld: cannot find -lalpha

The same thing happens if I use the line:

target_link_libraries(beta libalpha.a)

Why can beta not find the alpha library?

You may need to add `link_directories(the_directory_where_you_put_the_library)`. — juanchopanza, Dec 08 '14 at 11:48
But the library has been copied to the same directory as `beta.cpp`... — Karnivaurus, Dec 08 '14 at 11:49
Yes, that gives me the error: `/usr/bin/ld: cannot find -l./libalpha.a` — Karnivaurus, Dec 08 '14 at 11:57
I believe this should do what you want: http://stackoverflow.com/questions/4905089/cmake-how-to-correctly-create-dependencies-between-targets — Brad Howes, Dec 08 '14 at 12:14
take a look here: http://www.cs.swarthmore.edu/~newhall/unixhelp/howto_C_libraries.html — nimsson, Dec 08 '14 at 13:09

user3159253 · Answer 1 · 2014-12-08T12:15:17.407

If you wish to build the library and the program completely separately, you have to use imported targets. When you try to link your executable against a "completely unknown" library, CMake build system automatically passes the task of locating the library to the linker, simply adding -lalpha option. When the linker encounters the option it attempts to locate libalpha.so in one of the standard library locations (i.e. /usr/lib/, /usr/local/lib etc) and expectedly fails. You can use an absolute path to the libalpha.a: target_link_libraries(beta /path/to/libalpha.a).

However if you can build things together, this greatly simplifies the task. Consider

<project>/CMakeLists.txt:

cmake_minimum_required(VERSION 2.8)

Project(Test)

add_subdirectory(alpha)
add_subdirectory(beta)

<project>/alpha/CMakeLists.txt

cmake_minimum_required(VERSION 2.8.11)

project(alpha)

set(SOURCES alpha.c)

add_library(alpha ${SOURCES})
target_include_directories(
  alpha INTERFACE
  "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>"
  "$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>"
)

target_include_directories() with the complex expression within is required to automatically add libalpha include directories to all components which later are linked against libalpha.

<project>/beta/CMakeLists.txt

project(beta)

set(SOURCES beta.c)

add_executable(beta ${SOURCES})
target_link_libraries(beta alpha)

score 0 · Answer 2 · answered Dec 10 '14 at 11:00

0

Add this line with the path to alpha-library.

link_directories( <library path> )

answered Dec 10 '14 at 11:00

user1766169

1,932
3
22
44

Cannot find library with simple C++ example

2 Answers2