AutoHotKey JavaScript Link

Question

I'm not familiar with JavaScript and web development, as my experience is in Java and C++ primarily, and I'm even new to that. I'm using AutoHotKey to automate data entry for the company I work for, and in order to get into the form that to fill out a new item, I have to click a link. I've had no problem when the links all had URLs for href values, but now I'm running into one that is a JavaScript link, and I don't know how to click it... here is the code for the link.

<a href="javascript:" 
tabindex="7"
onclick="this.parentNode.parentNode._skip=true;$find('ctl00_MainContent_view1Extender').executeAction('ActionBar',0,null,0);return false;"
onfocus="$showHover(this,&quot;ctl00_MainContent_view1Extender$0$ActionGroup$0&quot;,&quot;ActionGroup&quot;,2)" 
title="New Reimbursement" 
onblur="$hideHover(this)">New Reimbursement</a>

And I'm not sure what to do with it, despite a days worth of Googling.

Thanks in advance!

I've tried finding it by `wb.document.links[x].href` so that I could `wb.Navigate` to it — Jonathon Anderson, Dec 09 '14 at 05:03
I also tried copying and pasting `javascript:(onClick text)` — Jonathon Anderson, Dec 09 '14 at 05:04
Somehow you need to run the `onclick` event, the `href` does nothing. Can you trigger the click event by calling `.click()` on the DOM node? — Alexander O'Mara, Dec 09 '14 at 05:10
Hmmm. I suppose I should have looked into that. The problem I'm having is that the element doesn't have an id... so I don't know how to reference it. — Jonathon Anderson, Dec 09 '14 at 05:41
I'm thinking this: http://www.autohotkey.com/board/topic/85281-help-with-ahk-l-and-the-dom/ — Jonathon Anderson, Dec 09 '14 at 05:42
Just making a note for myself for tomorrow: http://stackoverflow.com/questions/19030742/difference-between-innertext-and-innerhtml-in-javascript — Jonathon Anderson, Dec 09 '14 at 05:47
I am not sure but maybe that can help you: http://www.autohotkey.com/board/topic/84258-iwb2-learner-iwebbrowser2/ — vasili111, Dec 09 '14 at 07:38

score 2 · Accepted Answer · answered Dec 09 '14 at 21:07

More then one way get to an element without a ID or Name, but one of the easy ones are to loop over the elements on the page until you get to the one you need.

Example Function:

LoopElements(Elements, String, attribute="title")
{
try
Loop % Elements.Length ; check each element
    If instr((Elements[A_Index-1])[Attribute], String) ; if the Attribute text is what we need
        return Elements[A_Index-1] ; return Element
}

Most of the time the .click() method will work but with the newest versions of IE I have seen a need to use other methods like dispatchEvent to make a mouseevent object

Usage example:

site := "ahkscript.org"

wb := ComObjCreate("InternetExplorer.Application")
wb.visible := true
wb.navigate(site)

while wb.readyState!=4 || wb.document.readyState != "complete" || wb.busy
    continue

links := wb.document.getElementsByTagName("A")

linkElement := LoopElements(links, "GNU General Public License", "innertext")

if (linkElement)
{
    msgbox % "Element found it was #" linkElement.sourceindex "`n`nLets click it!"
    linkElement.click()
}
else
    msgbox % "no Element found"
return



LoopElements(Elements, String, attribute="title")
{
try
Loop % Elements.Length ; check each element
    If instr((Elements[A_Index-1])[Attribute], String) ; if the Attribute text is what we need
        return Elements[A_Index-1] ; return Element
}

You can also call the function the onclick event is doing but try this first then later you can try other ways as you get the need...

Hope it helps

I ended up with an "Access Denied" error when I ran my script, pointing to the line where I executed `.click()` I will run it with your method and see if it works. Thanks for the info. I will report back. — Jonathon Anderson, Dec 09 '14 at 23:01
Baby Jesus, it works. Thanks for your help!!! I may be back here in the near future. I hope you will be around. }:) — Jonathon Anderson, Dec 10 '14 at 15:51

AutoHotKey JavaScript Link

1 Answers1

Linked