Splitting up and transforming delimited string in XSLT

Question

This is a sample of the XML I want to transform:

<dsQueryResponse>
  <Rows>
    <Row Contacts="#111;#Smith, John;#112;#Sue, Mary;#113;#Jones, Rick" />
    <Row Contacts="#114;#Lee, Thomas;#115;#Richards, Kate" />
  </Rows>
</dsQueryResponse>

Using XSLT, how do I split this up so that it the output looks like:

<div>
  <span>#111;#Smith, John</span>
  <span>#112;#Sue, Mary</span>
  <span>#113;#Jones, Rick</span>
</div>
<div>
  <span>#114;#Lee, Thomas</span>
  <span>#115;#Richards, Kate</span>
</div>

The ; being used as a delimiter while having each set contain it is what is confusing me.

Edit:
Yes, I am aware of this post.
I have tried it but it is not splitting the way I need it to.
; is a delimiter and is also part of what is being split.

@Tomalak This question is little more complicated than that. — michael.hor257k, Dec 18 '14 at 17:32
@DanielHaley This question is little more complicated than that. — michael.hor257k, Dec 18 '14 at 17:32
I have seen that post and have tried, but it is splitting it too much. For example, `#111`, `#Smith, John`, `#112`, `#Sue, Mary` **(4)** instead of `#111;#Smith, John`, `#112;#Sue, Mary` **(2)** — Katie, Dec 18 '14 at 17:33
@michael.hor257k I don't know to be honest. Just whatever SharePoint 2010 is using I guess. — Katie, Dec 18 '14 at 17:39

michael.hor257k · Accepted Answer · 2014-12-18T19:07:10.560

Try it this way:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="yes" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:template match="/dsQueryResponse">
    <body>
        <xsl:for-each select="Rows/Row">
            <div>
               <xsl:call-template name="tokenize">
                    <xsl:with-param name="text" select="@Contacts"/>
                </xsl:call-template>
            </div>
        </xsl:for-each>
    </body>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="';'"/>
    <xsl:choose>
        <xsl:when test="contains($text, $delimiter) and contains(substring-after($text, $delimiter), $delimiter)">
            <span>
                <xsl:value-of select="substring-before($text, $delimiter)"/>
                <xsl:value-of select="$delimiter"/>
                <xsl:value-of select="substring-before(substring-after($text, $delimiter), $delimiter)"/>
            </span>
            <!-- recursive call -->
            <xsl:call-template name="tokenize">
                <xsl:with-param name="text" select="substring-after(substring-after($text, $delimiter), $delimiter)"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <span>
                <xsl:value-of select="$text"/>
            </span>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

Note:
If there is XML hell, the authors of your source document shall burn in it.

Hahaha! Great this works! (The XML is generated by SharePoint. Not the most easiest of XMLs of deal with that's for sure haha) — Katie, Dec 18 '14 at 18:19

Splitting up and transforming delimited string in XSLT

1 Answers1