Shortcut triggers TAction on first created form instead of form with focus

Question

I found (in Delphi 2010) that shortcuts always end up on first form (as owned by main form) that has that action, but not the currently focused form. My TMainFrm owns several TViewFrm. Each has a TActionManager with the same TActons.

I see some ways out, but wonder whats the best fix.. (and not a bad hack)

The forms are navigated using a tabset which calls their Hide() and Show(). I'd did not expect hidden forms to receive keypresses. Am i doing something wrong?
It seems that action shortcuts are always start at the main form, and using TCustomForm.IsShortCut() get distributed to owned forms. I see no logic there to respect hidden windows, should i override it and have it trigger the focused form first?
Disabling all TActions in TViewFrm.Hide() .. ?
Moving the TActionToolBar to TMainFrm but that is a pit of snakes and last resort.

I am thinking this newsgroup conversation is related: http://codeverge.com/embarcadero.delphi.vcl.using/shortcut-problem-suspect-taction/1076571 — Barry Staes, Jan 05 '15 at 14:42
There is no `TActionManager.Enabled`, i'd have to set `TAction.Enabled` or use its `TAction.OnUpdate()`. — Barry Staes, Jan 07 '15 at 07:12
Isn't there a `State` property like there is for action lists — David Heffernan, Jan 07 '15 at 07:14
Yes there is a `State` property.. did not see that. I found a workaround (see my answer) but this might be also be an answer! — Barry Staes, Jan 07 '15 at 07:29

Barry Staes · Answer 1 · 2015-01-07T07:31:55.993

I have found a workaround thats good enough for me; my main form now overrides TCustomForm.IsShortcut() and first checks visible windows from my list of editor tabs.

A list which i conveniently already have, so this might not work for everyone.

// Override TCustomForm and make it check the currently focused tab/window first.
function TFormMain.IsShortCut(var Message: TWMKey): Boolean;
  function DispatchShortCut(const Owner: TComponent) : Boolean; // copied function unchanged
  var
    I: Integer;
    Component: TComponent;
  begin
    Result := False;
    { Dispatch to all children }
    for I := 0 to Owner.ComponentCount - 1 do
    begin
      Component := Owner.Components[I];
      if Component is TCustomActionList then
      begin
        if TCustomActionList(Component).IsShortCut(Message) then
        begin
          Result := True;
          Exit;
        end
      end
      else
      begin
        Result := DispatchShortCut(Component);
        if Result then
          Break;
      end
    end;
  end;
var
  form : TForm;
begin
  Result := False;

  // Check my menu
  Result := Result or (Menu <> nil) and (Menu.WindowHandle <> 0) and
    Menu.IsShortCut(Message);

  // Check currently focused form   <-------------------  (the fix)
  for form in FEditorTabs do
    if form.Visible then
    begin
      Result := DispatchShortCut(form);
      if Result then Break;
    end;
  // ^ wont work using GetActiveWindow() because it always returns Self.

  // Check all owned components/forms (the normal behaviour)
  if not Result then
    Result := inherited IsShortCut(Message);
end;

Another solution would be to change DispatchShortCut() to check for components being visible and/or enabled, but that might impact more than i'd like. I wonder whether the original code architects had a reason not to -- by design. Best would be have it called twice: first to give priority to visible+enabled components, and second call as fallback to normal behavior.

Don't worry about the list we don't have, 'Forms' of 'Screen' always keep them respecting the z-order. — Sertac Akyuz, Jan 08 '15 at 01:26

Shortcut triggers TAction on first created form instead of form with focus

1 Answers1