add namespace + prefix to XML using XSL

Question

I hope you can help... Let's assume I have following XML:

<data>
   <token>
      <sessionId>12345</sessionId>         
      <userId>john</userId>
      <moreInfo>
         <bla> .....
         </bla>
      </moreInfo>
   </token>
</data>

And I need this to become

<login:data xmlns:login="http://my.ns.uri">
       <login:token>
          <login:sessionId>12345</sessionId>         
          <login:userId>john</userId>
          <login:moreInfo>
             <login:bla> .....
             </login:bla>
          </login:moreInfo>
       </login:token>
    </login:data>

Can I do this with XSL? I did try but failed miserably ... Any help would be greatly appreciated!

Thanks, Jan

Actually, what you produced is bad XML. You want `xmlns:login="http://my.ns.uri"`. — John Saunders, May 10 '10 at 13:51
you are right, that is what I want. xmlns:login="http://my.ns.uri" but what woud be the XSL to do something like that? — Jan, May 10 '10 at 13:54
Good question (+1). See my answer for a complete and correct solution. :) — Dimitre Novatchev, May 10 '10 at 14:06

score 19 · Accepted Answer · answered May 10 '10 at 14:05

Use:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:login="http://my.ns.uri">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="*">
  <xsl:element name="login:{name()}" namespace="http://my.ns.uri">
    <xsl:copy-of select="namespace::*"/>
    <xsl:apply-templates select="node()|@*"/>
  </xsl:element>
 </xsl:template>
</xsl:stylesheet>

When this transformation is applied on the provided XML document, the wanted, correct result is produced:

<login:data xmlns:login="http://my.ns.uri">
   <login:token>
      <login:sessionId>12345</login:sessionId>
      <login:userId>john</login:userId>
      <login:moreInfo>
         <login:bla> .....
         </login:bla>
      </login:moreInfo>
   </login:token>
</login:data>

score 0 · Answer 2 · answered May 10 '10 at 13:54

0

<xsl:template match="*">
  <xsl:element name="{local-name()}" namespace="http://my.ns.uri">
    <xsl:apply-templates />
  </xsl:element>
</xsl:template>

answered May 10 '10 at 13:54

Boldewyn

81,211
44
156
212

All right, I understand this. But how can I change the prefixes of all the elements? – Jan May 10 '10 at 13:56
Prefixes are something, that is quite fluid in XML. I mean, that the spec says explicitly, that they are *arbitrary*. So, your XSLT processor would be free to change them to whatever it likes. However, every (known to me) XSLT engine re-uses the prefixes that you wrote in your opening `` tag, if there aren't reasons to not do this (like XSLT's `exclude-result-prefix`). – Boldewyn May 10 '10 at 14:03

Mandy · Answer 3 · 2016-08-27T14:31:44.510

XSLT 2.0 is more efficient and compact. It supports to add namespaces to node directly. We don't need to define anything in the starting of stylesheet as well.

Here is the spec : creating namespace prefix

Use :

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:template match="*">
  <xsl:element name="login:{name()}" xmlns:login="http://my.ns.uri">
   <xsl:namespace name="login">http://my.ns.uri</xsl:namespace>
   <xsl:value-of select="node()"/>
   <xsl:apply-templates select="*"/>
  </xsl:element>
 </xsl:template>
</xsl:stylesheet>

It will give the output :

<login:data xmlns:login="http://my.ns.uri">
   <login:token>
      <login:sessionId>12345</login:sessionId>
      <login:userId>john</login:userId>
      <login:moreInfo>
         <login:bla> .....
         </login:bla>
      </login:moreInfo>
   </login:token>
</login:data>

add namespace + prefix to XML using XSL

3 Answers3

Linked

Related