Getting PID for a process using Groovy

Question

I'm trying to create a method in Groovy to get the Process ID of an application. I'm currently at this stage:

String getProcessIdFor(String program) {
    def buffer = new StringBuffer()

    Process commandOne = 'ps -A'.execute()
    Process commandTwo = "grep -m1 '${program}'".execute()
    Process commandThree = "awk '{print \$1}'".execute()

    Process process = commandOne | commandTwo | commandThree
    process.waitForProcessOutput(buffer, buffer)

    return buffer.toString()
}

But this gives me:

Exception in thread "Thread-1" groovy.lang.GroovyRuntimeException: exception while reading process stream
awk: syntax error at source line 1
at org.codehaus.groovy.runtime.ProcessGroovyMethods$3.run(ProcessGroovyMethods.java:402)
context is
at java.lang.Thread.run(Thread.java:745)
 >>> ' <<< 
missing }
Caused by: java.io.IOException: Stream closed
awk: bailing out at source line 1
at java.lang.ProcessBuilder$NullOutputStream.write(ProcessBuilder.java:434)
at java.io.OutputStream.write(OutputStream.java:116)
at java.io.BufferedOutputStream.write(BufferedOutputStream.java:122)
at java.io.BufferedOutputStream.write(BufferedOutputStream.java:122)
at org.codehaus.groovy.runtime.ProcessGroovyMethods$3.run(ProcessGroovyMethods.java:399)
... 1 more

Process finished with exit code 0

It looks like it's struggling on the awk command, but I can't seem to figure out where I'm going wrong. Any ideas?

Does `'awk {print \$1}'.execute()` work? I'd just use findAll and split instead of piping between three processes — tim_yates, Jan 26 '15 at 23:15
There is some nice solutions in this link and some of them platform independent-- http://stackoverflow.com/questions/35842/how-can-a-java-program-get-its-own-process-id — Rao, Jan 27 '15 at 04:21
@Rao In that post, all of the answers are about getting the JVM pid etc., but what I need is a method that can check for the pid of ANY process by taking a String for the process name — Fifer Sheep, Jan 27 '15 at 08:32

score 5 · Accepted Answer · answered Jan 27 '15 at 16:57

5

An alternative (as the output from ps shouldn't block any buffers)

Integer getPid(processName) {
    'ps -A'.execute()
           .text
           .split('\n')
           .find { it.contains processName }?.split()?.first() as Integer
}

println getPid('groovyconsole')

answered Jan 27 '15 at 16:57

tim_yates

167,322
27
342
338

This work like a charm - thank you!! You are officially on my SO hero list ^_^ – Fifer Sheep Jan 27 '15 at 21:41

cfrick · Answer 2 · 2015-01-27T00:06:54.887

on linux/bsd/... pgrep would make finding a running process alot easier. e.g.

def b = new StringBuffer()
def p = 'pgrep zsh'.execute() // does a zsh run?
p.waitForProcessOutput(b,b)
assert b // any output?  there is a zsh running
assert b.split().first().toInteger() > 0 // split, take first and cast to integer for the first pid returned

b = new StringBuffer()
p = 'pgrep nuffin'.execute() // use `-f` to use the "whole" command line
p.waitForProcessOutput(b,b)
assert !b // empty string?  process not running

Getting PID for a process using Groovy

2 Answers2