Using SDL2 with CMake

Question

I'm trying to use CLion to create a SDL2 project. The problem is that the SDL headers can't be found when using #include's.

My CMakeLists.txt file:

cmake_minimum_required(VERSION 2.8.4)
project(ChickenShooter)

set(SDL2_INCLUDE_DIR C:/SDL/SDL2-2.0.3/include)
set(SDL2_LIBRARY C:/SDL/SDL2-2.0.3/lib/x64)

include_directories(${SDL2_INCLUDE_DIR})
set(SOURCE_FILES main.cpp)

add_executable(ChickenShooter ${SOURCE_FILES})
target_link_libraries(ChickenShooter ${SDL2_LIBRARY})

My test main.cpp:

#include <iostream>
#include "SDL.h" /* This one can't be found */

int main(){
    if (SDL_Init(SDL_INIT_VIDEO) != 0){
        std::cout << "SDL_Init Error: " << SDL_GetError() << std::endl;
        return 1;
    }
    SDL_Quit();
    return 0;
}

Thank you for any help you could give me.

Edit: I'm using Windows and CLion is configured to use cygwin64.

trenki · Answer 1 · 2017-06-04T13:29:49.263

This blog post shows how you can do it: Using SDL2 with CMake

On Linux you can use a recent CMake (e.g. version 3.7) and using SDL2 works out of the box.

cmake_minimum_required(VERSION 3.7)
project(SDL2Test)

find_package(SDL2 REQUIRED)
include_directories(SDL2Test ${SDL2_INCLUDE_DIRS})

add_executable(SDL2Test Main.cpp)
target_link_libraries(SDL2Test ${SDL2_LIBRARIES})

Under Windows you can download the SDL2 development package, extract it somewhere and then create a sdl-config.cmake file in the extracted location with the following content:

set(SDL2_INCLUDE_DIRS "${CMAKE_CURRENT_LIST_DIR}/include")

# Support both 32 and 64 bit builds
if (${CMAKE_SIZEOF_VOID_P} MATCHES 8)
  set(SDL2_LIBRARIES "${CMAKE_CURRENT_LIST_DIR}/lib/x64/SDL2.lib;${CMAKE_CURRENT_LIST_DIR}/lib/x64/SDL2main.lib")
else ()
  set(SDL2_LIBRARIES "${CMAKE_CURRENT_LIST_DIR}/lib/x86/SDL2.lib;${CMAKE_CURRENT_LIST_DIR}/lib/x86/SDL2main.lib")
endif ()

string(STRIP "${SDL2_LIBRARIES}" SDL2_LIBRARIES)

When you now configure inside the CMake-GUI application there will be a SDL2_DIR variable. You have to point it to the SDL2 directory where you extracted the dev package and reconfigure then everything should work.

You can then include SDL2 headers by just writing #include "SDL.h".

This doesn't work with Mingw on Windows. The library directory and file names are different in the SDL2 Mingw package. — Emil Laine, Nov 13 '19 at 17:13
just to add to this. the name of the config file for find package should be sdl2-config.cmake — Groshh, May 29 '20 at 15:21

score 27 · Accepted Answer · edited Sep 17 '22 at 23:13

27

Don't set the path to SDL2 by hand. Use the proper find command which uses FindSDL. Should look like:

find_file(SDL2_INCLUDE_DIR NAME SDL.h HINTS SDL2)
find_library(SDL2_LIBRARY NAME SDL2)
add_executable(ChickenShooter main.cpp)
target_include_directories(ChickenShooter ${SDL2_INCLUDE_DIR})
target_link_libraries(ChickenShooter ${SDL2_LIBRARY})

If SDL2 is not found, you have to add the path to SDL2 to CMAKE_PREFIX_PATH, that's the place where CMake looks for installed software.

If you can use Pkg-config, its use might be easier, see How to use SDL2 and SDL_image with cmake

If you feel more comfortable to use a FindSDL2.cmake file similar to FindSDL.cmake provided by CMake, see https://brendanwhitfield.wordpress.com/2015/02/26/using-cmake-with-sdl2/

edited Sep 17 '22 at 23:13

starball

20,030
7
43
238

answered Apr 04 '15 at 13:34

usr1234567

21,601
16
108
128

1

I've got a `Unknown CMake command "find"`. But I could do it using `find_library(SDL)` instead. – Charles Sep 03 '15 at 17:35
2

@charlesrockbass: Thanks for the hint, it should be find_package. – usr1234567 Sep 04 '15 at 08:41
7

SDL is _not_ the same as SDL2, and the default FindSDL.cmake does not look for SDL2. – Cubic Aug 27 '16 at 16:14
https://github.com/fastogt/fastoplayer/blob/master/src/CMakeLists.txt#L352 crossplatfrom – Topilski Alexandr Feb 19 '19 at 17:46
@FRR Great question, but kind of unrelated to this answer. Please open a question, and I'll happily answer it. – usr1234567 Apr 17 '20 at 04:25

Tom · Answer 3 · 2020-12-01T11:26:57.313

I recently discovered the latest version of SDL2 (version 2.0.12) now comes with all the required CMake config/install scripts, so there's no need to use FindSDL anymore.

I downloaded the SDL source from https://www.libsdl.org/download-2.0.php then from the root folder ran...

cmake -S . -B build/debug -G Ninja -DCMAKE_INSTALL_PREFIX=./install -DCMAKE_BUILD_TYPE=Debug
cmake --build build/debug --target install

This will build and install the debug version of the library, you can then also run...

cmake -S . -B build/release -G Ninja -DCMAKE_INSTALL_PREFIX=./install -DCMAKE_BUILD_TYPE=Release
cmake --build build/release --target install

Which will build and install the release version of the library (and because the SDL CMake script uses DEBUG_POSTFIX the release version of the library won't overwrite the debug one as the debug versions all have 'd' appended to their name).

In your CMakeLists.txt file you can then simply do this:

find_package(SDL2 REQUIRED)

add_executable(${PROJECT_NAME} ...)

target_link_libraries(
    ${PROJECT_NAME} PRIVATE
    SDL2::SDL2
    SDL2::SDL2main

You'll need to tell your application where to find the SDL install folder if you used a custom location as I've done in the example. To do this from the root folder of your app run:

cmake -S . -B build/debug -G Ninja -DCMAKE_BUILD_TYPE=Debug -DCMAKE_PREFIX_PATH=</absolute/path/to/install/dir>
cmake --build build/debug

Note: You can use $(pwd) (*nix/macOS) or %cd% (Windows) to create a hybrid relative path which can be very useful.

You can omit both DCMAKE_INSTALL_PREFIX and DCMAKE_PREFIX_PATH if you want to install SDL to the default system location.

In the examples I've opted to use the Ninja generator as it is consistent across macOS/Windows - it can be used with MSVC/Visual Studio, just make sure you run this (path may differ slightly depending on year/version) to add Ninja to your path.

C:\Program Files (x86)\Microsoft Visual Studio\2019\Community\VC\Auxiliary\Build\vcvars64.bat

Update:

One other thing I remembered which is useful on Windows is the ability to copy the SDL .dll file into the application binary directory, this can be achieved like so:

if (WIN32)
# copy the .dll file to the same folder as the executable
add_custom_command(
    TARGET ${PROJECT_NAME} POST_BUILD
    COMMAND ${CMAKE_COMMAND} -E copy_if_different
    $<TARGET_FILE:SDL2::SDL2>
    $<TARGET_FILE_DIR:${PROJECT_NAME}>
    VERBATIM)
endif()

Is there a way to use it but without installing it? I want to fetch it and use it. — eri0o, Nov 22 '20 at 23:40
You could use FetchContent instead of you prefer - it should work much the same. There's some info about it here you might find useful - https://github.com/pr0g/cmake-examples/tree/main/examples/more/fetch-content. Here's an example of using ExternalProject_Add to add SDL (essentially automates the above steps - https://github.com/pr0g/sdl-bgfx-imgui-starter/blob/main/third-party/CMakeLists.txt) — Tom, Nov 24 '20 at 09:52
Thanks! Those links are useful! :) Last one was exactly what I was looking for! Thank you! — eri0o, Nov 24 '20 at 11:27

genpfault · Answer 4 · 2022-06-22T12:46:05.013

10

You can also pull in the SDL source repository as a submodule and build/link it statically along with your main program via add_subdirectory() and target_link_libraries():

cmake_minimum_required( VERSION 3.18.0 )
project( sdl2-demo )

set( SDL_STATIC ON CACHE BOOL "" FORCE )
set( SDL_SHARED OFF CACHE BOOL "" FORCE )
# 'external/sdl' should point at a SDL
# repo clone or extracted release tarball
add_subdirectory( external/sdl )

add_executable(
    ${CMAKE_PROJECT_NAME}
    "src/main.cpp"
    )
target_link_libraries( ${CMAKE_PROJECT_NAME} SDL2main SDL2-static )

(At least as of the release-2.0.9 tag, possibly earlier.)

edited Jun 22 '22 at 12:46

answered Nov 12 '18 at 17:35

genpfault

51,148
11
85
139

1

Be aware that this cmake script can fail if the path to project contains spaces (at least on Mac OS). Other than that, indeed it is an easy way to statically link to SDL2. – Max Klint May 08 '20 at 16:08
how to do this with sdl2 image? – jksevend Feb 28 '23 at 14:25
1

@jksevend: [In a similar way](https://github.com/genpfault/sdl-base/blob/main/external/CMakeLists.txt#L10-L17). Don't forget [the `add_subdirectory()` in the root `CMakeLists.txt`](https://github.com/genpfault/sdl-base/blob/main/CMakeLists.txt#L22) – genpfault Feb 28 '23 at 14:47
thanks thats helpful. Having trouble building the SDL_image repo from source, SDL works fine. I try out your approach – jksevend Feb 28 '23 at 15:56

score 2 · Answer 5 · answered Feb 19 '19 at 17:42

Using the SDL2 CMake module that I developed, you can integrate the SDL2 library easily in a modern and portable approach.

You should just copy the module in cmake/sdl2 (Or just clone the modules repo) in your project:

git clone https://github.com/aminosbh/sdl2-cmake-modules cmake/sdl2

Then add the following lines in your CMakeLists.txt:

list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake/sdl2)
find_package(SDL2 REQUIRED)
target_link_libraries(${PROJECT_NAME} SDL2::Main)

Note: If CMake didn't find the SDL2 library (in Windows), we can specify the CMake option SDL2_PATH as follows:

cmake .. -DSDL2_PATH="/path/to/sdl2"

For more details, please read the README.md file.

The SDL2 CMake modules support other related libraries : SDL2_image, SDL2_ttf, SDL2_mixer, SDL2_net and SDL2_gfx.

You can find a list of examples/samples and projects that uses these modules here : https://github.com/aminosbh/sdl-samples-and-projects

score 2 · Answer 6 · answered May 04 '19 at 13:34

With the compiled version of SDL2-2.0.9 with MinGW-w64 in Windows, the following configuration works for me:

find_package(SDL2 REQUIRED)

add_executable(sdl-test ${SOURCES})

target_link_libraries(sdl-test
  mingw32
  SDL2::SDL2main
  SDL2::SDL2
)

A longer explanation

By reading SDL2Targets.cmake file, I've learned that SDL2 is providing several targets:

SDL2::SDL2main (lib/libSDL2main.a)
SDL2::SDL2 (lib/libSDL2.dll.a)
SDL2::SDL2-static (lib/libSDL2-static.a)

Each of them has INTERFACE_INCLUDE_DIRECTORIES defined, which means we don't need to manually specify include_directories for SDL2.

But by only adding SDL2::SDL2main and SDL2::SDL2 as target_link_libraries is not enough. The g++ compiler might be complaining about "undefined reference to `WinMain'".

By inspecting the compiler options, I found that the SDL2 libraries are added before -lmingw32 option. In order to make the -lmingw32 option comes before SDL2 libraries, we have to also specify mingw32 as the first target_link_libraries. Which will make this configuration working.

The command that I have used for building it is:

$ mkdir build && cd build && cmake .. -G"MinGW Makefiles" && cmake --build .

The only small problem here is in the finally generated compiler options, the -lmingw32 option is duplicated. But since it doesn't affect the linking process, I've ignored it for now.

score 2 · Answer 7 · answered Aug 21 '21 at 20:54

2

On Linux, in Clion, this works:

cmake_minimum_required(VERSION 3.20)
project(first_game)

set(CMAKE_CXX_STANDARD 14)

find_package(SDL2 REQUIRED)
include_directories(${SDL2_INCLUDE_DIRS})

add_executable(${PROJECT_NAME} main.cpp)
target_link_libraries(${PROJECT_NAME} ${SDL2_LIBRARIES})

answered Aug 21 '21 at 20:54

Eric

22,183
20
145
196

Your answer only works for 2.0.12 or newer. It lacks some explanation – usr1234567 Dec 03 '22 at 10:30

score 0 · Answer 8 · edited Aug 07 '16 at 09:10

0

You don't seems to have a CMake error whike generating your make file. But I think your problem is, the SDL Header are located in a subfolder named "SDL2".

Change your CMakeLists.txt to include

C:/SDL/SDL2-2.0.3/include/SDL2

Instead of

C:/SDL/SDL2-2.0.3/include

edited Aug 07 '16 at 09:10

Emil Laine

41,598
9
101
157

answered Feb 08 '15 at 17:18

jordsti

746
8
12

score 0 · Answer 9 · answered Mar 23 '18 at 12:07

I had the same problem and none of the other solutions worked. But I finally got it working by following this solution : How to properly link libraries with cmake?

In a nutshell, the problem was that the SDL2 library was not linked properly in my CMakeLists.txt. And by writing this into the file, it worked (more explainations in the other thread) :

project (MyProgramExecBlaBla)  #not sure whether this should be the same name of the executable, but I always see that "convention"
cmake_minimum_required(VERSION 2.8)

ADD_LIBRARY(LibsModule 
    file1.cpp
    file2.cpp
)

target_link_libraries(LibsModule -lpthread)
target_link_libraries(LibsModule liblapack.a)
target_link_libraries(LibsModule -L/home/user/libs/somelibpath/)
ADD_EXECUTABLE(MyProgramExecBlaBla main.cpp)
target_link_libraries(MyProgramExecBlaBla LibsModule)

score 0 · Answer 10 · answered Jan 30 '19 at 23:09

Highlighting the steps of how I was able to eventually accomplish this using the FindSDL2.cmake module:

Download SDL2-devel-2.0.9-VC.zip (or whatever version is out after this answer is posted) under the Development Libraries section of the downloads page.
Extract the zip folder and you should see a folder similar to "SDL2-2.0.9". Paste this folder in your C:\Program Files(x86)\ directory.
Copy the FindSDL2.cmake module and place it in a new "cmake" directory within your project. I found a FindSDL2.cmake file in the answer referenced in the Accepted Answer: https://brendanwhitfield.wordpress.com/2015/02/26/using-cmake-with-sdl2/
Find the SET(SDL2_SEARCH_PATHS line in the FindSDL2.cmake and add your copied development directory for SDL2 as a new line: "/Program Files (x86)/SDL2-2.0.9" # Windows
Within my CMakeLists.txt, add this line: set(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)

After this, running CMake worked for me. I'm including the rest of my CMakeLists just in case it further clarifies anything I may have left out:

cmake_minimum_required(VERSION 2.8.4)
project(Test_Project)

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")

# includes cmake/FindSDL2.cmake
set(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)

set(SOURCE_FILES src/main.cpp src/test.cpp)
add_executable(test ${SOURCE_FILES})

# The two lines below have been removed to run on my Windows machine
#INCLUDE(FindPkgConfig)
#PKG_SEARCH_MODULE(SDL2 REQUIRED sdl2)
find_package(SDL2 REQUIRED)

INCLUDE_DIRECTORIES(${SDL2_INCLUDE_DIR})
TARGET_LINK_LIBRARIES(chip8 ${SDL2_LIBRARY})

Hope this helps somebody in the near future.

It's `${SDL2_LIBRARIES}` (plural). The singular may work, but that would be fortuitous. — Alexis Wilke, Aug 01 '21 at 03:54

score -1 · Answer 11 · answered Sep 21 '16 at 18:41

by the time of my answer, SDL2 is provided with sdl2-config executable (as I understand, developers call him "experimental"). After "make install" of SDL2 you can try calling it from terminal with sdl2-config --cflags --libs to see what it outputs.

And then you can add call to it in your makefile:

set(PROJECT_NAME SomeProject)

project(${PROJECT_NAME})

execute_process(COMMAND /usr/local/bin/sdl2-config --libs RESULT_VARIABLE CMD_RES OUTPUT_VARIABLE SDL2_CFLAGS_LIBS ERROR_VARIABLE ERR_VAR OUTPUT_STRIP_TRAILING_WHITESPACE)
message("SDL2_CFLAGS_LIBS=${SDL2_CFLAGS_LIBS}; CMD_RES=${CMD_RES}; ERR_VAR=${ERR_VAR}")

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 ${SDL2_CFLAGS_LIBS}")

set(SOURCE_FILES main.cpp)
add_executable(${PROJECT_NAME} ${SOURCE_FILES})

Here I have a problem - if I only put an executable name without path like

execute_process(COMMAND sdl2-config --libs <...>

I get error "No such file", i.e. cmake does not search in current path and I don't know how to write it properly by now.

One more notice: in my makefile I do not user --cflags option, because cmake finds includes correctly and I do not need to specify them explicitly.

score -1 · Answer 12 · answered Mar 24 '20 at 21:29

For your information, I was able to successfully cmake and compile SDL2_ttf while linking to SDL2 source code.

At first I was getting errors due to cmake not being able to locate SDL2, even though it was specified in cmake using the SLD2_DIR variable in cmake.

It seems that for some reason cmaking SDL2 fails to create the SDL2Targets.cmake file which is searched for by SDL2_ttf

If this is the case for you, get the SDL2Targets.cmake file from https://bugs.archlinux.org/task/57972 and modify the file like so:

You can remove the following lines:

get_filename_component(_IMPORT_PREFIX "${CMAKE_CURRENT_LIST_FILE}" PATH)
get_filename_component(_IMPORT_PREFIX "${_IMPORT_PREFIX}" PATH)
get_filename_component(_IMPORT_PREFIX "${_IMPORT_PREFIX}" PATH)
get_filename_component(_IMPORT_PREFIX "${_IMPORT_PREFIX}" PATH)
if(_IMPORT_PREFIX STREQUAL "/")
    set(_IMPORT_PREFIX "")
endif()

and add this one:

set(_IMPORT_PREFIX "C:/SDL2-2.0.12")

Obviously change the filepath to the place you unpacked the SDL2 source code

I'm not sure if this is exactly your issue, but there it is.

Using SDL2 with CMake

12 Answers12

Linked

Related