How do I check for the existence of an external file with XSL?

Question

I've found a lot of examples that reference Java and C for this, but how do I, or can I, check for the existence of an external file with XSL.

First, I realize that this is only a snippet, but it's part of a huge stylesheet, so I'm hoping it's enough to show my issue.

    <!-- Use this template for Received SMSs -->
<xsl:template name="ReceivedSMS">
    <!-- Set/Declare "SMSname" variable (local, evaluates per instance) -->
    <xsl:variable name="SMSname">
        <xsl:value-of select=" following-sibling::Name"/>
    </xsl:variable>
    <fo:table font-family="Arial Unicode MS" font-size="8pt" text-align="start">
        <fo:table-column column-width=".75in"/>
        <fo:table-column column-width="6.75in"/>
        <fo:table-body>
            <fo:table-row>
                <!-- Cell contains "speakers" icon -->
                <fo:table-cell display-align="after">
                    <fo:block text-align="start">
                        <fo:external-graphic src="../images/{$SMSname}.jpg" content-height="0.6in"/>

What I'd like to do, is put in an "if" statement, surronding the {$SMSname}.jpg line. That is:

                     <fo:block text-align="start">
                        <xsl:if test="exists( the external file {$SMSname}.jpg)">
                            <fo:external-graphic src="../images/{$SMSname}.jpg" content-height="0.6in"/>                            
                        </xsl:if>
                        <xsl:if test="not(exists( the external file {$SMSname}.jpg))">
                            <fo:external-graphic src="../images/unknown.jpg" content-height="0.6in"/>                            
                        </xsl:if>
                    </fo:block>

Because of "grouping", etc., I'm using XSLT 2.0. I hope that this is something that can be done. I hope even more that it's something simple.

As always, thanks in advance for any help. LO

Good question (+1). Short answer: cannot be currently done with pure XSLT 2.0. Long answer and explanation: see my answer. :) — Dimitre Novatchev, May 27 '10 at 01:27
It looks like it will be possible with EXPath extensions - file package (http://expath.org/spec/file)... — potame, Jun 08 '16 at 14:52
I have done it for myself, Check my answer for the solution. — Bharat Darakh, Jan 30 '19 at 07:03

score 12 · Answer 1 · answered Jan 14 '13 at 17:53

For anyone else who might stumble upon this old question, by piecing together information from various sources on the internet, I came up with this XSLT2 function that uses a Java extension for checking whether a file exists:

<?xml version="1.0" encoding="UTF-8"?>

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:java="http://www.java.com/"
  exclude-result-prefixes="java xs">

  <xsl:function name="java:file-exists" xmlns:file="java.io.File" as="xs:boolean">
    <xsl:param name="file" as="xs:string"/>
    <xsl:param name="base-uri" as="xs:string"/>

    <xsl:variable name="absolute-uri" select="resolve-uri($file, $base-uri)" as="xs:anyURI"/>
    <xsl:sequence select="file:exists(file:new($absolute-uri))"/>
  </xsl:function>

</xsl:stylesheet>

You can then use the function like this:

<xsl:if test="java:file-exists($filename, base-uri())">
  <!-- ... -->
</xsl:if>

This works at least with Saxon 9.1.0.5J — haven't tested it with any other XSLT processors.

Note: If the file for whose existence you're checking is an XML file and you're using XSLT2, you can also use the built-in doc-available() function:

<xsl:if test="doc-available('hello_world.xml')">
  <!-- ... -->
</xsl:if>

With PE9.4, I get the error message `Error at xsl:sequence on line 32 column 66 of propertize-opf.xslt: XPST0017 XPath syntax error at char 12 on line 32 near {...xists(file:new($absolute-ur...}: Cannot find a matching 1-argument function named {java.io.File}new(). For diagnostics on calls to Java methods, use the -TJ command line option or set the Configuration property FeatureKeys.TRACE_EXTERNAL_FUNCTIONS` — , Feb 17 '13 at 17:37
@torazaburo: Are you sure you're passing `base-uri()` as the second argument to `java:file-exists()`? As in: ` `. Also, note that this function will only work on XSLT2.0. — Eero Helenius, Feb 18 '13 at 11:59

score 11 · Accepted Answer · answered May 27 '10 at 01:25

No, this cannot be done using XSLT 2.0/XPath 2.0.

The XSLT 2.0 function unparsed-text-available() is only suitable for locating text files and even if a text file with the specifies URI exists this function may return false(), because it also must read the contents of the file and check that it only contains allowed characters.

From the spec:

"The unparsed-text-available function determines whether a call on the unparsed-text function with identical arguments would return a string.

If the first argument is an empty sequence, the function returns false. If the second argument is an empty sequence, the function behaves as if the second argument were omitted.

In other cases, the function returns true if a call on unparsed-text with the same arguments would succeed, and false if a call on unparsed-text with the same arguments would fail with a non-recoverable dynamic error.

Note:

This requires that the unparsed-text-available function should actually attempt to read the resource identified by the URI, and check that it is correctly encoded and contains no characters that are invalid in XML "

End of quotation.

score 3 · Answer 3 · edited May 23 '17 at 11:33

3

In case someone else needs it and is using fop, I would like to share this answer since it worked for me like a charm.

I've found a solution:

<xsl:when test="fs:exists(fs:new('myfile.html'))" xmlns:fs="java.io.File">
    <!-- do something here... -->
</xsl:when>

and it works independently of XSLT 1.0 or 2.0

edited May 23 '17 at 11:33

Community

1
1

answered Sep 02 '15 at 18:57

elysch

1,846
4
25
43

mdma · Answer 4 · 2010-05-27T00:17:59.320

EDIT: Use unparsed-text-available function. It is part of xslt 2.0, but not XQuery or standalone XPath.

I've left my previous answer here so you can follow the trail of uncertainty...

I don't believe there is a way of doing this in XSLT using the standard functions. You can do it using extension functions, as described here, for java.

There is the unparsed-text-available function, but I'm unsure if this is a standard function. There's an example of it's usage at Zvon. The unparsed-text-available is mentioned here as being part of xslt 2.0, and is supported in Saxon.

pgfearo · Answer 5 · 2016-09-09T14:40:47.553

2

A proposed File Module EXPath specification would support file-system functions such as this (file:exists() in the spec) as standard XPath extension functions. There isn't yet an XSLT implementation for this, but its worth watching.

edited Sep 09 '16 at 14:40

answered May 27 '10 at 09:19

pgfearo

2,087
1
22
27

1

This is not working for me below is error: XPath syntax error at char 30 on line 40 in {...file:exists($htmlFilePath))...}: Cannot find a matching 1-argument function named {http://expath.org/ns/file}exists() – Bharat Darakh Jan 29 '19 at 06:52
Is it dependent on saxon version I am using saxon 8 but don't think that would be the case. – Bharat Darakh Jan 29 '19 at 06:59

score 1 · Answer 6 · answered Sep 14 '17 at 12:46

Back to pgfearo's notice.

A proposed File Module EXPath specification would support file-system functions such as this (file:exists() in the spec) as standard XPath extension functions. There isn't yet an XSLT implementation for this, but its worth watching.

For those who need to check if an file exists or not.

file:exists($path as xs:string)

works fine now.

score 1 · Answer 7 · answered Jan 30 '19 at 07:02

If you still wants to do it in XSLT here is the solution, I have done it for myself as explained below.

This will not working with regular java.io.File class in XSLT. So I have used java.nio.file.Files class.

JARS required - servelt.jar w: is the namespace of the our own Java class where pathFromURI method is defined.

Code:

<xsl:variable name="fileURI" select="u:new($absoluteFilePath)" xmlns:u="java:java.net.URI"/>
<xsl:variable name="filePathFromURI" select="w:pathFromURI($fileURI)"/>
<xsl:variable name="fileNotExist" select="not(files:exists($filePathFromURI, /..)) or files:size($filePathFromURI) = 0"/>

public static java.nio.file.Path pathFromURI(java.net.URI uri) throws Exception {
    return java.nio.file.Paths.get(uri);
}

Paul Sweatte · Answer 8 · 2016-08-26T20:18:55.280

If you need to check for the existence of an XML file, use an external entity and an inline doctype:

<!DOCTYPE foo [ <!ENTITY bar SYSTEM "baz.xml"> ]>

Then add the entity to the stylesheet:

&bar;

The processor will timeout if the file is not found.

If you know the files exist but want to dynamically load one out of many, use the concat function and a choose/when block:

<xsl:variable name="page_name">
<xsl:choose>
  <xsl:when test="$page = 1">
    <xsl:value-of select="'page1.xml'"/>
  </xsl:when>
  <xsl:when test="$page = 2">
    <xsl:value-of select="'page2.xml'"/>
  </xsl:when>
  <!--...-->
  <xsl:when test="$page = 9">
    <xsl:value-of select="'page9.xml'"/>
  </xsl:when>
  <xsl:when test="$page = 10">
    <xsl:value-of select="'page10.xml'"/>
  </xsl:when>
  <xsl:otherwise>
    <xsl:value-of select="'page0.xml'"/>
  </xsl:otherwise>
</xsl:choose>
</xsl:variable>

<xsl:variable name="agree" select="document(concat('include/pages/',$page_name))//processing-instruction()"/>

References

XML External Entity (XXE) Processing

score 0 · Answer 9 · answered Feb 27 '20 at 14:42

For anyone who needs plain XSLT solution for checking if file exist you can just use

unparsed-text-available(concat(system-property('user.dir'),'/filename.text'))

or wrap it into a function

<xsl:function name="functx:file-exists" xmlns:functx="http://www.functx.com">
    <xsl:param name="path"/>
    <xsl:value-of select="unparsed-text-available(concat(system-property('user.dir'),'/',$path))"/>
</xsl:function>

using this unparsed-text-available(concat(system-property('user.dir'),'/filename.text'))=false() will mean that file does not exist.

Have fun!

score 0 · Answer 10 · answered Nov 05 '11 at 09:00

It can't solely be done by standard XSLT, you have to use an extention function or some annoying workaround. There are two methods using extension functions: use of standard java/.NET for custom functions (works with some versions of Saxon, AltovaXML, and others), or use of processor specific extension functions, like saxon:file-last-modified()/saxon:last-modified(). You can find some sample code here, look for intern:file-exists().

If you can't use extension functions, you can either generate an XML file externaly which contains informations about your file system and pass it to your stylesheet, or you can wrap binary images within SVG and than use fn:doc-available().

How do I check for the existence of an external file with XSL?

10 Answers10

Linked