Vb.net : Get MAC Address of only internal Device

Question

We are using the following method to get the MAC addresses.

Imports System.Net.NetworkInformation
Dim nic As NetworkInterface = Nothing
Dim max() As String
Dim i As Integer
Dim nics() As NetworkInterface = NetworkInterface.GetAllNetworkInterfaces()
For Each nic In nics
    max(i) = nic.GetPhysicalAddress().ToString
    i = i + 1
Next

Using the above code we could successfully get all the MAC addresses including the MAC address of a dongle[Plug & Play Device]. But what we wanted is the MAC address of only internal Devices.

How can we get the MAC address of only internal Devices those can be called permanent MAC addresses?

Answer 1

I assume the endpoints in your LAN gets a private IP (as a DHCP response) and the dongle (an external USB GSM modem) gets a global IP address.

The standard ranges for private IP addresses:

• class A network 10.0.0.0 - 10.255.255.255
• class B network 172.16.0.0 - 172.31.255.255
• class C network 192.168.0.0 - 192.168.255.255

You can utilize a regular expression to determine for each interface if it's current ip address is private or not.

you may assist this regular expression (source):

(^10\.)|
(^172\.1[6-9]\.)|(^172\.2[0-9]\.)|(^172\.3[0-1]\.)|
(^192\.168\.)

---

for example, this is a basic regex match of the above in VB.net:

Imports System.Net.NetworkInformation
Imports System.Text.RegularExpressions

Module VBModule

    Sub Main()
        Dim nic As NetworkInterface = Nothing
        Dim max() As String
        Dim nics() As NetworkInterface = NetworkInterface.GetAllNetworkInterfaces()
        For Each nic In nics

            Dim ip = nic.GetIPProperties().UnicastAddresses(0).Address.ToString

            Dim regex As Regex = New Regex("(^10\.)|(^172\.1[6-9]\.)|(^172\.2[0-9]\.)|(^172\.3[0-1]\.)|(^192\.168\.)")
            Dim match As Match = regex.Match(ip)

            If match.Success Then
                Console.WriteLine(ip)
                Console.WriteLine(nic.GetPhysicalAddress().ToString)     
            End If

        Next

    End Sub

End Module

See it in action http://goo.gl/i9N6T9:

Answer 2

The code below returns MAC addresses for the most common durable interfaces (LAN or WLAN). This usually gets the job done. You can add different interface types to the comparison array.

Public Function GetDurableMACAddresses() As IEnumerable(Of String)
    Return From nic In NetworkInterface.GetAllNetworkInterfaces()
           Where ({NetworkInterfaceType.Ethernet, NetworkInterfaceType.Wireless80211}).Contains(nic.NetworkInterfaceType)
           Select macaddress = nic.GetPhysicalAddress().ToString()
End Function

Answer 3

The below function can be used to get the internal MAC address:

Private Function getMacAddress() As String
    Try
        Dim adapters As NetworkInterface() = NetworkInterface.GetAllNetworkInterfaces()
        Dim adapter As NetworkInterface
        Dim myMac As String = String.Empty

        For Each adapter In adapters
            Select Case adapter.NetworkInterfaceType
                'Exclude Tunnels, Loopbacks and PPP
                Case NetworkInterfaceType.Tunnel, NetworkInterfaceType.Loopback, NetworkInterfaceType.Ppp
                Case Else
                    If Not adapter.GetPhysicalAddress.ToString = String.Empty And Not adapter.GetPhysicalAddress.ToString = "00000000000000E0" Then
                        myMac = adapter.GetPhysicalAddress.ToString
                        Exit For
                    End If

            End Select
        Next adapter

        Return myMac
    Catch ex As Exception
        Return String.Empty
    End Try
End Function

It uses the Network Information library, which can be imported using Imports System.Net.NetworkInformation. The above code also excludes VPNs, tunnels, bridges, etc.

To test this I made a sample project which can be downloaded here, and gave the correct MAC address output as:

The system's Media Access Control (MAC) address is 142D27B97FD6

This is the correct MAC address as tested by viewing the properties of my wireless adapter:

Answer 4

Without additional information about the NIC itself it is not possible to identitfy "internal" ones - but : if you build a CLR (C++) - library which calls native functions to retrieve necessary information like "on which bus is the NIC located" you may be able to assemble grouping information about the NICs.

Hint : it is easily possible to use CLR-libraries within your VB.NET - application ... simply add the project, import its namespace and you're good to go : https://msdn.microsoft.com/en-us/library/ms235638%28v=vs.90%29.aspx

At first, you will need to query all NICs via SetupDiGetClassDevs with the parameter GUID_DEVCLASS_NET, then enumerate that list with SetupDiEnumDeviceInfo, the property DEVPKEY_Device_BusTypeGuid is what you're interested in, you can retrieve it via SetupDiGetDeviceProperty - after all your devices are enumerated you are now able to group them into bus-types, at least one of them is the USB bustype.

Additional filtering may be done via all of the other properties listed here, here and here.

Well, thats quite the expensive solution but it will actually enable you to filter out the "internal" NICs, good luck - feel free to ask any questions.

edit : Apparently there is also a GUID for USB devices, so if you simply retrieve the property DEVPKEY_DeviceInterface_ClassGuid and compare it to GUID_DEVINTERFACE_USB_DEVICE you might be able to filter out USB-NICs on the fly, without the need for additional grouping ... this looks very promising