XSLT - How to specify where dot point text will continue on new line

Question

I have the following XML element being converted to HTML by XSLT. My XSLT processor is Microsoft 1.

When I call an element from my XML to be displayed in an <li></li> tag in XSLT I want to be able to specify where an individual <li></li> text content will continue on a new line once it reaches a certain point.

I tried adding a <br></br> into where I wanted the breaks to occur in my XML elements but it just results in a new line having a bullet point next to it which I don't want.

What is the best way to do this?

Here's an example of my code:

XML ELEMENT being called into <li></li>. In this example two <li></li> would be created as my XSLT splits the element into different dot points through the ; as a delimitor.

<research>Strategies and Approaches to Teaching and Learning Cross Cultures,  Office for Learning and Teaching,  
    LOL - Grant (pre-2013),  2008 - 2052, $90,000;  Parkour strategies and parallel jumps for spatial data monitoring and join processing,  
    Right Wing Politics,  JSA Early Career Artifact - Grant,  2004 - 20010,  $14,0000.
    </research>

Answer 1

If you can and want to insert line breaks manually in the source XML document, I would suggest you use some special string for this, not a markup element such as <br/>. Then you can call another recursive template to replace any instances of the special string with a real HTML line break.

For example, using the § symbol to indicate a requested line break in the following input XML:

<research>Strategies and Approaches to Teaching and Learning Cross Cultures,  Office for Learning and Teaching,  
LOL - Grant (pre-2013),  2008 - 2052, §$90,000;  Parkour strategies and parallel jumps for spatial data monitoring and join processing,  
Right Wing Politics,  JSA Early Career Artifact - Grant,  2004 - 20010,  $14,0000.
</research>

then, after having your XSLT call:

<ul>
    <xsl:call-template name="tokenize">
        <xsl:with-param name="text" select="research"/>
    </xsl:call-template>
</ul>

you need to modify the tokenizing template from your previous question to:

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="';'"/>
        <xsl:variable name="token" select="substring-before(concat($text, $delimiter), $delimiter)" />
        <xsl:if test="$token">
            <li>
                <xsl:call-template name="replace">
                    <xsl:with-param name="text" select="$token"/>
                </xsl:call-template>
            </li>
        </xsl:if>
        <xsl:if test="contains($text, $delimiter)">
            <!-- recursive call -->
            <xsl:call-template name="tokenize">
                <xsl:with-param name="text" select="substring-after($text, $delimiter)"/>
            </xsl:call-template>
        </xsl:if>
</xsl:template>

and add the replacing template:

<xsl:template name="replace">
    <xsl:param name="text"/>
    <xsl:param name="search-string" select="'§'"/>
    <xsl:choose>
        <xsl:when test="contains($text, $search-string)">
            <xsl:value-of select="substring-before($text, $search-string)"/>
            <br/>
            <xsl:call-template name="replace">
                <xsl:with-param name="text" select="substring-after($text, $search-string)"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$text"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

Answer 2

Here is a short solution that doesn't use any <xsl:choose>, <xsl:when> or <xsl:otherwise>:

<xsl:stylesheet version="1.0"  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
    <ul>
      <xsl:apply-templates select="research"/>
    </ul>
 </xsl:template>

 <xsl:template match="research/text()[normalize-space()]" name="split">
     <xsl:param name="pText" select="."/>
     <xsl:if test="normalize-space($pText)">
       <li>
         <xsl:call-template name="replace">
           <xsl:with-param name="pText" select="substring-before(concat($pText, ';'), ';')"/>
         </xsl:call-template>
       </li>
       <xsl:call-template name="split">
         <xsl:with-param name="pText" select="substring-after($pText, ';')"/>
       </xsl:call-template>
     </xsl:if>
 </xsl:template>

 <xsl:template name="replace">
   <xsl:param name="pText"/>
   <xsl:if test="normalize-space($pText)">
       <xsl:value-of select="substring-before(concat($pText, '§'),'§')"/>
       <xsl:if test="contains($pText, '§')">
           <br/>
         <xsl:call-template name="replace">
           <xsl:with-param name="pText" select="substring-after($pText, '§')"/>
         </xsl:call-template>
       </xsl:if>
    </xsl:if> 
 </xsl:template>
</xsl:stylesheet>

When this transformation is applied on this source XML document (the originally-provided one with inserted ';' for line item and '§' for newline):

<research>Strategies and Approaches to Teaching and Learning Cross Cultures,  Office for Learning and Teaching,  
LOL - Grant (pre-2013),  2008 - 2052, §$90,000;  Parkour strategies and parallel jumps for spatial data monitoring and join processing,  
Right Wing Politics,  JSA Early Career Artifact - Grant,  2004 - 20010,  §$14,0000.
</research>

the wanted, correct result is produced:

<ul>
  <li>Strategies and Approaches to Teaching and Learning Cross Cultures,  Office for Learning and Teaching,  
LOL - Grant (pre-2013),  2008 - 2052, <br />$90,000</li>
  <li>  Parkour strategies and parallel jumps for spatial data monitoring and join processing,  
Right Wing Politics,  JSA Early Career Artifact - Grant,  2004 - 20010,  <br />$14,0000.
</li>
</ul>

and this is displayed by the browser as:

• Strategies and Approaches to Teaching and Learning Cross Cultures, Office for Learning and Teaching, LOL - Grant (pre-2013), 2008 - 2052,
  $90,000
• Parkour strategies and parallel jumps for spatial data monitoring and join processing, Right Wing Politics, JSA Early Career Artifact - Grant, 2004 - 20010,
  $14,0000.

Answer 3

Browsers seem to treat <br></br> and <br/> differently, although I've never seen one add a new bullet point. I think <br/> will work for your needs.