Updating groovy object fields from a map

Question

In groovy we can easily create objects from maps and fill the corresponding fields automatically:

def myAddress = new Address([street:"King's street", number:"1200"])

Is it possible to also update an existing object from a map without recreating it? Something like...

myAddress.update([zip: "30555050", city: "London"])

to bad `myAddress.properties.putAll` does not work – cfrick Apr 14 '15 at 07:14 — cfrick, Apr 14 '15 at 07:14

score 16 · Accepted Answer · answered Apr 14 '15 at 05:05

16

You can use object."${variable}" accessors to do this:

map.each { key, value ->
    object."${key}" = value
}

You can then create a method that does this and install that on Object.metaClass and it will be available everywhere:

@Canonical
class MapSet {

    String name
    int count

    static def setAttributesFromMap(Object o, Map<String, Object> map) {
        map.each { key, value ->
            o."${key}" = value
        }
    }

    static void main(String[] args) {
        Object.metaClass.update = {
            setAttributesFromMap delegate, it
        }

        def o = new MapSet([
                name: "foo",
                count: 5
        ])

        assert o.name == "foo"
        assert o.count == 5

        o.update([
                name: "bar",
                count: 6
        ])

        assert o.name == "bar"
        assert o.count == 6
    }
}

answered Apr 14 '15 at 05:05

Raniz

10,882
1
32
64

Good one @Raniz. Although I will need some time to figure out the best place to "install" that behaviour on my Grails app. Maybe on bootstrap.groovy. Any suggestion? – Cléssio Mendes Apr 14 '15 at 05:38
2

Works as excptected. And implementing that on boostrap.groovy (for a Grails application) seems to do the job. Thanks. – Cléssio Mendes Apr 14 '15 at 05:57
I'm not a Grails developer so can't help you there. – Raniz Apr 14 '15 at 05:57
1

An useful update: testing for property availlability before setting might by a good idea `if (object.hasProperty(key))` – Cléssio Mendes Apr 16 '15 at 05:10

score 6 · Answer 2 · answered Oct 15 '18 at 17:25

After looking up/learning from Szymon's Excellent answer and finding a different way to invoke the helper, it seems like the answer can be simplified to:

InvokerHelper.setProperties(myAddress, [zip: "30555050", city: "London"])"

which is amazingly close to your requested

myAddress.update([zip: "30555050", city: "London"])

I added this as a comment to his question but it's so easy I thought it deserved a terse top-level answer of it's own.

score 5 · Answer 3 · answered Apr 14 '15 at 04:41

5

You can use InvokeHelper category and setProperties method, here is a short example:

import groovy.transform.EqualsAndHashCode
import groovy.transform.ToString
import org.codehaus.groovy.runtime.InvokerHelper

@EqualsAndHashCode
@ToString
class Address {
    String street
    String number
    String city
}

Address mainAddress = new Address(street: 'Test', number: '2B', city: 'London')

use InvokerHelper, {
    mainAddress.setProperties([street: 'Lorem', number: 'Ipsum'])
}

assert mainAddress.street == 'Lorem'
assert mainAddress.number == 'Ipsum'
assert mainAddress.city == 'London'

Although if you can avoid mutable objects, it's better for you. Otherwise you have to think about thread-safety to do not run into concurrency problems. You can use previous example to create a static method that expects 2 arguments: the existing object and a map of properties to update. In result you get a new instance that contains updated fields. Also you can make your class an immutable one.

answered Apr 14 '15 at 04:41

Szymon Stepniak

40,216
10
104
131

Thanks @Szymon Stepniak. I will try your solution. But should I really be worried about thread safety if my Address object is created localy and used only, say, during an http request? Or are you just warning me in case my object is obtained from some underlying framework (like hibernate) and thus, potentilaly shared by other threads? – Cléssio Mendes Apr 14 '15 at 05:11
1

It depends on the use case - if you start sharing your object between multiple threads, you **might** run into concurrency problems. If you use it only as a local variable, then you don't have to worry about it. Just keep it in mind, it's worth thinking about it :-) – Szymon Stepniak Apr 14 '15 at 05:15
Either the libraries have been updated since this was written or the example is just unnecessarily obtuse--instead of the use block you should be able to simply use "InvokerHelper.setProperties(mainAddress, [street: 'Lorem', number: 'Ipsum'])" – Bill K Oct 15 '18 at 17:20

Updating groovy object fields from a map

3 Answers3

Linked