How to get path from a variable

Question

Following How to get folder path from file path with CMD

I want to strip the path (without the filename) from a variable. following the logic of the methods discussed above I would like to use batch bellow, which doesn't work. any takers? possible?

set cpp="C:\temp\lib.dll"
echo %cpp% 
"C:\temp\lib.dll"
echo %~dpcpp
"C:\temp\" > doesn't work

Patrick Cuff · Answer 1 · 2010-06-03T14:32:10.380

1

You can use the for command, like so:

set cpp="C:\temp\lib.dll" 

:: Print the full path and file name:
echo %cpp%  

:: Print just the path:
for %%P in (%cpp%) do echo %%~dpP

edited Jun 03 '10 at 14:32

answered Jun 03 '10 at 13:51

Patrick Cuff

28,540
12
67
94

I tried this without success - admittedly it was on WINE on Linux so perhaps the interpreter hadn't been fully compatible with Microsoft Windows... – PP. Jun 03 '10 at 15:17
@PP: Hmmmm, this works on my XP, Windows 7, Server 2003 and Server 2008 boxes. – Patrick Cuff Jun 03 '10 at 16:29
works on win7, i like this but learning the CALL way was a mind opener for me, so i give it the V – yoshco Jun 06 '10 at 08:29

PP. · Accepted Answer · 2010-06-03T08:57:11.580

Tested: demo.bat

@echo off
echo "Setting cpp"
set cpp="C:\temp\lib.dll"

echo "Calling JustGetPath"
call :JustGetPath %cpp%

echo "Returning result"
echo %_RESULT%

echo "Quitting"
goto :eof

:JustGetPath
echo "  +JustGetPath( %1 )"
set _RESULT=%~dp1

echo "  -JustGetPath()"
GOTO :eof

:eof

Outputs the following when run:

"Setting cpp"
"Calling JustGetPath"
"  +JustGetPath( C:\temp\lib.dll )"
"  -JustGetPath()"
"Returning result"
C:\temp\
"Quitting"

How to get path from a variable

2 Answers2