How to get the next sibling with GPathResult

Question

How can I get the next sibling of an GPathResult? For example I have the following code:

def priorityIssue = xmlReport.'**'.find { Issue ->
   Issue.Priority.text() == priority
}

How do I get priorityIssue's next sibling?

Thanks!

Does my answer solve the problem? – Opal Apr 16 '15 at 12:08 — Opal, Apr 16 '15 at 12:08

score 6 · Accepted Answer · answered Apr 15 '15 at 16:30

6

More or less this is the way to go:

import groovy.util.XmlSlurper

def xml = new XmlSlurper().parseText('''
<issues>
    <issue>
        <id>1</id>
        <priority>1</priority>
    </issue>
    <issue>
        <id>2</id>
        <priority>2</priority>
    </issue>
</issues>
''')
def p = '1' 
def priorityIssue = xml.'**'.find { issue ->
    issue.priority.text() == p
}
def kids = priorityIssue.parent().children().list()
def idx = kids.indexOf(priorityIssue)
def sibling = kids[++idx]
assert sibling.id.text() == '2'

answered Apr 15 '15 at 16:30

Opal

81,889
28
189
210

1

As for Groovy 2.3.6 the `.list()` part is excessive and leads to a runtime error. Alles fine without it. – Pavel Vlasov Nov 12 '16 at 21:34
@PavelVlasov without the list() the rest of the code doesn't work and that is the answer to get the next sibling. – Pablo Pazos Apr 20 '18 at 05:06

score 0 · Answer 2 · answered Aug 04 '23 at 07:51

The solution with indexOf() works only if you search for a node with unique text content. The problem is, that NodeChild instances are always compared by text(), see GPathResult#hashCode(). I had to get to the actual nodes instead of their proxies NodeChild.

xml = new groovy.util.XmlSlurper().parseText('''\
<issues>
  <issue>
    <first/>
    <priority>1</priority>
  </issue>
  <issue>   
    <second/>
    <priority>2</priority>
  </issue>
  <issue>   
    <third/>
    <priority>1</priority>
  </issue>  
</issues>
''')

third = xml.'**'.find{it.name() == 'third'}
thirdIssue = third.parent()
issues = thirdIssue.parent().children()
println 'wrong: ' + issues.list().indexOf(thirdIssue)
println 'right: ' + issues.findIndexOf{it[0] == thirdIssue[0]}

Extra tip: You can also use Integer.toHexString(System.identityHashCode(issue)) to check, what instances are you dealing with.

How to get the next sibling with GPathResult

2 Answers2