0

I'm hoping someone may be able to help.

Dropbox stores its path in a file called 'info.json'. The contents of my file is as follows:

{"personal": {"path": "C:\\Users\\Sam\\Dropbox", "host": 241656592}}

{"business": {"path": "C:\\Common\\Allusers\\Dropbox", "host": 45143292}}

I need to extract the 'personal' path only to a Windows CMD variable %dropboxpath% using only a windows batch script. I have tried using FOR and FINDSTR but couldn't make it work.

The other issue is stripping away the extra backslashes in the path to leave 'C:\Users\Sam\Dropbox'.

I believe FINDSTR should locate the 'personal' line and FOR should extract everything after "path": but before , "host" and then somehow, remove the double backslashes.

Hope this makes sense and really appreciate any help you could give.

Many thanks, Sam

Vikasdeep Singh
  • 20,983
  • 15
  • 78
  • 104
BLS
  • 5
  • 2
  • Sounds easy. Are these two lines of code the only content of the file? You are talking about double backslashes but I can't see any in the two lines you've posted. – MichaelS Apr 23 '15 at 08:25

3 Answers3

1
@ECHO OFF
SETLOCAL
FOR /f "tokens=1,3*delims={:" %%a IN (q29817666.txt) DO IF /i "%%~a"=="personal" (
 FOR %%p IN (%%c) DO SET "dropboxpath=%%~p"&GOTO process
)
:process
SET "dropboxpath=%dropboxpath:\\=\%"
ECHO dropboxpath=%dropboxpath%

GOTO :EOF

I used a file named q29817666.txt containing your data for my testing.

The tokens/delimiters combination selects "personal" to %%a, a space to%%band "C:\Users\Sam\Dropbox", "host": 241656592}}to%%c`

if %%a (stripped of enclosing quotes) is equal to the string personal. %%c is then processed as a series of elements separated by spaces and commas. Since the first element is of interest and it's quoted, then %%p will acquire "C:\\Users\\Sam\\Dropbox" and this, stripped of enclosing quotes will be assigned to the variable dropbox and the loop is then terminated by the goto.

Then replace double-backslashes with single. Done.

Magoo
  • 77,302
  • 8
  • 62
  • 84
  • Thank you Mango. I accepted the first solution as it came up quicker but very kind of you too. Interesting to see another route to get the same path. I note you didn't need to use 'setlocal enableextensions disabledelayedexpansion'. Are there pro's and con's to either method? – BLS Apr 23 '15 at 15:15
  • Hmm - actually, responses are listed in reverse-order of being lodged, but no matter. The extra options to `setlocal` are a belt-and-braces approach to ensure that `cmd` is running in default mode. My attitude is that if you change `cmd`'s mode, then you should know what you're doing, so it's not required ad leads to having to explain irrelevancies. – Magoo Apr 23 '15 at 15:44
  • @BLS, the default configuration is extensions enabled, delayed expansion disabled, and is a safe configuration. BUT this configuration can be changed and the new one set as default, and this can make that a working batch file starts to fail. So, just to be sure how the batch file is running, I include it. – MC ND Apr 23 '15 at 15:50
1
@echo off
    setlocal enableextensions disabledelayedexpansion

    set "file=info.json"

    for /f usebackq^ tokens^=2^,6^ delims^=^" %%a in ("%file%") do (
        if /i "%%a"=="personal" set "dropboxpath=%%~fb"
    )
    echo %dropboxpath%

Using the quotes as delimiters, split the line, so delimiters and tokens are

{"personal": {"path": "C:\\Users\\Sam\\Dropbox", "host": 241656592}}    
 ^        ^   ^    ^  ^                       ^  ^    ^
1 2        3   4    5  6                       7  8    9

we request the fourth and sixth tokens into %%a and %%b and if %%a is personal, then %%b is the path

Or, you can try with 

@echo off
    setlocal enableextensions disabledelayedexpansion

    set "file=info.json"

    for /f "delims=" %%a in ('findstr /l /i /c:"{\"personal\"" "%file%"'
    ) do for %%b in (%%a
    ) do for /f "tokens=4 delims=\:" %%c in ("%%~b"
    ) do set "dropboxpath=%%~fb"

    echo %dropboxpath%
  • findstr is used to find the required line in the input file. This line retrieved by ...
  • for /f %%a who called the findstr command. For each retrieved line ...
  • for %%b will iterate over the elements in the line stored in %%a and for each ...
  • for /f %%c will split the element using colon and backslash as delimiters and trying to find the fouth token. As the only element in the line with four tokens is the path...
  • we set the variable to the full path of the element
MC ND
  • 69,615
  • 8
  • 84
  • 126
0

As you need to modify and evaluate your variables at run time and not at parse time, you will need to use EnableDelayedExpansion and !...! instead of %...%. However, this code will work if the two lines you've posted are correct.

@ECHO OFF
SETLOCAL EnableDelayedExpansion
FOR /F "tokens=*" %%a IN (scanword.txt) DO (
    SET line=%%a
    IF "!line:~2,8!"=="personal" SET dropboxpath=%%a
)
FOR /F "tokens=3" %%a IN ("!dropboxpath!") DO (
    SET dropboxpath=%%a
)
SET dropboxpath=!dropboxpath:"=!
SET dropboxpath=!dropboxpath:,=!
SET dropboxpath=!dropboxpath:\\=\!
ECHO !dropboxpath!
PAUSE

The path will be stored in !dropboxpath! and not in %dropboxpath% as you requested but I hope that's ok ;-)

MichaelS
  • 5,941
  • 6
  • 31
  • 46
  • Thank you for helping - I note the above solutions use % rather than !. I've tested and it works. I wondered what difference it makes? – BLS Apr 23 '15 at 15:13
  • % means that the variable is evaluated at parse time. Using ! instead forces the interpreter to evaluate it at run time. This makes a difference if you e.g. change a value of a variable within a for loop. If you would use % these changes would be forgotten whereas ! would contain the changed value. It only works with `SETLOCAL EnableDelayedExpansion`. Another example I've explained here: http://stackoverflow.com/questions/29696734/how-to-put-variable-value-inside-another-variable-name-in-batch/29696975#29696975. It's about using a variable as part of the name of another variable. – MichaelS Apr 24 '15 at 07:50