Change background color of string

Question

I have a problem in NASM. I want to change the background colour, but only for one string.

These are my macros:

%macro SetBackGroundColour 0
    mov dx, 0
    mov bh, 0
    mov ah, 0x2
    int 0x10
    mov cx, 2000 
    mov bh, 0
    mov bl, 0x21 
    mov al, 0x20 
    mov ah, 0x9
    int 0x10     
%endmacro

%macro printOnTheScreen 1
    xor dx,dx 
    mov ah, 09h 
    mov dx, %1 
    int 21h 
    xor dx, dx
%endmacro

I tried other changes, but nothing worked.

Specifying the exact asm flavor you are using would help others spot your question (and possibly answer it) much quicker. — D-side, Apr 28 '15 at 16:38
http://stackoverflow.com/questions/29460318/how-to-print-colored-string-in-assembly-language/29478158#29478158 — Jose Manuel Abarca Rodríguez, Apr 28 '15 at 16:43
http://stackoverflow.com/questions/29704807/the-following-codes-should-print-jan-string-in-video-mode-but-it-prints-some-sym/29705041#29705041 — Jose Manuel Abarca Rodríguez, Apr 28 '15 at 16:45
thanks, but I don't want to change colour of a string, but background colour of the string. — Ola214, Apr 28 '15 at 16:50
I mean I don't want all the background being green as I had written in a macro, but only when there is a string — Ola214, Apr 28 '15 at 16:51
The given links allow you to display a string with some color, ONLY the string will have color. Try the interrupts and their parameters. — Jose Manuel Abarca Rodríguez, Apr 28 '15 at 16:53
I wanted to do that. but I don't have 15 reputation, so I unfortunately I can't :( mov ah, 9 mov bh, 0 mov bl, 0x20 ;ANY COLOR. mov cx, 5 ;HOW MANY TIMES TO DISPLAY CHAR. int 10h what do ah and bh? — Ola214, Apr 28 '15 at 17:08
Loop through the characters of the string. Display each char with the desired color. What answer or technique are you using? — Jose Manuel Abarca Rodríguez, Apr 28 '15 at 17:18
Ok, thank you, I asked you, because I want my string in right corner and I wonder if it works only for the beginning of the line. — Ola214, Apr 28 '15 at 17:22
It depends on the technique. Are you using interrupt 10h ah 13h, or B800h? — Jose Manuel Abarca Rodríguez, Apr 28 '15 at 17:23
Oh ok, now I understand youre question :) I use interrupt 10h. Sorry, I'm begginer — Ola214, Apr 28 '15 at 17:25
The interrupt accepts the X,Y position in DL,DH = http://stackoverflow.com/questions/29460318/how-to-print-colored-string-in-assembly-language/29478158#29478158 , where the comments say "x (screen coordinate)". — Jose Manuel Abarca Rodríguez, Apr 28 '15 at 17:29
%macro moveString 2 mov ah,02H mov bh, 0 mov dh, %1 ;number of x mov dl, %2 ;number of y int 21h %endmacro but it doesn't work — Ola214, Apr 28 '15 at 17:31
Is it possible to replace (just to test) the %1 and %2 with numbers? — Jose Manuel Abarca Rodríguez, Apr 28 '15 at 17:33
What if, instead of a macro, you create a PROCEDURE? Does it got to be a macro? — Jose Manuel Abarca Rodríguez, Apr 28 '15 at 17:40
No, it doesn't. It only has to work :D I have never used procedure, so I would try. Will procedure uses parameters like macro does ? Because in your code you don't use parameters or I don't see that. Because I have to change places of a string for some times. — Ola214, Apr 28 '15 at 17:41
http://wklej.org/id/1699002/ I have error :parser:instruction expected when I compile :( — Ola214, Apr 28 '15 at 17:50
What is the instruction that gives you the error? Add RET before the end of the PROC. — Jose Manuel Abarca Rodríguez, Apr 28 '15 at 17:51
ah=02h with int 21h requires the character to display in DL. Move some char to DL. And it uses the current cursor position. Do GOTOXY before. — Jose Manuel Abarca Rodríguez, Apr 28 '15 at 17:55

Jose Manuel Abarca Rodríguez · Answer 1 · 2015-04-28T20:47:57.167

Next is a procedure in (almost) NASM to display string with color, notice how parameters are set before the CALL :

SECTION .data

text:  db  "Just some text"  ;LENGTH = 14.
color: db 181          
x:     db 0
y:     db 0

SECTION .text

global main
main:

  mov  bp, text ;STRING TO DISPLAY.
  mov  cx, 14          ;STRING LENGTH.
  mov  [x], byte 50    
  mov  [y], byte 20
  call color_string

;FINISH PROGRAM.
  mov  ax,4c00h
  int  21h

;----------------------------------------------     
;PARAMETERS : BP = OFFSET OF STRING TO DISPLAY.  
;             CX = STRING LENGTH.
;             COLOR = VARIABLE WITH COLOR (0..255).
;             X,Y   = VARIABLES WITH COORDINATES.

color_string:

  mov  ax, ds
  mov  es, ax         ;ES SEGMENT MUST POINT TO DATA SEGMENT.
  mov  ah, 13h        ;SERVICE TO DISPLAY STRING WITH COLOR.
  mov  bh, 0          ;PAGE (ALWAYS ZERO).
  mov  bl, color
  mov  dl, x          ;X (SCREEN COORDINATE). 
  mov  dh, y          ;Y (SCREEN COORDINATE). 
  int  10h           ;BIOS SCREEN SERVICES.  

  ret

The code to set cursor position is this :

mov  ah, 2  ;SERVICE TO SET CURSOR POSITION.
mov  bh, 0  ;PAGE NUMBER (ALWAYS ZERO).
mov  dl, x  ;X COORDINATE 0..79.
mov  dh, y  ;Y COORDINATE 0..24.
int  10h    ;BIOS VIDEO SERVICES.

I tried running your program but it says ld: warning: cannot find entry symbol _start; defaulting to 0000000008048080` any issue here — varad, Apr 02 '18 at 11:49
@aryan, try this ► https://stackoverflow.com/questions/34758769/load-warning-cannot-find-entry-symbol-start — Jose Manuel Abarca Rodríguez, Apr 02 '18 at 13:55

score 0 · Answer 2 · answered Jul 09 '23 at 15:41

If you output via DOS (you're using DOS.PrintString function 09h), you loose the ability to produce color. Luckily BIOS does support colorful text. Read all about the available DOS and BIOS text output functions in Displaying characters with DOS or BIOS.
For the text video mode, you can use the WriteStringWithAttributeTVM code that expects DS:SI to point at your zero-terminated text and BL to contain the attribute to use (specifying the foreground color in the low nibble and the background color in the high nibble). Just like the DOS.PrintString function 09h, it will expand tabs.

; IN (bl,ds:si) OUT ()
WriteStringWithAttributeTVM:
      pusha
      mov     bh, 0           ; Display page 0
      jmp     .d
.a:   cmp     al, 9
      je      .Tab
      cmp     al, 13
      ja      .b
      mov     cx, 1101_1010_0111_1111b
      bt      cx, ax
      jnc     .c              ; {7,8,10,13} don't need the color
.b:   mov     cx, 1
      mov     ah, 09h         ; BIOS.WriteCharacterAndAttribute
      int     10h
.c:   mov     ah, 0Eh         ; BIOS.Teletype
      int     10h
.d:   lodsb
      test    al, al
      jnz     .a
      popa
      ret
.Tab: mov     cx, 1           ; Start displaying colored space(s)
      mov     ax, 0920h       ; BIOS.WriteCharacterAndAttribute
      int     10h
      mov     ah, 0Eh         ; BIOS.Teletype
      int     10h
      mov     ah, 03h         ; BIOS.GetCursor
      int     10h             ; -> CX DX
      test    dl, 7
      jnz     .Tab            ; Column not yet multiple of 8
      jmp     .d

There is an additional BIOS function that can display a string in color but it will not expand tabs like the DOS.PrintString function 09h does. This is also the solution in one of the other answers but over there it contains an error. A further drawback is that you need to know the length of the string beforehand and that it requires the weird ES:BP pointer. The only nice thing about it, is that you can specify the column and row in the call...

; IN (bl,cx,dx,bp) OUT ()
;  BL Attribute eg. 1Fh is BrightWhiteOnBlue
;  CX Length of the string
;  DL Column
;  DH Row
;  BP Offset address of the string
WriteString:
      push    ax
      push    bx
      push    es
      mov     ax, ds          ; DS:BP --> ES:BP
      mov     es, ax
      mov     bh, 0           ; Display page 0
      mov     ax, 1301h       ; BIOS.WriteString
      int     10h
      pop     es
      pop     bx      
      pop     ax
      ret

About mov ax, 1301h : Because the WriteMode in AL is set to 1, the attribute is taken from the BL register AND the cursor gets updated (just like the DOS.PrintString function 09h would have done).

admin · Answer 3 · 2023-07-07T15:20:01.517

-1

You can display that string, and change the color, display another string. For example this code change background color to blue, foreground color to white, and then change background color to black, foreground color to white:

    mov cx, 2000 
    mov bh, 0
    mov bl, 0x1F 
    mov al, 0x20
    mov ah, 0x9
    int 0x10

    ;display string here

    mov cx, 2000 
    mov bh, 0
    mov bl, 0x0F 
    mov al, 0x20
    mov ah, 0x9
    int 0x10

    ;display string here

Note: That code wasn't clear the screen at beginning.

edited Jul 07 '23 at 15:20

answered Jul 07 '23 at 15:18

admin

3
3

This does not answer the OP's question where they just want the string to have a certain backgroundcolor (see comment https://stackoverflow.com/questions/29925051/change-background-color-of-string#comment47972339_29925051) – Sep Roland Jul 09 '23 at 14:47

Change background color of string

3 Answers3