How to chain Promises? — clarification needed

Question

Trying to use Promises instead of caolan's async library, I'm struggling with completely different approach. A little clarification is highly appreciated.

Let's say I'm registering User with Sequezlie library. To do this I need:

1. Create user oject
2. Create dependent object Folder
3. Return result to client

Sequezlie use promises for all CRUD-operations. And User.register is a promisifed shortcut to User.create(...).

user =
  email: req.body.email
  name : req.body.name

createFolder = (user)->
  new Promise (resolve, reject)->
    Folder
      .build(title: "untitled", UserId: user.id)
      .save()
      .then (folder)-> resolve folder
      .catch (err)-> reject err

# register
User
  .register(user, req.body.password)
  .then(createFolder(user))
  .then (folder)->
    console.log "User with Folder is created"
    res.send 201

At this time Folder is created, but createFolder() has no access to user object. What I'm doing wrong? Which is the better way to chain Promises and access it's results in each other?

FYI, I'm using then/promise implementation.

Thanks.

Answer 1

You've defined a function createUser that accepts a parameter user.

I suspect (though it's hard to tell from your code) that this is not meant to be the same object user declared in the outer scope. You pass that to register, and that returns a different object (wrapped in a promise) representing the user. Let's call that object registeredUser to avoid confusion:

User
  .register(user, req.body.password)
  .then((registeredUser) -> createFolder(registeredUser))
  .then (folder)-> ...

We can write that more succinctly:

User
  .register(user, req.body.password)
  .then(createFolder)
  .then (folder)-> ...

The difference is that we are not calling createFolder - we're just passing it to then so it acts directly as the handler function for the successful resolution of the promise returned by register, i.e. it will be called by then when the user is registered.

Update

You asked in the comments about accessing the results of multiple previous promises, further back in the chain. Just start another chain inside the previous handler:

User.register(user, req.body.password).then((registeredUser) ->
  createFolder(registeredUser).then (folder) ->
    # do more stuff here, or just return an object
    {
      folder: folder
      user: registeredUser
    }
).then (all) ->
  console.log all

By returning an object from the inner then, that becomes the result passed back to the outer chain, so all is the object with folder and user properties.

Answer 2

Sequelize queries seems to return promises. In which case you don't need to create your own promise objects - just use the ones returned by sequelize:

function createFolder (user) {
    // assuming the following returns a promise
    return Folder.build(title: "untitled", UserId: user.id).save();
}

Then you can chain it like this:

User.register(user, req.body.password)
    .then(createFolder) // <------------ note!!
    .then function (folder) {
        console.log("User with Folder is created");
        res.send(201);
    }

note!!: We pass createFolder instead of calling it! That's because the .then() will call it when .register() completes.