Send Excel range into Email body with autofit

Question

I'm currently using Ron de Bruin's RangetoHTML function to send a couple of tables out in an e-mail. I'd like to have these tables auto-fit to the screen in outlook.

Currently, I have to click on each table and go to layout->autofit to screen on each table. I was wondering if this task could be folded into the macro in some way.

Edit: This was my first guess at a solution:

objMail.HTMLBody = RangetoHTML(Range("A1:G14")) & _
    RangetoHTML(Range(Range("vmRange").Value)) & _
    RangetoHTML(Range(Range("hpRange").Value)) & _
    RangetoHTML(Range(Range("esrRange").Value))

For Each tbl In objMail.body.tables
    tbl.Columns.AutoFit 'Note: This doesn't actually work
Next tbl

Answer 1

Here's my modified version of Ron de Bruin's function:

Function RangetoHTMLFlexWidth(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2013
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTMLFlexWidth = ts.readall
    ts.Close
    RangetoHTMLFlexWidth = Replace(RangetoHTMLFlexWidth, "align=center x:publishsource=", _
        "align=left x:publishsource=")

    Dim startIndex As Long
    Dim stopIndex As Long
    Dim subString As String

    'Change table width to "100%"
    startIndex = InStr(RangetoHTMLFlexWidth, "<table")
    startIndex = InStr(startIndex, RangetoHTMLFlexWidth, "width:") + 5
    stopIndex = InStr(startIndex, RangetoHTMLFlexWidth, "'>")
    subString = Left(RangetoHTMLFlexWidth, startIndex)
    subString = subString & "100%"
    RangetoHTMLFlexWidth = subString & Mid(RangetoHTMLFlexWidth, stopIndex)

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

The changes start with the comment:

'Change table width to "100%"

It just finds the spot where the table's width is defined and sets it to 100%. The browser or outlook scales the cells to the new width, so it does the job, but it's a dirty hack, IMO.

Answer 2

Edit CODE From

With TempWB.Sheets(1)
    .Cells(1).PasteSpecial Paste:=8
    .Cells(1).PasteSpecial xlPasteValues, , False, False
    .Cells(1).PasteSpecial xlPasteFormats, , False, False
    .Cells(1).Select

Change and Add To CODE

      Cells(1).Select '<<---- Change
      Cells(1).EntireRow.AutoFit '<<-- Add
      Cells(1).EntireColumn.AutoFit '<<-- Add

See Complete CODE

Option Explicit
'// Source From Ron de Bruin
Sub MailSelectionRangeOutlookBody()
    Dim rng As Range
    Dim OutApp As Object
    Dim OutMail As Object

    Set rng = Nothing
    On Error Resume Next
    '// Only the visible cells in the selection
    Set rng = Selection.SpecialCells(xlCellTypeVisible)
    '// You can also use a fixed range if you want
    '// Set rng = Sheets("YourSheet").Range("D4:D12").SpecialCells(xlCellTypeVisible)
    On Error GoTo 0

    If rng Is Nothing Then
        MsgBox "The selection is not a range or the sheet is protected" & _
               vbNewLine & "please correct and try again.", vbOKOnly
        Exit Sub
    End If

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    On Error Resume Next
    With OutMail
        .To = "Add@Email.com"
        .CC = ""
        .BCC = ""
        .Subject = "This is the Subject line"
        .HTMLBody = RangetoHTML(rng)
        '.Send   '// or use .Display
        .Display
    End With
    On Error GoTo 0

    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub

Function RangetoHTML(rng As Range)
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    '// Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
         Cells.Select
         Cells.EntireRow.AutoFit
         Cells.EntireColumn.AutoFit
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    '// Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    '// Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    '// Close TempWB
    TempWB.Close savechanges:=False

    '// Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

Answer 3

Option Explicit

Sub call_function()

ResizeAllTables_FitContentsOrWindow

End Sub

Function ResizeAllTables_FitContentsOrWindow()

Dim objMail As Object
Set objMail = CreateObject("Outlook.application")

Dim objMailDocument As Object
Dim objTables As Object

Dim i As Integer
Dim objTable As Object


Set objMail = objMail.ActiveInspector.CurrentItem
Set objMailDocument = objMail.GetInspector.WordEditor
Set objTables = objMailDocument.Tables

If objTables.Count > 0 Then
   For i = 1 To objTables.Count
       Set objTable = objTables.Item(i)
       
       ' Autofit Table Default
       'objTable.AutoFitBehavior 0   'wdAutoFixed

       'Fit the window
       'objTable.AutoFitBehavior 2 ' wdAutoFitWindow

       'Fit the contents, use the following line instead
       objTable.AutoFitBehavior 1   'wdAutoFitWindow
   Next
End If

End Function