Is it possible to know current loop index inside a for loop?

Question

I have a .bat file like this:

@echo OFF

if "%1" == "" (
    set pattern=*
) else (
    set pattern=%1
)

for %%g in (%pattern%) do echo   %%g

Executing listfile.bat setenv*.bat, it outputs something like:

  setenv-win7x64-chk.bat
  setenv-win7x64-fre.bat
  setenv-winxp-chk.bat
  setenv-winxp-fre.bat

My question is: How can I make it output like:

[1]  setenv-win7x64-chk.bat
[2]  setenv-win7x64-fre.bat
[3]  setenv-winxp-chk.bat
[4]  setenv-winxp-fre.bat

Is there a secret variable that tells me the current loop-index? -- just like Autohotkey's A_Index variable.

http://stackoverflow.com/questions/7522740/counting-in-a-for-loop-using-dos-batch-script — Marc B, May 28 '15 at 14:26
I recommend leaving behind `cmd.exe` shell scripting and use PowerShell instead. It's far superior in nearly every conceivable way. — Bill_Stewart, May 28 '15 at 14:45

score 3 · Accepted Answer · answered May 28 '15 at 16:36

The answer is "no", but you may add a counting variable in a very simple way:

@echo OFF
setlocal EnableDelayedExpansion

if "%1" == "" (
    set pattern=*
) else (
    set pattern=%1
)

set i=0
for %%g in (%pattern%) do (
   set /A i+=1
   echo [!i!]  %%g
)

user1016274 · Answer 2 · 2015-05-29T06:41:51.563

2

I suggest letting a tool do the enumeration for simplicity:

( for %%g in (%pattern%) do @echo %%g ) | find /n /v ""

edited May 29 '15 at 06:41

answered May 28 '15 at 15:04

user1016274

4,071
1
23
19

1

Good tip, better add a @ before the nested echo. – Jimm Chen May 29 '15 at 00:31

Is it possible to know current loop index inside a for loop?

2 Answers2